src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper?;
  59
  60 kwmodule = 'package'|'module';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwenum = 'universal'|'enum';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 ll = '<<';
 133 gt = '>';
 134 ge = '>=';
 135 gg = '>>';
 136 starship = '<=>';
 137 bang='!';
 138
 139 classid = uppercase letter*;
 140 id = lowercase letter*;
 141 attrid = '_' lowercase letter*;
 142
 143 number = digit+;
 144 float = digit* '.' digit+;
 145 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 146 string = '"' str_body '"';
 147 start_string = '"' str_body '{';
 148 mid_string = '}' str_body '{';
 149 end_string = '}' str_body '"';
 150 bad_char = ''' '\'? any;
 151 bad_string = ('"'|'}') str_body;
 152
 153
 154 /*****************************************************************************/
 155 Ignored Tokens
 156 /*****************************************************************************/
 157
 158 blank;
 159
 160 /*****************************************************************************/
 161 Productions
 162 /*****************************************************************************/
 163
 164 /* MODULES *******************************************************************/
 165 module
 166         = moduledecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 167
 168 moduledecl
 169         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 170
 171 import
 172         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 173         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 174         ;
 175
 176 implicit_top_class {-> classdef}
 177         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 178
 179 implicit_main_class {-> classdef?}
 180         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 181         | {null} n {-> Null}
 182         ;
 183 implicit_main_meth {-> propdef}
 184         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 185         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 186         ;
 187
 188 /* CLASSES *******************************************************************/
 189 classdef
 190         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef], kwend)};
 191 redef {-> kwredef?}
 192         = kwredef? {-> kwredef};
 193 classkind
 194         = {concrete} kwclass
 195         | {abstract} kwabstract kwclass
 196         | {interface} kwinterface
 197         | {enum} kwenum
 198         | {extern} kwextern
 199         ;
 200
 201 formaldefs {-> formaldef*}
 202         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 203 formaldefs_tail {-> formaldef}
 204         = comma no formaldef {-> formaldef};
 205 formaldef
 206         = classid typing? {-> New formaldef(classid, typing.type)};
 207
 208 special {-> superclass}
 209         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 210         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 211         ;
 212
 213 propdefs~toplevel {-> propdef}
 214         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 215         ;
 216 propdef~toplevel {-> propdef}
 217         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 218         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 219 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 220 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 221         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls)}
 222 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 223 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 224 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 225 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 226 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 227 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 228 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls)}
 229         ;
 230 readable {-> able}
 231         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 232         ;
 233 writable {-> able}
 234         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 235         ;
 236 writable2 {-> able}
 237         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 238         ;
 239
 240 visibility
 241         = {public} {-> New visibility.public()}
 242         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 243         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 244         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 245         ;
 246
 247 methid {-> methid}
 248         = {id} id {-> New methid.id(id)}
 249         | {plus} plus {-> New methid.plus(plus)}
 250         | {minus} minus {-> New methid.minus(minus)}
 251         | {star} star {-> New methid.star(star)}
 252         | {slash} slash {-> New methid.slash(slash)}
 253         | {percent} percent {-> New methid.percent(percent)}
 254         | {eq} eq {-> New methid.eq(eq)}
 255         | {ne} ne {-> New methid.ne(ne)}
 256         | {le} le {-> New methid.le(le)}
 257         | {ge} ge {-> New methid.ge(ge)}
 258         | {lt} lt {-> New methid.lt(lt)}
 259         | {gt} gt {-> New methid.gt(gt)}
 260         | {ll} ll {-> New methid.ll(ll)}
 261         | {gg} gg {-> New methid.gg(gg)}
 262         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 263         | {starship} starship {-> New methid.starship(starship)}
 264         | {assign} id assign {-> New methid.assign(id, assign)}
 265         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 266         ;
 267
 268 signature~withret {-> signature}
 269         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 270         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 271 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 272 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 273         ;
 274
 275 signature_noclosures {-> signature}
 276         = params? typing? {-> New signature([params.param], typing.type, [])};
 277
 278 params {-> param*}
 279         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 280         | {empty} opar no cpar {-> []}
 281         ;
 282 params_tail {-> param}
 283         = comma no param {-> param};
 284 param
 285         = {untyped} id {-> New param(id, Null, Null)}
 286         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 287         ;
 288
 289 closure_decls {->closure_decl*}
 290         = no closure_decl+ {-> [closure_decl]};
 291 closure_decl
 292         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 293         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 294         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 295         ;
 296
 297 assign_return{-> expr}
 298         = expr_final {-> New expr.return(Null, expr_final.expr)}
 299         ;
 300
 301 extern_calls {-> extern_calls}
 302         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 303         ;
 304 extern_call_tail {-> extern_call}
 305         = comma no extern_call {-> extern_call};
 306 extern_call {-> extern_call}
 307     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 308     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 309         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 310     ;
 311 extern_call_prop {-> extern_call}
 312     = {local} methid {-> New extern_call.local_prop( methid )}
 313         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 314         | {init} classid {-> New extern_call.init_prop( classid )}
 315         ;
 316 extern_call_cast {-> extern_call}
 317     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 318         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 319         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 320         ;
 321
 322
 323 /* TYPES *********************************************************************/
 324 type~nobra {-> type}
 325         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 326 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 327         ;
 328 types {-> type*}
 329         = type types_tail* {-> [type, types_tail.type]};
 330 types_tail {-> type}
 331         = comma no type {-> type};
 332 typing {-> type}
 333         = column no type {-> type};
 334
 335 /* STATMENTS *****************************************************************/
 336 stmtso~withelse~withend {-> expr?}
 337         = {block} n stmtsnend {-> stmtsnend.expr}
 338         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 339         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 340 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 341         ;
 342 stmts {-> expr}
 343         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 344 stmtsn {-> expr}
 345         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 346 stmtsnend {-> expr}
 347         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 348 stmts_tail {-> expr}
 349         = n stmt {-> stmt.expr};
 350 stmt~withelse {-> expr}
 351         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 352         | {assign} assignment~withelse {-> assignment~withelse.expr}
 353         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 354         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 355         | {abort} kwabort {-> New expr.abort(kwabort)}
 356         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 357         | {do} do~withelse {-> do~withelse.expr}
 358         | {if} if~withelse {-> if~withelse.expr}
 359         | {while} while~withelse {-> while~withelse.expr}
 360         | {loop} loop~withelse {-> loop~withelse.expr}
 361         | {for} for~withelse {-> for~withelse.expr}
 362         | {assert} assert~withelse {-> assert~withelse.expr}
 363         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 364         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 365         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 366         ;
 367
 368 label= kwlabel id;
 369
 370 closure_defs~withelse {-> closure_def*}
 371         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 372         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 373         ;
 374
 375 closure_def_last~withelse {-> closure_def}
 376         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 377         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 378         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 379         ;
 380
 381 closure_def {-> closure_def}
 382         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 383         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 384         ;
 385 closure_id
 386         = {simple} id
 387         | {break} kwbreak
 388         ;
 389
 390 assign_continue~withelse{-> expr}
 391         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 392         ;
 393
 394 vardecl~withelse{-> expr}
 395         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 396         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 397         ;
 398
 399 assignment~withelse {-> expr}
 400         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 401         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 402         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 403         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 404         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 405         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 406         ;
 407 assign_op
 408         = {plus} pluseq
 409         | {minus} minuseq
 410         ;
 411
 412 do~withelse {-> expr}
 413         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 414         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 415         ;
 416
 417 if~withelse {-> expr}
 418         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 419 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 420 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 421 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 422         ;
 423 elsepartblock {-> expr?}
 424         = {else} kwelse stmtso {-> stmtso.expr}
 425         | {empty} kwend {-> New expr.block([], kwend)}
 426         ;
 427
 428 loop~withelse {-> expr}
 429         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 430         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 431         ;
 432
 433 while~withelse {-> expr}
 434         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 435         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 436         ;
 437
 438 for~withelse {-> expr}
 439         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 440         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 441         ;
 442
 443 assert~withelse {-> expr}
 444         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 445 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 446         ;
 447 assertid {-> id}
 448         = id column {-> id};
 449
 450 /* EXPRESSIONS ***************************************************************/
 451 expr_final~nopar~withelse~nobra {-> expr}
 452         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 453         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 454 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 455         ;
 456
 457 expr~nopar~nobra {-> expr}
 458         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 459         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 460         ;
 461
 462 expr_and~nopar~nobra {-> expr}
 463         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 464         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 465         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 466         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 467         ;
 468
 469 expr_not~nopar~nobra {-> expr}
 470         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 471         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 472         ;
 473
 474 expr_eq~nopar~nobra {-> expr}
 475         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 476         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 477         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 478         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 479         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 480         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 481         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 482         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 483         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 484         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 485         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 486         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 487         ;
 488
 489 expr_add~nopar~nobra {-> expr}
 490         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 491         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 492         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 493         ;
 494
 495 expr_mul~nopar~nobra {-> expr}
 496         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 497         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 498         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 499         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 500         ;
 501
 502 expr_minus~nopar~nobra {-> expr}
 503         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 504         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 505         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 506         ;
 507
 508 expr_new~nopar~nobra {-> expr}
 509         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 510         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 511         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 512         ;
 513
 514 expr_atom~nopar~nobra {-> expr}
 515         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 516         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 517         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 518         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 519 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, [braargs.expr], [])}
 520         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 521 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 522 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(obra, expr, expr2.expr, cbra)}
 523 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(obra, expr, expr2.expr, cbra)}
 524 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 525         | {self} kwself {-> New expr.self(kwself)}
 526         | {true} kwtrue {-> New expr.true(kwtrue)}
 527         | {false} kwfalse {-> New expr.false(kwfalse)}
 528         | {null} kwnull {-> New expr.null(kwnull)}
 529         | {int} number  {-> New expr.int(number)}
 530         | {float} float  {-> New expr.float(float)}
 531         | {char} char  {-> New expr.char(char)}
 532         | {string} string  {-> New expr.string(string)}
 533         | {superstring} superstring  {-> superstring.expr}
 534 !nopar  | {par} opar expr cpar {-> New expr.par(opar, expr, cpar)}
 535         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 536         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 537         ;
 538
 539 superstring {-> expr}
 540         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 541 superstring_start {-> expr*}
 542         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 543 start_string_p {-> expr}
 544         = start_string {-> New expr.start_string(start_string)};
 545 superstring_middle {-> expr*}
 546         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 547 mid_string_p {-> expr}
 548         = mid_string {-> New expr.mid_string(mid_string)};
 549 superstring_end {-> expr}
 550         = end_string {-> New expr.end_string(end_string)};
 551
 552 /* MISC **********************************************************************/
 553
 554 recv~nopar~nobra {-> expr}
 555         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 556         | {implicit} {-> New expr.implicit_self()}
 557         ;
 558
 559 args {-> expr*}
 560         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 561         | {emptypar} opar no cpar {-> []}
 562         | {empty} {-> []}
 563         ;
 564 args_nopar {-> expr*}
 565         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 566         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 567         | {emptypar} opar no cpar {-> []}
 568         | {empty} {-> []}
 569         ;
 570 braargs {-> expr*}
 571         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 572 args_tail {-> expr}
 573         = comma no expr [n2]:no {-> expr};
 574 idlist {-> id*}
 575         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 576         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 577         ;
 578 idlist_nopar {-> id*}
 579         = {single} id {-> [id]}
 580         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 581         ;
 582
 583 module_name {-> module_name}
 584         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 585         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 586         ;
 587
 588 qualified
 589         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 590         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 591         ;
 592 modquad {-> id}
 593         = id quad no {-> id};
 594 classquad {-> classid}
 595         = classid quad no {-> classid};
 596
 597 n1      = {a} comment | {b} eol;
 598 n {-> doc?}
 599         = {a} n2? comment+ {-> New doc([comment])}
 600         | {b} n2 {-> Null}
 601         ;
 602 no {-> doc?}
 603         = {empty} {-> Null}
 604         | n {-> n.doc}
 605         ;
 606
 607 n2
 608         = {a} n2? comment+ eol+
 609         | {b} eol+
 610         ;
 611
 612 /*****************************************************************************/
 613 Abstract Syntax Tree
 614 /*****************************************************************************/
 615
 616 module  = moduledecl? [imports]:import* [classdefs]:classdef*;
 617
 618 moduledecl
 619         = doc? kwmodule [name]:module_name;
 620
 621 import  = {std} visibility kwimport [name]:module_name
 622         | {no} visibility kwimport kwend
 623         ;
 624
 625 visibility
 626         = {public}
 627         | {private} kwprivate
 628         | {protected} kwprotected
 629         | {intrude} kwintrude
 630         ;
 631
 632 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef* kwend
 633         | {top} [propdefs]:propdef*
 634         | {main} [propdefs]:propdef*
 635         ;
 636 classkind
 637         = {concrete} kwclass
 638         | {abstract} kwabstract kwclass
 639         | {interface} kwinterface
 640         | {enum} kwenum
 641         | {extern} kwextern
 642         ;
 643 formaldef = [id]:classid type?;
 644 superclass = kwspecial? kwsuper? type;
 645
 646
 647 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 648         | {meth} doc? kwredef? visibility methid signature
 649         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 650         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 651         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls?
 652         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 653         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 654         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls?
 655         | {main_meth} kwredef? [block]:expr?
 656         | {type} doc? kwredef? visibility kwtype [id]:classid type
 657         ;
 658
 659 able    = {read} kwredef? kwreadable
 660         | {write} kwredef? visibility? kwwritable
 661         ;
 662
 663 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 664
 665 signature = [params]:param* type? [closure_decls]:closure_decl*;
 666
 667 param   = id type? dotdotdot?
 668         ;
 669
 670 closure_decl = kwbreak? bang id signature expr?
 671         ;
 672
 673 type    = kwnullable? [id]:classid [types]:type*;
 674
 675 label = kwlabel id;
 676
 677 expr    = {block} expr* kwend?
 678         | {vardecl} kwvar id type? assign? expr?
 679         | {return} kwreturn? expr?
 680         | {break} kwbreak label? expr?
 681         | {abort} kwabort
 682         | {continue} kwcontinue? label? expr?
 683         | {do} kwdo [block]:expr? label?
 684         | {if} kwif expr [then]:expr? [else]:expr?
 685         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 686         | {while} kwwhile expr kwdo [block]:expr? label?
 687         | {loop} kwloop [block]:expr? label?
 688         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 689         | {assert} kwassert id? expr [else]:expr?
 690         | {once} kwonce expr
 691         | {send} expr
 692         | {binop} expr [expr2]:expr
 693         | {or} expr [expr2]:expr
 694         | {and} expr [expr2]:expr
 695         | {or_else} expr [expr2]:expr
 696         | {not} kwnot expr
 697         | {eq} expr [expr2]:expr
 698         | {ee} expr [expr2]:expr
 699         | {ne} expr [expr2]:expr
 700         | {lt} expr [expr2]:expr
 701         | {le} expr [expr2]:expr
 702         | {ll} expr [expr2]:expr
 703         | {gt} expr [expr2]:expr
 704         | {ge} expr [expr2]:expr
 705         | {gg} expr [expr2]:expr
 706         | {isa} expr type
 707         | {plus} expr [expr2]:expr
 708         | {minus} expr [expr2]:expr
 709         | {starship} expr [expr2]:expr
 710         | {star} expr [expr2]:expr
 711         | {slash} expr [expr2]:expr
 712         | {percent} expr [expr2]:expr
 713         | {uminus} minus expr
 714         | {new} kwnew type id? [args]:expr*
 715         | {attr} expr [id]:attrid
 716         | {attr_assign} expr [id]:attrid assign [value]:expr
 717         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 718         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 719         | {call_assign} expr id [args]:expr* assign [value]:expr
 720         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 721         | {super} qualified? kwsuper [args]:expr*
 722         | {init} expr kwinit [args]:expr*
 723         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 724         | {bra_assign} expr [args]:expr* assign [value]:expr
 725         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 726         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 727         | {var} id
 728         | {var_assign} id assign [value]:expr
 729         | {var_reassign} id assign_op [value]:expr
 730         | {range} expr [expr2]:expr
 731         | {crange} obra expr [expr2]:expr cbra
 732         | {orange} obra expr [expr2]:expr [cbra]:obra
 733         | {array} [exprs]:expr*
 734         | {self} kwself
 735         | {implicit_self}
 736         | {true} kwtrue
 737         | {false} kwfalse
 738         | {null} kwnull
 739         | {int} number
 740         | {float} float
 741         | {char} char
 742         | {string} string
 743         | {start_string} [string]:start_string
 744         | {mid_string} [string]:mid_string
 745         | {end_string} [string]:end_string
 746         | {superstring} [exprs]:expr*
 747         | {par} opar expr cpar
 748         | {as_cast} expr kwas opar type cpar
 749         | {as_notnull} expr kwas opar kwnot kwnull cpar
 750         | {isset_attr} kwisset expr [id]:attrid
 751         ;
 752 assign_op
 753         = {plus} pluseq
 754         | {minus} minuseq
 755         ;
 756
 757 closure_def
 758         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 759         ;
 760 closure_id
 761         = {simple} id
 762         | {break} kwbreak
 763         ;
 764
 765 module_name = quad? [path]:id* id;
 766 extern_calls = kwimport [extern_calls]:extern_call*
 767         ;
 768 extern_call =
 769         | {super} kwsuper
 770         | {local_prop} methid
 771         | {full_prop} classid quad? methid
 772         | {init_prop} classid
 773         | {cast_as} [from_type]:type kwas [to_type]:type
 774         | {as_nullable} type kwas kwnullable
 775         | {as_not_nullable} type kwas kwnot kwnullable
 776         ;
 777
 778 qualified = id* classid? ;
 779
 780 doc = comment+;
 781
 782 /*****************************************************************************/
 783