lib/gamnit/examples/triangle/src/portable_triangle.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Portable example of using Gamnit with custom calls to OpenGL ES 2.0
  16 #
  17 # References:
  18 # * The book OpenGL ES 2.0 Programming Guide
  19 # * https://code.google.com/p/opengles-book-samples/source/browse/trunk/LinuxX11/Chapter_2/Hello_Triangle/Hello_Triangle.c
  20 module portable_triangle is
  21         app_name "gamnit Triangle"
  22         app_namespace "org.nitlanguage.triangle"
  23         app_version(1, 1, git_revision)
  24 end
  25
  26 import gamnit
  27
  28 redef class App
  29
  30         # Our only program for the graphic card
  31         var program: GLProgram is noautoinit
  32
  33         # The only vertex sharder
  34         var vertex_shader: GLVertexShader is noautoinit
  35
  36         # The only fragment sharder
  37         var fragment_shader: GLFragmentShader is noautoinit
  38
  39         # Vertex data for the triangle
  40         var vertex_array: VertexArray is noautoinit
  41
  42         redef fun create_scene
  43         do
  44                 super
  45
  46                 var display = display
  47                 assert display != null
  48
  49                 print "Width: {display.width}"
  50                 print "Height: {display.height}"
  51
  52                 assert glGetError == gl_NO_ERROR
  53                 assert gl.shader_compiler else print "Cannot compile shaders"
  54
  55                 # GL program
  56                 program = new GLProgram
  57                 if not glIsProgram(program) then
  58                         print "Program is not ok: {glGetError.to_s}\nLog:"
  59                         print glGetProgramInfoLog(program)
  60                         abort
  61                 end
  62                 assert glGetError == gl_NO_ERROR
  63
  64                 # Vertex shader
  65                 vertex_shader = new GLVertexShader
  66                 assert glIsShader(vertex_shader) else print "Vertex shader is not ok: {glGetError}"
  67                 glShaderSource(vertex_shader, """
  68                 attribute vec4 vPosition;
  69                 void main()
  70                 {
  71                   gl_Position = vPosition;
  72                 }
  73                 """@glsl_vertex_shader.to_cstring)
  74                 glCompileShader(vertex_shader)
  75                 assert vertex_shader.is_compiled else print "Vertex shader compilation failed with: {glGetShaderInfoLog(vertex_shader)} {glGetProgramInfoLog(program)}"
  76                 assert glGetError == gl_NO_ERROR
  77
  78                 # Fragment shader
  79                 fragment_shader = new GLFragmentShader
  80                 assert glIsShader(fragment_shader) else print "Fragment shader is not ok: {glGetError}"
  81                 glShaderSource(fragment_shader, """
  82                 precision mediump float;
  83                 void main()
  84                 {
  85                         gl_FragColor = vec4(1.0, 0.0, 0.0, 1.0);
  86                 }
  87                 """@glsl_fragment_shader.to_cstring)
  88                 glCompileShader(fragment_shader)
  89                 assert fragment_shader.is_compiled else print "Fragment shader compilation failed with: {glIsShader(fragment_shader)}"
  90                 assert glGetError == gl_NO_ERROR
  91
  92                 # Attach to program
  93                 glAttachShader(program, vertex_shader)
  94                 glAttachShader(program, fragment_shader)
  95                 program.bind_attrib_location(0, "vPosition")
  96                 glLinkProgram program
  97                 assert program.is_linked else print "Linking failed: {glGetProgramInfoLog(program)}"
  98                 assert glGetError == gl_NO_ERROR
  99
 100                 # Draw!
 101                 var vertices = [0.0, 0.5, 0.0, -0.5, -0.5, 0.0, 0.5, -0.5, 0.0]
 102                 vertex_array = new VertexArray(0, 3, vertices)
 103                 vertex_array.attrib_pointer
 104         end
 105
 106         private var t = 0.0
 107
 108         redef fun frame_core(display)
 109         do
 110                 glClearColor(t, t, t, 1.0)
 111
 112                 assert glGetError == gl_NO_ERROR
 113                 glViewport(0, 0, display.width, display.height)
 114                 glClear gl_COLOR_BUFFER_BIT
 115                 glUseProgram program
 116                 vertex_array.enable
 117
 118                 glDrawArrays(gl_TRIANGLES, 0, 3)
 119
 120                 display.flip
 121
 122                 t += 0.01
 123                 if t > 1.0 then t = 0.0
 124         end
 125
 126         redef fun on_stop
 127         do
 128                 # Clean up
 129                 glDeleteProgram program
 130                 glDeleteShader vertex_shader
 131                 glDeleteShader fragment_shader
 132
 133                 # Close gamnit
 134                 var display = display
 135                 if display != null then display.close
 136         end
 137 end
 138
 139 if "NIT_TESTING".environ == "true" then exit(0)
 140 super