src/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure: OptionBool = new OptionBool("Erase generic types", "--erasure")
  24         # --no-check-erasure-cast
  25         var opt_no_check_erasure_cast: OptionBool = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  26
  27         redef init
  28         do
  29                 super
  30                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast)
  31         end
  32 end
  33
  34 redef class ModelBuilder
  35         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: RapidTypeAnalysis)
  36         do
  37                 var time0 = get_time
  38                 self.toolcontext.info("*** COMPILING TO C ***", 1)
  39
  40                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  41                 compiler.compile_header
  42
  43                 # compile class structures
  44                 compiler.new_file
  45                 for m in mainmodule.in_importation.greaters do
  46                         for mclass in m.intro_mclasses do
  47                                 compiler.compile_class_to_c(mclass)
  48                         end
  49                 end
  50
  51                 # The main function of the C
  52                 compiler.new_file
  53                 compiler.compile_main_function
  54
  55                 # compile methods
  56                 for m in mainmodule.in_importation.greaters do
  57                         compiler.new_file
  58                         compiler.compile_module_to_c(m)
  59                 end
  60
  61                 compiler.display_stats
  62
  63                 write_and_make(compiler)
  64         end
  65 end
  66
  67 class SeparateErasureCompiler
  68         super SeparateCompiler
  69
  70         private var class_layout: nullable TypingLayout[MClass]
  71         private var class_tables: Map[MClass, Array[nullable MClass]]
  72
  73         protected var vt_layout: nullable PropertyLayout[MVirtualTypeProp]
  74         protected var vt_tables: Map[MClass, Array[nullable MPropDef]]
  75
  76         init(mainmodule: MModule, mmbuilder: ModelBuilder, runtime_type_analysis: RapidTypeAnalysis) do
  77                 super
  78
  79                 var mclasses = new HashSet[MClass].from(mmbuilder.model.mclasses)
  80
  81                 var layout_builder: TypingLayoutBuilder[MClass]
  82                 if modelbuilder.toolcontext.opt_phmod_typing.value then
  83                         layout_builder = new PHClassLayoutBuilder(mainmodule, new PHModOperator)
  84                         self.header.add_decl("#define HASH(mask, id) ((mask)%(id))")
  85                 else if modelbuilder.toolcontext.opt_phand_typing.value then
  86                         layout_builder = new PHClassLayoutBuilder(mainmodule, new PHAndOperator)
  87                         self.header.add_decl("#define HASH(mask, id) ((mask)&(id))")
  88                 else if modelbuilder.toolcontext.opt_bm_typing.value then
  89                         layout_builder = new BMClassLayoutBuilder(mainmodule)
  90                 else
  91                         layout_builder = new CLClassLayoutBuilder(mainmodule)
  92                 end
  93                 self.class_layout = layout_builder.build_layout(mclasses)
  94                 self.class_tables = self.build_class_typing_tables(mclasses)
  95
  96                 # vt coloration
  97                 var vt_coloring = new CLPropertyLayoutBuilder[MVirtualTypeProp](mainmodule)
  98                 var vt_layout = vt_coloring.build_layout(mclasses)
  99                 self.vt_tables = build_vt_tables(mclasses, vt_layout)
 100                 self.compile_color_consts(vt_layout.pos)
 101                 self.vt_layout = vt_layout
 102         end
 103
 104         fun build_vt_tables(mclasses: Set[MClass], layout: PropertyLayout[MProperty]): Map[MClass, Array[nullable MPropDef]] do
 105                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 106                 for mclass in mclasses do
 107                         var table = new Array[nullable MPropDef]
 108                         # first, fill table from parents by reverse linearization order
 109                         var parents = self.mainmodule.super_mclasses(mclass)
 110                         var lin = self.mainmodule.reverse_linearize_mclasses(parents)
 111                         for parent in lin do
 112                                 for mproperty in self.mainmodule.properties(parent) do
 113                                         if not mproperty isa MVirtualTypeProp then continue
 114                                         var color = layout.pos[mproperty]
 115                                         if table.length <= color then
 116                                                 for i in [table.length .. color[ do
 117                                                         table[i] = null
 118                                                 end
 119                                         end
 120                                         for mpropdef in mproperty.mpropdefs do
 121                                                 if mpropdef.mclassdef.mclass == parent then
 122                                                         table[color] = mpropdef
 123                                                 end
 124                                         end
 125                                 end
 126                         end
 127
 128                         # then override with local properties
 129                         for mproperty in self.mainmodule.properties(mclass) do
 130                                 if not mproperty isa MVirtualTypeProp then continue
 131                                 var color = layout.pos[mproperty]
 132                                 if table.length <= color then
 133                                         for i in [table.length .. color[ do
 134                                                 table[i] = null
 135                                         end
 136                                 end
 137                                 for mpropdef in mproperty.mpropdefs do
 138                                         if mpropdef.mclassdef.mclass == mclass then
 139                                                 table[color] = mpropdef
 140                                         end
 141                                 end
 142                         end
 143                         tables[mclass] = table
 144                 end
 145                 return tables
 146         end
 147
 148         # Build class tables
 149         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 150                 var tables = new HashMap[MClass, Array[nullable MClass]]
 151                 var layout = self.class_layout
 152                 for mclass in mclasses do
 153                         var table = new Array[nullable MClass]
 154                         var supers = new HashSet[MClass]
 155                         supers.add_all(self.mainmodule.super_mclasses(mclass))
 156                         supers.add(mclass)
 157                         for sup in supers do
 158                                 var color: Int
 159                                 if layout isa PHTypingLayout[MClass] then
 160                                         color = layout.hashes[mclass][sup]
 161                                 else
 162                                         color = layout.pos[sup]
 163                                 end
 164                                 if table.length <= color then
 165                                         for i in [table.length .. color[ do
 166                                                 table[i] = null
 167                                         end
 168                                 end
 169                                 table[color] = sup
 170                         end
 171                         tables[mclass] = table
 172                 end
 173                 return tables
 174         end
 175
 176         redef fun compile_header_structs do
 177                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 178                 self.compile_header_attribute_structs
 179                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; struct vts_table *vts_table; struct type_table *type_table; nitmethod_t vft[1]; \}; /* general C type representing a Nit class. */")
 180                 self.header.add_decl("struct type_table \{ int size; int table[1]; \}; /* colorized type table. */")
 181                 self.header.add_decl("struct vts_entry \{ short int is_nullable; struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 182
 183                 if self.vt_layout isa PHPropertyLayoutBuilder[MVirtualTypeProp] then
 184                         self.header.add_decl("struct vts_table \{ int mask; struct vts_entry vts[1]; \}; /* vts list of a C type representation. */")
 185                 else
 186                         self.header.add_decl("struct vts_table \{ struct vts_entry vts[1]; \}; /* vts list of a C type representation. */")
 187                 end
 188
 189                 self.header.add_decl("typedef struct val \{ struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 190         end
 191
 192         redef fun compile_class_to_c(mclass: MClass)
 193         do
 194                 var mtype = mclass.intro.bound_mtype
 195                 var c_name = mclass.c_name
 196
 197                 var vft = self.method_tables[mclass]
 198                 var attrs = self.attr_tables[mclass]
 199                 var class_table = self.class_tables[mclass]
 200                 var v = self.new_visitor
 201
 202                 v.add_decl("/* runtime class {c_name} */")
 203
 204                 self.header.add_decl("extern const struct class_{c_name} class_{c_name};")
 205                 self.header.add_decl("struct class_{c_name} \{")
 206                 self.header.add_decl("int id;")
 207                 self.header.add_decl("const char *name;")
 208                 self.header.add_decl("int box_kind;")
 209                 self.header.add_decl("int color;")
 210                 self.header.add_decl("const struct vts_table *vts_table;")
 211                 self.header.add_decl("struct type_table *type_table;")
 212                 self.header.add_decl("nitmethod_t vft[{vft.length}];")
 213                 self.header.add_decl("\};")
 214
 215                 # Build class vft
 216                 v.add_decl("const struct class_{c_name} class_{c_name} = \{")
 217                 v.add_decl("{self.class_layout.ids[mclass]},")
 218                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 219                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 220                 var layout = self.class_layout
 221                 if layout isa PHTypingLayout[MClass] then
 222                         v.add_decl("{layout.masks[mclass]},")
 223                 else
 224                         v.add_decl("{layout.pos[mclass]},")
 225                 end
 226                 if build_class_vts_table(mclass) then
 227                         v.add_decl("(const struct vts_table*) &vts_table_{c_name},")
 228                 else
 229                         v.add_decl("NULL,")
 230                 end
 231                 v.add_decl("(struct type_table*) &type_table_{c_name},")
 232                 v.add_decl("\{")
 233                 for i in [0 .. vft.length[ do
 234                         var mpropdef = vft[i]
 235                         if mpropdef == null then
 236                                 v.add_decl("NULL, /* empty */")
 237                         else
 238                                 if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 239                                         v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 240                                 else
 241                                         v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 242                                 end
 243                         end
 244                 end
 245                 v.add_decl("\}")
 246                 v.add_decl("\};")
 247
 248                 # Build class type table
 249                 self.header.add_decl("extern const struct type_table_{c_name} type_table_{c_name};")
 250                 self.header.add_decl("struct type_table_{c_name} \{")
 251                 self.header.add_decl("int size;")
 252                 self.header.add_decl("int table[{class_table.length}];")
 253                 self.header.add_decl("\};")
 254
 255                 v.add_decl("const struct type_table_{c_name} type_table_{c_name} = \{")
 256                 v.add_decl("{class_table.length},")
 257                 v.add_decl("\{")
 258                 for msuper in class_table do
 259                         if msuper == null then
 260                                 v.add_decl("-1, /* empty */")
 261                         else
 262                                 v.add_decl("{self.class_layout.ids[msuper]}, /* {msuper} */")
 263                         end
 264                 end
 265                 v.add_decl("\}")
 266                 v.add_decl("\};")
 267
 268                 #Build instance struct
 269                 if mtype.ctype != "val*" then
 270                         self.header.add_decl("struct instance_{c_name} \{")
 271                         self.header.add_decl("const struct class *class;")
 272                         self.header.add_decl("{mtype.ctype} value;")
 273                         self.header.add_decl("\};")
 274
 275                         self.header.add_decl("val* BOX_{c_name}({mtype.ctype});")
 276                         v.add_decl("/* allocate {mtype} */")
 277                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 278                         v.add("struct instance_{c_name}*res = GC_MALLOC(sizeof(struct instance_{c_name}));")
 279                         v.add("res->class = (struct class*) &class_{c_name};")
 280                         v.add("res->value = value;")
 281                         v.add("return (val*)res;")
 282                         v.add("\}")
 283                         return
 284                 end
 285
 286                 var is_native_array = mclass.name == "NativeArray"
 287
 288                 var sig
 289                 if is_native_array then
 290                         sig = "int length"
 291                 else
 292                         sig = ""
 293                 end
 294
 295                 #Build instance struct
 296                 #extern const struct instance_array__NativeArray instance_array__NativeArray;
 297                 self.header.add_decl("struct instance_{c_name} \{")
 298                 self.header.add_decl("const struct class *class;")
 299                 self.header.add_decl("nitattribute_t attrs[{attrs.length}];")
 300                 if is_native_array then
 301                         # NativeArrays are just a instance header followed by an array of values
 302                         self.header.add_decl("val* values[0];")
 303                 end
 304                 self.header.add_decl("\};")
 305
 306
 307                 self.header.add_decl("{mtype.ctype} NEW_{c_name}({sig});")
 308                 v.add_decl("/* allocate {mtype} */")
 309                 v.add_decl("{mtype.ctype} NEW_{c_name}({sig}) \{")
 310                 var res = v.new_named_var(mtype, "self")
 311                 res.is_exact = true
 312                 if is_native_array then
 313                         var mtype_elt = mtype.arguments.first
 314                         v.add("{res} = GC_MALLOC(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 315                 else
 316                         v.add("{res} = GC_MALLOC(sizeof(struct instance_{c_name}));")
 317                 end
 318                 v.add("{res}->class = (struct class*) &class_{c_name};")
 319
 320                 self.generate_init_attr(v, res, mtype)
 321                 v.add("return {res};")
 322                 v.add("\}")
 323
 324                 generate_check_init_instance(mtype)
 325         end
 326
 327         private fun build_class_vts_table(mclass: MClass): Bool do
 328                 if self.vt_tables[mclass].is_empty then return false
 329
 330                 self.header.add_decl("extern const struct vts_table_{mclass.c_name} vts_table_{mclass.c_name};")
 331                 self.header.add_decl("struct vts_table_{mclass.c_name} \{")
 332                 if self.vt_layout isa PHPropertyLayoutBuilder[MVirtualTypeProp] then
 333                         self.header.add_decl("int mask;")
 334                 end
 335                 self.header.add_decl("struct vts_entry vts[{self.vt_tables[mclass].length}];")
 336                 self.header.add_decl("\};")
 337
 338                 var v = new_visitor
 339                 v.add_decl("const struct vts_table_{mclass.c_name} vts_table_{mclass.c_name} = \{")
 340                 if self.vt_layout isa PHPropertyLayoutBuilder[MVirtualTypeProp] then
 341                         #TODO redo this when PHPropertyLayoutBuilder will be implemented
 342                         #v.add_decl("{vt_masks[mclass]},")
 343                 end
 344                 v.add_decl("\{")
 345
 346                 for vt in self.vt_tables[mclass] do
 347                         if vt == null then
 348                                 v.add_decl("\{-1, NULL\}, /* empty */")
 349                         else
 350                                 var is_null = 0
 351                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 352                                 while bound isa MNullableType do
 353                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 354                                         is_null = 1
 355                                 end
 356                                 v.add_decl("\{{is_null}, (struct class*)&class_{bound.as(MClassType).mclass.c_name}\}, /* {vt} */")
 357                         end
 358                 end
 359                 v.add_decl("\},")
 360                 v.add_decl("\};")
 361                 return true
 362         end
 363
 364         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 365                 if mtype == null then
 366                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 367                         abort
 368                 end
 369                 if mtype isa MVirtualType then
 370                         return mtype.anchor_to(mainmodule, anchor)
 371                 else if mtype isa MParameterType then
 372                         return mtype.anchor_to(mainmodule, anchor)
 373                 else
 374                         return mtype
 375                 end
 376         end
 377
 378         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 379
 380         # Stats
 381
 382         redef fun display_sizes
 383         do
 384                 print "# size of tables"
 385                 print "\trs size\trs hole\tst size\tst hole"
 386                 var rt_table = 0
 387                 var rt_holes = 0
 388                 var st_table = 0
 389                 var st_holes = 0
 390                 var rtables = vt_tables
 391                 for unanch, table in rtables do
 392                         rt_table += table.length
 393                         for e in table do if e == null then rt_holes += 1
 394                 end
 395
 396                 var ttables = class_tables
 397                 for t, table in ttables do
 398                         st_table += table.length
 399                         for e in table do if e == null then st_holes += 1
 400                 end
 401                 print "\t{rt_table}\t{rt_holes}\t{st_table}\t{st_holes}"
 402         end
 403 end
 404
 405 class SeparateErasureCompilerVisitor
 406         super SeparateCompilerVisitor
 407
 408         redef fun compile_callsite(callsite, arguments)
 409         do
 410                 var res = super
 411                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 412                         assert res != null
 413                         var mtype = callsite.msignature.return_mtype
 414                         assert mtype != null
 415                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 416                         var cond = self.type_test(res, mtype, "erasure")
 417                         self.add("if (!{cond}) \{")
 418                         #var x = self.class_name_string(res)
 419                         #var y = self.class_name_string(arguments.first)
 420                         #self.add("fprintf(stderr, \"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 421                         self.add_abort("Cast failed")
 422                         self.add("\}")
 423                 end
 424                 return res
 425         end
 426
 427         redef fun init_instance(mtype) do return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 428
 429         redef fun type_test(value, mtype, tag)
 430         do
 431                 self.add("/* type test for {value.inspect} isa {mtype} */")
 432
 433                 var res = self.new_var(bool_type)
 434
 435                 var cltype = self.get_name("cltype")
 436                 self.add_decl("int {cltype};")
 437                 var idtype = self.get_name("idtype")
 438                 self.add_decl("int {idtype};")
 439
 440                 var maybe_null = self.maybe_null(value)
 441                 var accept_null = "0"
 442                 if mtype isa MNullableType then
 443                         mtype = mtype.mtype
 444                         accept_null = "1"
 445                 end
 446                 if mtype isa MParameterType then
 447                         # Here we get the bound of the the formal type (eh, erasure...)
 448                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 449                         if mtype isa MNullableType then
 450                                 mtype = mtype.mtype
 451                                 accept_null = "1"
 452                         end
 453                 end
 454
 455                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 456                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 457                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 458                                 self.compiler.count_type_test_skipped[tag] += 1
 459                                 self.add("count_type_test_skipped_{tag}++;")
 460                         end
 461                         return res
 462                 end
 463
 464                 var class_ptr
 465                 var type_table
 466                 if value.mtype.ctype == "val*" then
 467                         class_ptr = "{value}->class->"
 468                 else
 469                         var mclass = value.mtype.as(MClassType).mclass
 470                         class_ptr = "class_{mclass.c_name}."
 471                 end
 472
 473                 if mtype isa MClassType then
 474                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 475                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 476                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 477                                 self.compiler.count_type_test_resolved[tag] += 1
 478                                 self.add("count_type_test_resolved_{tag}++;")
 479                         end
 480                 else if mtype isa MVirtualType then
 481                         var recv = self.frame.arguments.first
 482                         var recv_ptr
 483                         if recv.mtype.ctype == "val*" then
 484                                 recv_ptr = "{recv}->class->"
 485                         else
 486                                 var mclass = recv.mtype.as(MClassType).mclass
 487                                 recv_ptr = "class_{mclass.c_name}."
 488                         end
 489                         var entry = self.get_name("entry")
 490                         self.add("struct vts_entry {entry};")
 491                         if self.compiler.as(SeparateErasureCompiler).vt_layout isa PHPropertyLayoutBuilder[MVirtualTypeProp] then
 492                                 self.add("{entry} = {recv_ptr}vts_table->vts[HASH({recv_ptr}vts_table->mask, {mtype.mproperty.const_color})];")
 493                         else
 494                                 self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 495                         end
 496                         self.add("{cltype} = {entry}.class->color;")
 497                         self.add("{idtype} = {entry}.class->id;")
 498                         if maybe_null and accept_null == "0" then
 499                                 var is_nullable = self.get_name("is_nullable")
 500                                 self.add_decl("short int {is_nullable};")
 501                                 self.add("{is_nullable} = {entry}.is_nullable;")
 502                                 accept_null = is_nullable.to_s
 503                         end
 504                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 505                                 self.compiler.count_type_test_unresolved[tag] += 1
 506                                 self.add("count_type_test_unresolved_{tag}++;")
 507                         end
 508                 else
 509                         self.debug("type_test({value.inspect}, {mtype})")
 510                         abort
 511                 end
 512
 513                 # check color is in table
 514                 if maybe_null then
 515                         self.add("if({value} == NULL) \{")
 516                         self.add("{res} = {accept_null};")
 517                         self.add("\} else \{")
 518                 end
 519                 if self.compiler.as(SeparateErasureCompiler).class_layout isa PHTypingLayout[MClass] then
 520                         self.add("{cltype} = HASH({class_ptr}color, {idtype});")
 521                 end
 522                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 523                 self.add("{res} = 0;")
 524                 self.add("\} else \{")
 525                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 526                 self.add("\}")
 527                 if maybe_null then
 528                         self.add("\}")
 529                 end
 530
 531                 return res
 532         end
 533
 534         redef fun class_name_string(value)
 535         do
 536                 var res = self.get_name("var_class_name")
 537                 self.add_decl("const char* {res};")
 538                 if value.mtype.ctype == "val*" then
 539                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 540                 else
 541                         self.add "{res} = class_{value.mtype.c_name}.name;"
 542                 end
 543                 return res
 544         end
 545
 546         redef fun array_instance(array, elttype)
 547         do
 548                 var nclass = self.get_class("NativeArray")
 549                 elttype = self.anchor(elttype)
 550                 var arraytype = self.get_class("Array").get_mtype([elttype])
 551                 var res = self.init_instance(arraytype)
 552                 self.add("\{ /* {res} = array_instance Array[{elttype}] */")
 553                 var nat = self.new_var(self.get_class("NativeArray").get_mtype([elttype]))
 554                 nat.is_exact = true
 555                 self.add("{nat} = NEW_{nclass.c_name}({array.length});")
 556                 for i in [0..array.length[ do
 557                         var r = self.autobox(array[i], self.object_type)
 558                         self.add("((struct instance_{nclass.c_name}*){nat})->values[{i}] = (val*) {r};")
 559                 end
 560                 var length = self.int_instance(array.length)
 561                 self.send(self.get_property("with_native", arraytype), [res, nat, length])
 562                 self.check_init_instance(res, arraytype)
 563                 self.add("\}")
 564                 return res
 565         end
 566
 567         redef fun calloc_array(ret_type, arguments)
 568         do
 569                 var ret = ret_type.as(MClassType)
 570                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 571         end
 572 end