lib/android/input_events.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Copyright 2012-2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Pointer and hardware key events
  18 module input_events
  19
  20 import mnit_input
  21 import android
  22
  23 in "C header" `{
  24         #include <android/log.h>
  25         #include <android_native_app_glue.h>
  26
  27         #define LOGW(...) ((void)__android_log_print(ANDROID_LOG_WARN, "mnit", __VA_ARGS__))
  28         #ifdef DEBUG
  29                 #define LOGI(...) ((void)__android_log_print(ANDROID_LOG_INFO, "mnit", __VA_ARGS__))
  30         #else
  31                 #define LOGI(...) (void)0
  32         #endif
  33 `}
  34
  35 in "C" `{
  36         /* Handle inputs from the Android platform and sort them before
  37            sending them in the Nit App */
  38         static int32_t mnit_handle_input(struct android_app* app, AInputEvent* event) {
  39                 App nit_app = app->userData;
  40                 LOGI("handle input %i", (int)pthread_self());
  41                 if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_KEY) {
  42                         LOGI("key");
  43                         return App_native_input_key(nit_app, event);
  44                 }
  45                 else if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_MOTION) {
  46                         LOGI("motion");
  47                         return App_native_input_motion(nit_app, event);
  48                 }
  49
  50                 return 0;
  51         }
  52 `}
  53
  54 private extern class NativeAndroidMotionEvent `{AInputEvent *`}
  55
  56         fun pointers_count: Int `{
  57                 return AMotionEvent_getPointerCount(self);
  58         `}
  59
  60         # Did this motion event just started?
  61         fun just_went_down: Bool `{
  62                 return (AMotionEvent_getAction(self) & AMOTION_EVENT_ACTION_MASK) == AMOTION_EVENT_ACTION_DOWN;
  63         `}
  64
  65         fun edge: Int `{
  66                 return AMotionEvent_getEdgeFlags(self);
  67         `}
  68
  69         # Get the non-primary pointer id that just went down (returns -1 or > 0)
  70         fun index_down_pointer: Int `{
  71                 int a = AMotionEvent_getAction(self);
  72                 if ((a & AMOTION_EVENT_ACTION_MASK) == AMOTION_EVENT_ACTION_POINTER_DOWN)
  73                         return (a & AMOTION_EVENT_ACTION_POINTER_INDEX_MASK) >> AMOTION_EVENT_ACTION_POINTER_INDEX_SHIFT;
  74                 else return -1;
  75         `}
  76
  77         fun action: AMotionEventAction `{ return AMotionEvent_getAction(self); `}
  78 end
  79
  80 private extern class AMotionEventAction `{ int32_t `}
  81         fun action: Int `{ return self & AMOTION_EVENT_ACTION_MASK; `}
  82
  83         fun is_down: Bool do return action == 0
  84         fun is_up: Bool do return action == 1
  85         fun is_move: Bool do return action == 2
  86         fun is_cancel: Bool do return action == 3
  87         fun is_outside: Bool do return action == 4
  88         fun is_pointer_down: Bool do return action == 5
  89         fun is_pointer_up: Bool do return action == 6
  90 end
  91
  92 # An input event on Android
  93 interface AndroidInputEvent
  94         super InputEvent
  95 end
  96
  97 # A motion event concerning a single or more `pointers`
  98 class AndroidMotionEvent
  99         super AndroidInputEvent
 100         super MotionEvent
 101
 102         private var native: NativeAndroidMotionEvent
 103
 104         # Pointers (or fingers) composing this motion event
 105         var pointers: Array[AndroidPointerEvent] is lazy do
 106                 return [for i in native.pointers_count.times do new AndroidPointerEvent(self, i)]
 107         end
 108
 109         redef fun just_went_down: Bool do return native.just_went_down
 110
 111         # Was the top edge of the screen intersected by this event?
 112         fun touch_to_edge: Bool do return native.edge == 1
 113
 114         # Was the bottom edge of the screen intersected by this event?
 115         fun touch_bottom_edge: Bool do return native.edge == 2
 116
 117         # Was the left edge of the screen intersected by this event?
 118         fun touch_left_edge: Bool do return native.edge == 4
 119
 120         # Was the right edge of the screen intersected by this event?
 121         fun touch_right_edge: Bool do return native.edge == 8
 122
 123         redef fun down_pointer: nullable AndroidPointerEvent
 124         do
 125                 if just_went_down then
 126                         # The primary pointer went down
 127                         return pointers[0]
 128                 end
 129
 130                 var i = native.index_down_pointer
 131                 if i > 0 then
 132                         # A secondary pointer went down
 133                         return pointers[i]
 134                 else
 135                         return null
 136                 end
 137         end
 138 end
 139
 140 # A pointer event
 141 class AndroidPointerEvent
 142         super PointerEvent
 143         super AndroidInputEvent
 144
 145         private var motion_event: AndroidMotionEvent
 146
 147         private var pointer_index: Int
 148
 149         redef fun x: Float do return native_x(motion_event.native, pointer_index)
 150
 151         private fun native_x(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 152                 return AMotionEvent_getX(motion_event, pointer_index);
 153         `}
 154
 155         redef fun y: Float do return native_y(motion_event.native, pointer_index)
 156
 157         private fun native_y(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 158                 return AMotionEvent_getY(motion_event, pointer_index);
 159         `}
 160
 161         # Pressure applied by this pointer
 162         fun pressure: Float do return native_pressure(motion_event.native, pointer_index)
 163
 164         private fun native_pressure(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 165                 return AMotionEvent_getPressure(motion_event, pointer_index);
 166         `}
 167
 168         redef fun pressed
 169         do
 170                 var action = motion_event.native.action
 171                 return action.is_down or action.is_move
 172         end
 173
 174         redef fun depressed do return not pressed
 175
 176         # Does this pointer just began touching the screen?
 177         fun just_went_down: Bool
 178         do
 179                 return motion_event.down_pointer == self
 180         end
 181
 182         # Unique id of this pointer since the beginning of the gesture
 183         fun pointer_id: Int do return native_pointer_id(motion_event.native, pointer_index)
 184
 185         private fun native_pointer_id(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Int `{
 186                 return AMotionEvent_getPointerId(motion_event, pointer_index);
 187         `}
 188 end
 189
 190 # An hardware key event
 191 extern class AndroidKeyEvent `{AInputEvent *`}
 192         super KeyEvent
 193         super AndroidInputEvent
 194
 195         private fun action: Int `{ return AKeyEvent_getAction(self); `}
 196
 197         redef fun is_down: Bool do return action == 0
 198         redef fun is_up: Bool do return action == 1
 199
 200         # Hardware code of the key raising this event
 201         fun key_code: Int `{ return AKeyEvent_getKeyCode(self); `}
 202
 203         redef fun to_c `{
 204                 int code = AKeyEvent_getKeyCode(self);
 205                 if (code >= AKEYCODE_0 && code <= AKEYCODE_9)
 206                         return '0'+code-AKEYCODE_0;
 207                 if (code >= AKEYCODE_A && code <= AKEYCODE_Z)
 208                         return 'a'+code-AKEYCODE_A;
 209                 return 0;
 210         `}
 211
 212         redef fun name do return key_code.to_s
 213
 214         # Was this event raised by the back key?
 215         fun is_back_key: Bool do return key_code == 4
 216
 217         # Was this event raised by the menu key?
 218         fun is_menu_key: Bool do return key_code == 82
 219
 220         # Was this event raised by the search key?
 221         fun is_search_key: Bool do return key_code == 84
 222
 223         # Was this event raised by the volume up key?
 224         fun is_volume_up: Bool do return key_code == 24
 225
 226         # Was this event raised by the volume down key?
 227         fun is_volume_down: Bool do return key_code == 25
 228 end
 229
 230 redef class App
 231
 232         redef fun init_window
 233         do
 234                 set_as_input_handler native_app_glue
 235                 super
 236         end
 237
 238         private fun set_as_input_handler(app_glue: NativeAppGlue)
 239         import native_input_key, native_input_motion `{
 240                 app_glue->onInputEvent = mnit_handle_input;
 241         `}
 242
 243         # these are used as a callback from native to type incoming events
 244         private fun native_input_key(event: AndroidKeyEvent): Bool is abstract
 245
 246         private fun native_input_motion(event: NativeAndroidMotionEvent): Bool is abstract
 247 end