contrib/github_merge.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Query the Github PR API to perform a merge
  16 module github_merge
  17
  18 import github::github_curl
  19 import template
  20 import opts
  21
  22 redef class Object
  23         # Factorize cast
  24         fun json_as_a: JsonArray do return self.as(JsonArray)
  25         # Factorize cast
  26         fun json_as_map: JsonObject do return self.as(JsonObject)
  27 end
  28
  29 redef class GithubCurl
  30         # Get a given pull request (PR)
  31         fun getpr(repo: String, number: Int): nullable JsonObject
  32         do
  33                 var ir = get_and_check("https://api.github.com/repos/{repo}/issues/{number}")
  34                 var irm = ir.json_as_map
  35                 if not irm.has_key("pull_request") then return null
  36                 var pr = get_and_check("https://api.github.com/repos/{repo}/pulls/{number}")
  37                 var prm = pr.json_as_map
  38                 var sha = prm["head"].json_as_map["sha"].to_s
  39                 var statuses = get_and_check("https://api.github.com/repos/{repo}/commits/{sha}/status")
  40                 statuses = statuses.json_as_map
  41                 prm["statuses"] = statuses
  42                 print "{prm["title"].to_s}: by {prm["user"].json_as_map["login"].to_s} (# {prm["number"].to_s})"
  43                 var mergeable = prm["mergeable"]
  44                 if mergeable != null then
  45                         print "\tmergeable: {mergeable.to_s}"
  46                 else
  47                         print "\tmergeable: unknown"
  48                 end
  49                 var state = statuses["state"]
  50                 if state == null then
  51                         print "\tstatus: not tested"
  52                 else
  53                         print "\tstatus: {state}"
  54                         var sts = statuses["statuses"].json_as_a
  55                         for st in sts do
  56                                 st = st.json_as_map
  57                                 var ctx = st["context"].to_s
  58                                 state = st["state"].to_s
  59                                 print "\tstatus {ctx}: {state}"
  60                         end
  61                 end
  62                 return prm
  63         end
  64
  65         # Get reviewers of a PR
  66         fun getrev(repo: String, pr: JsonObject): Array[String]
  67         do
  68                 var number = pr["number"].as(Int)
  69                 var user = pr["user"].json_as_map["login"].as(String)
  70                 var comments = new Array[nullable Object]
  71                 comments.add_all(get_and_check("https://api.github.com/repos/{repo}/issues/{number}/comments").json_as_a)
  72                 comments.add_all(get_and_check("https://api.github.com/repos/{repo}/pulls/{number}/comments").json_as_a)
  73                 var logins = new Array[String]
  74                 for c in comments do
  75                         var cm = c.json_as_map
  76                         var l = cm["user"].json_as_map["login"]
  77                         assert l isa String
  78                         if l != user and not logins.has(l) then logins.add(l)
  79                 end
  80                 var res = new Array[String]
  81                 for l in logins do
  82                         var u = get_and_check("https://api.github.com/users/{l}").json_as_map
  83                         if not u.has_key("name") or u["name"] == null or not u.has_key("email")or u["email"] == null then
  84                                 print "No public name/email for user {l}"
  85                                 continue
  86                         end
  87                         var r = "{u["name"].to_s} <{u["email"].to_s}>"
  88                         res.add r
  89
  90                 end
  91                 return res
  92         end
  93
  94 end
  95
  96 if "NIT_TESTING".environ == "true" then exit 0
  97
  98 var opt_repo = new OptionString("Repository (e.g. nitlang/nit)", "-r", "--repo")
  99 var opt_auth = new OptionString("OAuth token", "--auth")
 100 var opt_query = new OptionString("Query to get issues (e.g. label=ok_will_merge)", "-q", "--query")
 101 var opt_keepgoing = new OptionBool("Skip merge conflicts", "-k", "--keep-going")
 102 var opt_all = new OptionBool("Merge all", "-a", "--all")
 103 var opts = new OptionContext
 104 opts.add_option(opt_repo, opt_auth, opt_query, opt_all, opt_keepgoing)
 105
 106 opts.parse(sys.args)
 107 var args = opts.rest
 108
 109 var auth = opt_auth.value or else ""
 110 if auth == "" then auth = get_github_oauth
 111 if auth == "" then
 112         print "Warning: no github oauth token, you can configure one with"
 113         print "    git config --add github.oauthtoken MYOAUTHTOKEN"
 114 end
 115
 116 var repo = opt_repo.value or else "nitlang/nit"
 117
 118 var query = opt_query.value or else "labels=ok_will_merge"
 119
 120 var curl = new GithubCurl(auth, "Merge-o-matic (nitlang/nit)")
 121
 122 if args.is_empty then
 123         # Without args, list `ok_will_merge`
 124         var x = curl.get_and_check("https://api.github.com/repos/{repo}/issues?{query}")
 125         var list = new Array[String]
 126         for y in x.json_as_a do
 127                 var number = y.json_as_map["number"].as(Int)
 128                 var pr = curl.getpr(repo, number)
 129                 if pr == null then continue
 130                 list.add number.to_s
 131         end
 132
 133         if not opt_all.value then return
 134         args = list
 135 end
 136
 137 for arg in args do
 138         # With a arg, merge the PR
 139         var number = arg.to_i
 140         var pr = curl.getpr(repo, number)
 141         if pr == null then
 142                 print "Not a PR: {number}"
 143                 return
 144         end
 145         var revs = curl.getrev(repo, pr)
 146
 147         var mergemsg = new Template
 148         mergemsg.add "Merge: {pr["title"].to_s}\n\n"
 149         mergemsg.add "{pr["body"].to_s}\n\n"
 150         mergemsg.add "Pull-Request: #{pr["number"].to_s}\n"
 151         for r in revs do
 152                 mergemsg.add "Reviewed-by: {r}\n"
 153         end
 154         mergemsg.write_to_file("mergemsg")
 155
 156         var sha = pr["head"].json_as_map["sha"].as(String)
 157         if system("git show -s --pretty=format:%h {sha}") != 0 then
 158                 print "Commit {sha} not in local repository; did you fetch github?"
 159                 return
 160         end
 161         if system("git merge-base --is-ancestor {sha} HEAD") == 0 then
 162                 print "Is already merged."
 163                 continue
 164         end
 165         if system("git merge --no-ff --no-commit {sha}") != 0 then
 166                 if opt_keepgoing.value then
 167                          system("git reset --merge")
 168                          continue
 169                 end
 170                 system("cp mergemsg `git rev-parse --git-dir`/MERGE_MSG")
 171                 print "Problem during merge... Let's do the commit manually."
 172                 return
 173         end
 174         system("git commit -F mergemsg")
 175         print "The merge is made"
 176         mergemsg.write_to(stdout)
 177 end
 178