src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** COMPILING TO C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 compiler.new_file
  45                 for m in mainmodule.in_importation.greaters do
  46                         for mclass in m.intro_mclasses do
  47                                 compiler.compile_class_to_c(mclass)
  48                         end
  49                 end
  50
  51                 # The main function of the C
  52                 compiler.new_file
  53                 compiler.compile_main_function
  54
  55                 # compile methods
  56                 for m in mainmodule.in_importation.greaters do
  57                         compiler.new_file
  58                         compiler.compile_module_to_c(m)
  59                 end
  60
  61                 compiler.display_stats
  62
  63                 write_and_make(compiler)
  64         end
  65 end
  66
  67 class SeparateErasureCompiler
  68         super SeparateCompiler
  69
  70         private var class_layout: nullable TypingLayout[MClass]
  71         private var class_tables: Map[MClass, Array[nullable MClass]]
  72
  73         protected var vt_layout: nullable PropertyLayout[MVirtualTypeProp]
  74         protected var vt_tables: Map[MClass, Array[nullable MPropDef]]
  75
  76         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: RapidTypeAnalysis) do
  77                 super
  78
  79                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  80
  81                 var layout_builder: TypingLayoutBuilder[MClass]
  82                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  83                         layout_builder = new PHClassLayoutBuilder(mainmodule, new PHModOperator)
  84                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
  85                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  86                         layout_builder = new PHClassLayoutBuilder(mainmodule, new PHAndOperator)
  87                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
  88                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  89                         layout_builder = new BMClassLayoutBuilder(mainmodule)
  90                 else
  91                         layout_builder = new CLClassLayoutBuilder(mainmodule)
  92                 end
  93                 self.class_layout = layout_builder.build_layout(mclasses)
  94                 self.class_tables = self.build_class_typing_tables(mclasses)
  95
  96                 # vt coloration
  97                 var vt_coloring = new CLPropertyLayoutBuilder[MVirtualTypeProp](mainmodule)
  98                 var vt_layout = vt_coloring.build_layout(mclasses)
  99                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 100                 self.compile_color_consts(vt_layout.pos)
 101                 self.vt_layout = vt_layout
 102         end
 103
 104         fun build_vt_tables(mclasses: Set[MClass], layout: PropertyLayout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 105                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 106                 for mclass in mclasses do
 107                         var table = new Array[nullable MPropDef]
 108                         # first, fill table from parents by reverse linearization order
 109                         var parents = self.mainmodule.super_mclasses(mclass)
 110                         var lin = self.mainmodule.reverse_linearize_mclasses(parents)
 111                         for parent in lin do
 112                                 for mproperty in self.mainmodule.properties(parent) do
 113                                         if not mproperty isa MVirtualTypeProp then continue
 114                                         var color = layout.pos[mproperty]
 115                                         if table.length <= color then
 116                                                 for i in [table.length .. color[ do
 117                                                         table[i] = null
 118                                                 end
 119                                         end
 120                                         for mpropdef in mproperty.mpropdefs do
 121                                                 if mpropdef.mclassdef.mclass == parent then
 122                                                         table[color] = mpropdef
 123                                                 end
 124                                         end
 125                                 end
 126                         end
 127
 128                         # then override with local properties
 129                         for mproperty in self.mainmodule.properties(mclass) do
 130                                 if not mproperty isa MVirtualTypeProp then continue
 131                                 var color = layout.pos[mproperty]
 132                                 if table.length <= color then
 133                                         for i in [table.length .. color[ do
 134                                                 table[i] = null
 135                                         end
 136                                 end
 137                                 for mpropdef in mproperty.mpropdefs do
 138                                         if mpropdef.mclassdef.mclass == mclass then
 139                                                 table[color] = mpropdef
 140                                         end
 141                                 end
 142                         end
 143                         tables[mclass] = table
 144                 end
 145                 return tables
 146         end
 147
 148         # Build class tables
 149         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 150                 var tables = new HashMap[MClass, Array[nullable MClass]]
 151                 var layout = self.class_layout
 152                 for mclass in mclasses do
 153                         var table = new Array[nullable MClass]
 154                         var supers = new HashSet[MClass]
 155                         supers.add_all(self.mainmodule.super_mclasses(mclass))
 156                         supers.add(mclass)
 157                         for sup in supers do
 158                                 var color: Int
 159                                 if layout isa PHTypingLayout[MClass] then
 160                                         color = layout.hashes[mclass][sup]
 161                                 else
 162                                         color = layout.pos[sup]
 163                                 end
 164                                 if table.length <= color then
 165                                         for i in [table.length .. color[ do
 166                                                 table[i] = null
 167                                         end
 168                                 end
 169                                 table[color] = sup
 170                         end
 171                         tables[mclass] = table
 172                 end
 173                 return tables
 174         end
 175
 176         redef fun compile_header_structs do
 177                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 178                 self.compile_header_attribute_structs
 179                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; struct vts_table *vts_table; struct type_table *type_table; nitmethod_t vft[1]; \}; /* general C type representing a Nit class. */")
 180                 self.header.add_decl("struct type_table \{ int size; int table[1]; \}; /* colorized type table. */")
 181                 self.header.add_decl("struct vts_entry \{ short int is_nullable; struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 182
 183                 if modelbuilder.toolcontext.opt_phmod_typing.value or modelbuilder.toolcontext.opt_phand_typing.value then
 184                         self.header.add_decl("struct vts_table \{ int mask; struct vts_entry vts[1]; \}; /* vts list of a C type representation. */")
 185                 else
 186                         self.header.add_decl("struct vts_table \{ struct vts_entry vts[1]; \}; /* vts list of a C type representation. */")
 187                 end
 188
 189                 self.header.add_decl("typedef struct val \{ struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 190         end
 191
 192         redef fun compile_class_to_c(mclass: MClass)
 193         do
 194                 var mtype = mclass.intro.bound_mtype
 195                 var c_name = mclass.c_name
 196
 197                 var vft = self.method_tables[mclass]
 198                 var attrs = self.attr_tables[mclass]
 199                 var class_table = self.class_tables[mclass]
 200                 var v = self.new_visitor
 201
 202                 v.add_decl("/* runtime class {c_name} */")
 203                 var idnum = classids.length
 204                 var idname = "ID_" + c_name
 205                 self.classids[mtype] = idname
 206                 #self.header.add_decl("#define {idname} {idnum} /* {c_name} */")
 207
 208                 self.header.add_decl("extern const struct class_{c_name} class_{c_name};")
 209                 self.header.add_decl("struct class_{c_name} \{")
 210                 self.header.add_decl("int id;")
 211                 self.header.add_decl("const char *name;")
 212                 self.header.add_decl("int box_kind;")
 213                 self.header.add_decl("int color;")
 214                 self.header.add_decl("const struct vts_table *vts_table;")
 215                 self.header.add_decl("struct type_table *type_table;")
 216                 self.header.add_decl("nitmethod_t vft[{vft.length}];")
 217                 self.header.add_decl("\};")
 218
 219                 # Build class vft
 220                 v.add_decl("const struct class_{c_name} class_{c_name} = \{")
 221                 v.add_decl("{self.class_layout.ids[mclass]},")
 222                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 223                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 224                 var layout = self.class_layout
 225                 if layout isa PHTypingLayout[MClass] then
 226                         v.add_decl("{layout.masks[mclass]},")
 227                 else
 228                         v.add_decl("{layout.pos[mclass]},")
 229                 end
 230                 if build_class_vts_table(mclass) then
 231                         v.add_decl("(const struct vts_table*) &vts_table_{c_name},")
 232                 else
 233                         v.add_decl("NULL,")
 234                 end
 235                 v.add_decl("(struct type_table*) &type_table_{c_name},")
 236                 v.add_decl("\{")
 237                 for i in [0 .. vft.length[ do
 238                         var mpropdef = vft[i]
 239                         if mpropdef == null then
 240                                 v.add_decl("NULL, /* empty */")
 241                         else
 242                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 243                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 244                                 else
 245                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 246                                 end
 247                         end
 248                 end
 249                 v.add_decl("\}")
 250                 v.add_decl("\};")
 251
 252                 # Build class type table
 253                 self.header.add_decl("extern const struct type_table_{c_name} type_table_{c_name};")
 254                 self.header.add_decl("struct type_table_{c_name} \{")
 255                 self.header.add_decl("int size;")
 256                 self.header.add_decl("int table[{class_table.length}];")
 257                 self.header.add_decl("\};")
 258
 259                 v.add_decl("const struct type_table_{c_name} type_table_{c_name} = \{")
 260                 v.add_decl("{class_table.length},")
 261                 v.add_decl("\{")
 262                 for msuper in class_table do
 263                         if msuper == null then
 264                                 v.add_decl("-1, /* empty */")
 265                         else
 266                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 267                         end
 268                 end
 269                 v.add_decl("\}")
 270                 v.add_decl("\};")
 271
 272                 #Build instance struct
 273                 if mtype.ctype != "val*" then
 274                         self.header.add_decl("struct instance_{c_name} \{")
 275                         self.header.add_decl("const struct class *class;")
 276                         self.header.add_decl("{mtype.ctype} value;")
 277                         self.header.add_decl("\};")
 278
 279                         self.header.add_decl("val* BOX_{c_name}({mtype.ctype});")
 280                         v.add_decl("/* allocate {mtype} */")
 281                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 282                         v.add("struct instance_{c_name}*res = GC_MALLOC(sizeof(struct instance_{c_name}));")
 283                         v.add("res->class = (struct class*) &class_{c_name};")
 284                         v.add("res->value = value;")
 285                         v.add("return (val*)res;")
 286                         v.add("\}")
 287                         return
 288                 end
 289
 290                 var is_native_array = mclass.name == "NativeArray"
 291
 292                 var sig
 293                 if is_native_array then
 294                         sig = "int length"
 295                 else
 296                         sig = ""
 297                 end
 298
 299                 #Build instance struct
 300                 #extern const struct instance_array__NativeArray instance_array__NativeArray;
 301                 self.header.add_decl("struct instance_{c_name} \{")
 302                 self.header.add_decl("const struct class *class;")
 303                 self.header.add_decl("nitattribute_t attrs[{attrs.length}];")
 304                 if is_native_array then
 305                         # NativeArrays are just a instance header followed by an array of values
 306                         self.header.add_decl("val* values[0];")
 307                 end
 308                 self.header.add_decl("\};")
 309
 310
 311                 self.header.add_decl("{mtype.ctype} NEW_{c_name}({sig});")
 312                 v.add_decl("/* allocate {mtype} */")
 313                 v.add_decl("{mtype.ctype} NEW_{c_name}({sig}) \{")
 314                 var res = v.new_named_var(mtype, "self")
 315                 res.is_exact = true
 316                 if is_native_array then
 317                         var mtype_elt = mtype.arguments.first
 318                         v.add("{res} = GC_MALLOC(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 319                 else
 320                         v.add("{res} = GC_MALLOC(sizeof(struct instance_{c_name}));")
 321                 end
 322                 v.add("{res}->class = (struct class*) &class_{c_name};")
 323
 324                 self.generate_init_attr(v, res, mtype)
 325                 v.add("return {res};")
 326                 v.add("\}")
 327
 328                 generate_check_init_instance(mtype)
 329         end
 330
 331         private fun build_class_vts_table(mclass: MClass): Bool do
 332                 if self.vt_tables[mclass].is_empty then return false
 333
 334                 self.header.add_decl("extern const struct vts_table_{mclass.c_name} vts_table_{mclass.c_name};")
 335                 self.header.add_decl("struct vts_table_{mclass.c_name} \{")
 336                 if modelbuilder.toolcontext.opt_phmod_typing.value or modelbuilder.toolcontext.opt_phand_typing.value then
 337                         self.header.add_decl("int mask;")
 338                 end
 339                 self.header.add_decl("struct vts_entry vts[{self.vt_tables[mclass].length}];")
 340                 self.header.add_decl("\};")
 341
 342                 var v = new_visitor
 343                 v.add_decl("const struct vts_table_{mclass.c_name} vts_table_{mclass.c_name} = \{")
 344                 #TODO redo this once PHMPropertyLayoutBuilder will be implemented
 345                 #if modelbuilder.toolcontext.opt_phmod_typing.value or modelbuilder.toolcontext.opt_phand_typing.value then
 346                         #v.add_decl("{vt_masks[mclass]},")
 347                 #end
 348                 v.add_decl("\{")
 349
 350                 for vt in self.vt_tables[mclass] do
 351                         if vt == null then
 352                                 v.add_decl("\{-1, NULL\}, /* empty */")
 353                         else
 354                                 var is_null = 0
 355                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 356                                 while bound isa MNullableType do
 357                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 358                                         is_null = 1
 359                                 end
 360                                 v.add_decl("\{{is_null}, (struct class*)&class_{bound.as(MClassType).mclass.c_name}\}, /* {vt} */")
 361                         end
 362                 end
 363                 v.add_decl("\},")
 364                 v.add_decl("\};")
 365                 return true
 366         end
 367
 368         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 369                 if mtype == null then
 370                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 371                         abort
 372                 end
 373                 if mtype isa MVirtualType then
 374                         return mtype.anchor_to(mainmodule, anchor)
 375                 else if mtype isa MParameterType then
 376                         return mtype.anchor_to(mainmodule, anchor)
 377                 else
 378                         return mtype
 379                 end
 380         end
 381
 382         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 383
 384         # Stats
 385
 386         redef fun display_sizes
 387         do
 388                 print "# size of tables"
 389                 print "\trs size\trs hole\tst size\tst hole"
 390                 var rt_table = 0
 391                 var rt_holes = 0
 392                 var st_table = 0
 393                 var st_holes = 0
 394                 var rtables = vt_tables
 395                 for unanch, table in rtables do
 396                         rt_table += table.length
 397                         for e in table do if e == null then rt_holes += 1
 398                 end
 399
 400                 var ttables = class_tables
 401                 for t, table in ttables do
 402                         st_table += table.length
 403                         for e in table do if e == null then st_holes += 1
 404                 end
 405                 print "\t{rt_table}\t{rt_holes}\t{st_table}\t{st_holes}"
 406         end
 407 end
 408
 409 class SeparateErasureCompilerVisitor
 410         super SeparateCompilerVisitor
 411
 412         redef fun compile_callsite(callsite, arguments)
 413         do
 414                 var res = super
 415                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 416                         assert res != null
 417                         var mtype = callsite.msignature.return_mtype
 418                         assert mtype != null
 419                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 420                         var cond = self.type_test(res, mtype, "erasure")
 421                         self.add("if (!{cond}) \{")
 422                         #var x = self.class_name_string(res)
 423                         #var y = self.class_name_string(arguments.first)
 424                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 425                         self.add_abort("Cast failed")
 426                         self.add("\}")
 427                 end
 428                 return res
 429         end
 430
 431         redef fun init_instance(mtype) do return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 432
 433         redef fun type_test(value, mtype, tag)
 434         do
 435                 self.add("/* type test for {value.inspect} isa {mtype} */")
 436
 437                 var res = self.new_var(bool_type)
 438
 439                 var cltype = self.get_name("cltype")
 440                 self.add_decl("int {cltype};")
 441                 var idtype = self.get_name("idtype")
 442                 self.add_decl("int {idtype};")
 443
 444                 var maybe_null = self.maybe_null(value)
 445                 var accept_null = "0"
 446                 if mtype isa MNullableType then
 447                         mtype = mtype.mtype
 448                         accept_null = "1"
 449                 end
 450                 if mtype isa MParameterType then
 451                         # Here we get the bound of the the formal type (eh, erasure...)
 452                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 453                         if mtype isa MNullableType then
 454                                 mtype = mtype.mtype
 455                                 accept_null = "1"
 456                         end
 457                 end
 458
 459                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 460                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 461                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 462                                 self.compiler.count_type_test_skipped[tag] += 1
 463                                 self.add("count_type_test_skipped_{tag}++;")
 464                         end
 465                         return res
 466                 end
 467
 468                 var class_ptr
 469                 var type_table
 470                 if value.mtype.ctype == "val*" then
 471                         class_ptr = "{value}->class->"
 472                 else
 473                         var mclass = value.mtype.as(MClassType).mclass
 474                         class_ptr = "class_{mclass.c_name}."
 475                 end
 476
 477                 if mtype isa MClassType then
 478                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 479                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 480                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 481                                 self.compiler.count_type_test_resolved[tag] += 1
 482                                 self.add("count_type_test_resolved_{tag}++;")
 483                         end
 484                 else if mtype isa MVirtualType then
 485                         var recv = self.frame.arguments.first
 486                         var recv_ptr
 487                         if recv.mtype.ctype == "val*" then
 488                                 recv_ptr = "{recv}->class->"
 489                         else
 490                                 var mclass = recv.mtype.as(MClassType).mclass
 491                                 recv_ptr = "class_{mclass.c_name}."
 492                         end
 493                         var entry = self.get_name("entry")
 494                         self.add("struct vts_entry {entry};")
 495                         if compiler.modelbuilder.toolcontext.opt_phmod_typing.value or compiler.modelbuilder.toolcontext.opt_phand_typing.value then
 496                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 497                         else
 498                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 499                         end
 500                         self.add("{cltype} = {entry}.class->color;")
 501                         self.add("{idtype} = {entry}.class->id;")
 502                         if maybe_null and accept_null == "0" then
 503                                 var is_nullable = self.get_name("is_nullable")
 504                                 self.add_decl("short int {is_nullable};")
 505                                 self.add("{is_nullable} = {entry}.is_nullable;")
 506                                 accept_null = is_nullable.to_s
 507                         end
 508                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 509                                 self.compiler.count_type_test_unresolved[tag] += 1
 510                                 self.add("count_type_test_unresolved_{tag}++;")
 511                         end
 512                 else
 513                         self.debug("type_test({value.inspect}, {mtype})")
 514                         abort
 515                 end
 516
 517                 # check color is in table
 518                 if maybe_null then
 519                         self.add("if({value} == NULL) \{")
 520                         self.add("{res} = {accept_null};")
 521                         self.add("\} else \{")
 522                 end
 523                 if compiler.modelbuilder.toolcontext.opt_phmod_typing.value or compiler.modelbuilder.toolcontext.opt_phand_typing.value then
 524                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 525                 end
 526                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 527                 self.add("{res} = 0;")
 528                 self.add("\} else \{")
 529                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 530                 self.add("\}")
 531                 if maybe_null then
 532                         self.add("\}")
 533                 end
 534
 535                 return res
 536         end
 537
 538         redef fun class_name_string(value)
 539         do
 540                 var res = self.get_name("var_class_name")
 541                 self.add_decl("const char* {res};")
 542                 if value.mtype.ctype == "val*" then
 543                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 544                 else
 545                         self.add "{res} = class_{value.mtype.c_name}.name;"
 546                 end
 547                 return res
 548         end
 549
 550         redef fun array_instance(array, elttype)
 551         do
 552                 var nclass = self.get_class("NativeArray")
 553                 elttype = self.anchor(elttype)
 554                 var arraytype = self.get_class("Array").get_mtype([elttype])
 555                 var res = self.init_instance(arraytype)
 556                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 557                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 558                 nat.is_exact = true
 559                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 560                 for i in [0..array.length[ do
 561                         var r = self.autobox(array[i], self.object_type)
 562                         self.add("((struct instance_{nclass.c_name}*){nat})->values[{i}] = (val*) {r};")
 563                 end
 564                 var length = self.int_instance(array.length)
 565                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 566                 self.check_init_instance(res, arraytype)
 567                 self.add("\}")
 568                 return res
 569         end
 570
 571         redef fun calloc_array(ret_type, arguments)
 572         do
 573                 var ret = ret_type.as(MClassType)
 574                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 575         end
 576 end