src/metrics/metrics_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Helpers for various statistics tools.
  18 module metrics_base
  19
  20 import modelbuilder
  21
  22 redef class ToolContext
  23
  24         # --all
  25         var opt_all = new OptionBool("Compute all metrics", "--all")
  26
  27         # --refinement
  28         var opt_refinement = new OptionBool("Compute metrics about refinement usage", "--refinement")
  29         # --self
  30         var opt_self = new OptionBool("Compute metrics about the usage of explicit and implicit self", "--self")
  31         # --nullables
  32         var opt_nullables = new OptionBool("Compute metrics on nullables send", "--nullables")
  33         # --static-types
  34         var opt_static_types = new OptionBool("Compute explicit static types metrics", "--static-types")
  35         # --tables
  36         var opt_tables = new OptionBool("Compute tables metrics", "--tables")
  37         # --rta
  38         var opt_rta = new OptionBool("Compute RTA metrics", "--rta")
  39         # --generate_hyperdoc
  40         var opt_generate_hyperdoc = new OptionBool("Generate Hyperdoc", "--generate_hyperdoc")
  41
  42         var opt_dir = new OptionString("Directory where some statistics files are generated", "-d", "--dir")
  43         var output_dir: String = "."
  44
  45         redef init
  46         do
  47                 super
  48                 self.option_context.add_option(opt_all)
  49                 self.option_context.add_option(opt_refinement)
  50                 self.option_context.add_option(opt_self)
  51                 self.option_context.add_option(opt_nullables)
  52                 self.option_context.add_option(opt_static_types)
  53                 self.option_context.add_option(opt_tables)
  54                 self.option_context.add_option(opt_rta)
  55                 self.option_context.add_option(opt_generate_hyperdoc)
  56                 self.option_context.add_option(opt_dir)
  57         end
  58
  59         redef fun process_options
  60         do
  61                 super
  62                 var val = self.opt_dir.value
  63                 if val != null then
  64                         val = val.simplify_path
  65                         val.mkdir
  66                         self.output_dir = val
  67                 end
  68         end
  69 end
  70
  71 # A counter counts occurence of things
  72 # Use this instead of a HashMap[E, Int]
  73 class Counter[E: Object]
  74         # Total number of counted occurences
  75         var total: Int = 0
  76
  77         private var map = new HashMap[E, Int]
  78
  79         # The number of counted occurences of `e'
  80         fun [](e: E): Int
  81         do
  82                 var map = self.map
  83                 if map.has_key(e) then return map[e]
  84                 return 0
  85         end
  86
  87         # Count one more occurence of `e'
  88         fun inc(e: E)
  89         do
  90                 self.map[e] = self[e] + 1
  91                 total += 1
  92         end
  93
  94         # Return an array of elements sorted by occurences
  95         fun sort: Array[E]
  96         do
  97                 var res = map.keys.to_a
  98                 var sorter = new CounterSorter[E](self)
  99                 sorter.sort(res)
 100                 #res.sort !cmp a, b = map[a] <=> map[b]
 101                 return res
 102         end
 103 end
 104
 105 private class CounterSorter[E: Object]
 106         super AbstractSorter[E]
 107         var counter: Counter[E]
 108         redef fun compare(a,b) do return self.counter.map[a] <=> self.counter.map[b]
 109 end
 110
 111 # Helper function to display n/d and handle division by 0
 112 fun div(n: Int, d: Int): String
 113 do
 114         if d == 0 then return "na"
 115         return ((100*n/d).to_f/100.0).to_precision(2)
 116 end