lib/serialization/serialization.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Abstract services to serialize Nit objects to different formats
  18 #
  19 # This module declares the `serialize` annotation to mark Nit classes as serializable.
  20 # For an introduction to this service, refer to the documentation of the `serialization` group.
  21 # This documentation provides more technical information on interesting entitie of this module.
  22 #
  23 # Interesting entities for end users of serializable classes:
  24 #
  25 # * Serialize an instance subclass of `Serializable` with either
  26 #   `Serializer::serializable` and `Serializable::serialize`.
  27 # * Deserialize an object using `Deserializer::deserialize`.
  28 #   The object type must the be checked with an `assert` or otherwise.
  29 #
  30 # Interesting entities to create custom serializable classes:
  31 #
  32 # * Subclass `Serializable` to declare a class as serializable and to customize
  33 #   the serialization and deserialization behavior.
  34 # * Redefine `Serializable::core_serialize_to` to customize the serialization
  35 #   of the receiver class.
  36 # * Redefine `Deserializer::deserialize_class` to customize the deserialization
  37 #   of a specific class by name.
  38 #
  39 # Interesting entities for serialization format:
  40 #
  41 # * Subclass `Serializer` and `Deserializer` with custom serices.
  42 # * In `Serializer`, `serialize` and `serialize_reference` must be redefined.
  43 # * In `Deserializer`; `deserialize`, `deserialize_attribute and
  44 #   `notify_of_creation` must be redefined.
  45 module serialization is
  46         new_annotation auto_serializable
  47         new_annotation serialize
  48         new_annotation noserialize
  49         new_annotation serialize_as
  50 end
  51
  52 # Abstract serialization service to be sub-classed by specialized services.
  53 interface Serializer
  54         # Entry point method of this service, serialize the `object`
  55         #
  56         # This method, and refinements, should handle `null` and probably
  57         # use double dispatch to customize the bahavior per serializable objects.
  58         fun serialize(object: nullable Serializable) is abstract
  59
  60         # Serialize an object, with full serialization or a simple reference
  61         protected fun serialize_reference(object: Serializable) is abstract
  62
  63         # Serialize an attribute to compose a serializable object
  64         #
  65         # This method should be called from `Serializable::core_serialize_to`.
  66         fun serialize_attribute(name: String, value: nullable Object)
  67         do
  68                 if not try_to_serialize(value) then
  69                         warn("argument {name} of type {value.class_name} is not serializable.")
  70                 end
  71         end
  72
  73         # Serialize `value` is possie, i.e. it is `Serializable` or `null`
  74         fun try_to_serialize(value: nullable Object): Bool
  75         do
  76                 if value isa Serializable then
  77                         value.serialize_to_or_delay(self)
  78                 else if value == null then
  79                         serialize value
  80                 else return false
  81                 return true
  82         end
  83
  84         # Warn of problems and potential errors (such as if an attribute
  85         # is not serializable)
  86         fun warn(msg: String) do print "Serialization warning: {msg}"
  87 end
  88
  89 # Abstract deserialization service
  90 #
  91 # After initialization of one of its sub-classes, call `deserialize`
  92 abstract class Deserializer
  93         # Main method of this class, returns a Nit object
  94         fun deserialize: nullable Object is abstract
  95
  96         # Internal method to be implemented by sub-classes
  97         fun deserialize_attribute(name: String): nullable Object is abstract
  98
  99         # Internal method called by objects in creation,
 100         # to be implemented by sub-classes
 101         fun notify_of_creation(new_object: Object) is abstract
 102
 103         # Deserialize the next available object as an instance of `class_name`
 104         #
 105         # Returns the deserialized object on success, aborts on error.
 106         #
 107         # This method should be redefined for each custom subclass of `Serializable`.
 108         # All refinement should look for a precise `class_name` and call super
 109         # on unsupported classes.
 110         protected fun deserialize_class(class_name: String): nullable Object do
 111                 if class_name == "Error" then return new Error.from_deserializer(self)
 112                 return deserialize_class_intern(class_name)
 113         end
 114
 115         # Generated service to deserialize the next available object as an instance of `class_name`
 116         #
 117         # Refinements to this method will be generated by the serialization phase.
 118         # To avoid conflicts, there should not be any other refinements to this method.
 119         # You can instead use `deserialize_class`.
 120         protected fun deserialize_class_intern(class_name: String): nullable Object do
 121                 errors.add new Error("Deserialization Error: Doesn't know how to deserialize class \"{class_name}\"")
 122                 return null
 123         end
 124
 125         # Should `self` keep trying to deserialize an object after an error?
 126         #
 127         # This behavior takes effect after each attribute deserialization with
 128         # errors such as a missing attribute or the value is of the wrong type.
 129         # If `keep_going`, the attribute will be skipped but the engine will
 130         # deserialize the next attribute.
 131         # If `not keep_going`, the engine stops deserializing right away.
 132         #
 133         # When at `true`, this may cause the accumulation of a lot of entries in `errors`.
 134         #
 135         # Default at `true`.
 136         var keep_going: nullable Bool = null is writable
 137
 138         # Errors encountered in the last call to `deserialize`
 139         var errors = new Array[Error]
 140 end
 141
 142 # Deserialization got wrong attribute names
 143 class AttributeTypeError
 144         super Error
 145
 146         # Parent object of the problematic attribute
 147         var receiver: Object
 148
 149         # Name of the problematic attribute in `receiver`
 150         var attribute_name: String
 151
 152         # Deserialized object that isn't of the `expected_type`
 153         var attribute: nullable Object
 154
 155         # Name of the type expected for `attribute`
 156         var expected_type: String
 157
 158         redef fun to_s
 159         do
 160                 var attribute = attribute
 161                 var found_type = if attribute != null then attribute.class_name else "null"
 162
 163                 return "Deserialization Error: {
 164                 }Wrong type on `{receiver.class_name}::{attribute_name}` expected `{expected_type}`, got `{found_type}`"
 165         end
 166 end
 167
 168 # Instances of this class can be passed to `Serializer::serialize`
 169 interface Serializable
 170         # Serialize `self` to `serializer`
 171         #
 172         # This is a shortcut to `Serializer::serialize`.
 173         fun serialize_to(serializer: Serializer) do serializer.serialize(self)
 174
 175         # Actual serialization of `self` to `serializer`
 176         #
 177         # This writes the full data of `self` to `serializer`.
 178         #
 179         # This method can be redefined in sub classes and refinements.
 180         # It should use `Serializer::serialize_attribute` to to register real or
 181         # logical attributes.
 182         #
 183         # Any refinement should have its equivalent refinement of
 184         # `Deserializer::deserialize_class` to support this custom deserialization.
 185         fun core_serialize_to(serializer: Serializer) do end
 186
 187         # Accept references or force direct serialization (using `serialize_to`)
 188         #
 189         # The subclass change the default behavior, which will accept references,
 190         # to force to always serialize copies of `self`.
 191         private fun serialize_to_or_delay(v: Serializer) do v.serialize_reference(self)
 192
 193         # Create an instance of this class from the `deserializer`
 194         #
 195         # This constructor is refined by subclasses to correctly build their instances.
 196         init from_deserializer(deserializer: Deserializer) is nosuper do end
 197 end
 198
 199 redef interface Object
 200         # Is `self` the same as `other` in a serialization context?
 201         #
 202         # Used to determine if an object has already been serialized.
 203         fun is_same_serialized(other: nullable Object): Bool do return is_same_instance(other)
 204
 205         # Hash value use for serialization
 206         #
 207         # Used in combination with `is_same_serialized`. If two objects are the same
 208         # in a serialization context, they must have the same `serialization_hash`.
 209         fun serialization_hash: Int do return object_id
 210 end
 211
 212 # Instances of this class are not delayed and instead serialized immediately
 213 # This applies mainly to `universal` types
 214 interface DirectSerializable
 215         super Serializable
 216
 217         redef fun serialize_to_or_delay(v) do serialize_to(v)
 218 end
 219
 220 redef class Bool super DirectSerializable end
 221 redef class Char super DirectSerializable end
 222 redef class Int super DirectSerializable end
 223 redef class Float super DirectSerializable end
 224 redef class NativeString super DirectSerializable end
 225 redef class Text super DirectSerializable end
 226 redef class SimpleCollection[E] super Serializable end
 227 redef class Map[K, V] super Serializable end
 228
 229 redef class Couple[F, S]
 230         super Serializable
 231
 232         redef init from_deserializer(v)
 233         do
 234                 v.notify_of_creation self
 235                 var first = v.deserialize_attribute("first")
 236                 var second = v.deserialize_attribute("second")
 237                 init(first, second)
 238         end
 239
 240         redef fun core_serialize_to(v)
 241         do
 242                 v.serialize_attribute("first", first)
 243                 v.serialize_attribute("second", second)
 244         end
 245 end
 246
 247 redef class Ref[E]
 248         super Serializable
 249
 250         redef init from_deserializer(v)
 251         do
 252                 v.notify_of_creation self
 253                 var item = v.deserialize_attribute("item")
 254                 init item
 255         end
 256
 257         redef fun core_serialize_to(v)
 258         do
 259                 v.serialize_attribute("item", first)
 260         end
 261 end
 262
 263 redef class Error
 264         super Serializable
 265
 266         redef init from_deserializer(v)
 267         do
 268                 v.notify_of_creation self
 269
 270                 var message = v.deserialize_attribute("message")
 271                 if not message isa String then message = ""
 272                 init message
 273
 274                 var cause = v.deserialize_attribute("cause")
 275                 if cause isa nullable Error then self.cause = cause
 276         end
 277
 278         redef fun core_serialize_to(v)
 279         do
 280                 v.serialize_attribute("message", message)
 281                 v.serialize_attribute("cause", cause)
 282         end
 283 end