src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwmodule = 'package'|'module';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwenum = 'universal'|'enum';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 ll = '<<';
 133 gt = '>';
 134 ge = '>=';
 135 gg = '>>';
 136 starship = '<=>';
 137 bang='!';
 138
 139 classid = uppercase letter*;
 140 id = lowercase letter*;
 141 attrid = '_' lowercase letter*;
 142
 143 number = digit+;
 144 float = digit* '.' digit+;
 145 char = ''' [any - ''']* ''';
 146 string = '"' str_body '"';
 147 start_string = '"' str_body '{';
 148 mid_string = '}' str_body '{';
 149 end_string = '}' str_body '"';
 150
 151
 152 /*****************************************************************************/
 153 Ignored Tokens
 154 /*****************************************************************************/
 155
 156 blank;
 157
 158 /*****************************************************************************/
 159 Productions
 160 /*****************************************************************************/
 161
 162 /* MODULES *******************************************************************/
 163 module
 164         = moduledecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 165
 166 moduledecl
 167         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 168
 169 import
 170         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 171         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 172         ;
 173
 174 implicit_top_class {-> classdef}
 175         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 176
 177 implicit_main_class {-> classdef?}
 178         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 179         | {null} n {-> Null}
 180         ;
 181 implicit_main_meth {-> propdef}
 182         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 183         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 184         ;
 185
 186 /* CLASSES *******************************************************************/
 187 classdef
 188         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef], kwend)};
 189 redef {-> kwredef?}
 190         = kwredef? {-> kwredef};
 191 classkind
 192         = {concrete} kwclass
 193         | {abstract} kwabstract kwclass
 194         | {interface} kwinterface
 195         | {enum} kwenum
 196         | {extern} kwextern
 197         ;
 198
 199 formaldefs {-> formaldef*}
 200         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 201 formaldefs_tail {-> formaldef}
 202         = comma no formaldef {-> formaldef};
 203 formaldef
 204         = classid typing? {-> New formaldef(classid, typing.type)};
 205
 206 special {-> superclass}
 207         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 208         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 209         ;
 210
 211 propdefs~toplevel {-> propdef}
 212         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 213         ;
 214 propdef~toplevel {-> propdef}
 215         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 216         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 217 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 218 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 219         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls)}
 220 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 221 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 222 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 223 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 224 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 225 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 226 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls)}
 227         ;
 228 readable {-> able}
 229         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 230         ;
 231 writable {-> able}
 232         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 233         ;
 234 writable2 {-> able}
 235         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 236         ;
 237
 238 visibility
 239         = {public} {-> New visibility.public()}
 240         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 241         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 242         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 243         ;
 244
 245 methid {-> methid}
 246         = {id} id {-> New methid.id(id)}
 247         | {plus} plus {-> New methid.plus(plus)}
 248         | {minus} minus {-> New methid.minus(minus)}
 249         | {star} star {-> New methid.star(star)}
 250         | {slash} slash {-> New methid.slash(slash)}
 251         | {percent} percent {-> New methid.percent(percent)}
 252         | {eq} eq {-> New methid.eq(eq)}
 253         | {ne} ne {-> New methid.ne(ne)}
 254         | {le} le {-> New methid.le(le)}
 255         | {ge} ge {-> New methid.ge(ge)}
 256         | {lt} lt {-> New methid.lt(lt)}
 257         | {gt} gt {-> New methid.gt(gt)}
 258         | {ll} ll {-> New methid.ll(ll)}
 259         | {gg} gg {-> New methid.gg(gg)}
 260         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 261         | {starship} starship {-> New methid.starship(starship)}
 262         | {assign} id assign {-> New methid.assign(id, assign)}
 263         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 264         ;
 265
 266 signature~withret {-> signature}
 267         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 268         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 269 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 270 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 271         ;
 272
 273 signature_noclosures {-> signature}
 274         = params? typing? {-> New signature([params.param], typing.type, [])};
 275
 276 params {-> param*}
 277         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 278         | {empty} opar no cpar {-> []}
 279         ;
 280 params_tail {-> param}
 281         = comma no param {-> param};
 282 param
 283         = {untyped} id {-> New param(id, Null, Null)}
 284         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 285         ;
 286
 287 closure_decls {->closure_decl*}
 288         = no closure_decl+ {-> [closure_decl]};
 289 closure_decl
 290         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 291         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 292         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 293         ;
 294
 295 assign_return{-> expr}
 296         = expr_final {-> New expr.return(Null, expr_final.expr)}
 297         ;
 298
 299 extern_calls {-> extern_calls}
 300         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 301         ;
 302 extern_call_tail {-> extern_call}
 303         = comma no extern_call {-> extern_call};
 304 extern_call {-> extern_call}
 305     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 306     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 307         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 308     ;
 309 extern_call_prop {-> extern_call}
 310     = {local} methid {-> New extern_call.local_prop( methid )}
 311         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 312         | {init} classid {-> New extern_call.init_prop( classid )}
 313         ;
 314 extern_call_cast {-> extern_call}
 315     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 316         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 317         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 318         ;
 319
 320
 321 /* TYPES *********************************************************************/
 322 type~nobra {-> type}
 323         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 324 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 325         ;
 326 types {-> type*}
 327         = type types_tail* {-> [type, types_tail.type]};
 328 types_tail {-> type}
 329         = comma no type {-> type};
 330 typing {-> type}
 331         = column no type {-> type};
 332
 333 /* STATMENTS *****************************************************************/
 334 stmtso~withelse~withend {-> expr?}
 335         = {block} n stmtsnend {-> stmtsnend.expr}
 336         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 337         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 338 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 339         ;
 340 stmts {-> expr}
 341         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 342 stmtsn {-> expr}
 343         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 344 stmtsnend {-> expr}
 345         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 346 stmts_tail {-> expr}
 347         = n stmt {-> stmt.expr};
 348 stmt~withelse {-> expr}
 349         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 350         | {assign} assignment~withelse {-> assignment~withelse.expr}
 351         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 352         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 353         | {abort} kwabort {-> New expr.abort(kwabort)}
 354         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 355         | {do} do~withelse {-> do~withelse.expr}
 356         | {if} if~withelse {-> if~withelse.expr}
 357         | {while} while~withelse {-> while~withelse.expr}
 358         | {loop} loop~withelse {-> loop~withelse.expr}
 359         | {for} for~withelse {-> for~withelse.expr}
 360         | {assert} assert~withelse {-> assert~withelse.expr}
 361         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 362         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 363         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 364         ;
 365
 366 label= kwlabel id;
 367
 368 closure_defs~withelse {-> closure_def*}
 369         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 370         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 371         ;
 372
 373 closure_def_last~withelse {-> closure_def}
 374         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 375         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 376         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 377         ;
 378
 379 closure_def {-> closure_def}
 380         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 381         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 382         ;
 383 closure_id
 384         = {simple} id
 385         | {break} kwbreak
 386         ;
 387
 388 assign_continue~withelse{-> expr}
 389         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 390         ;
 391
 392 vardecl~withelse{-> expr}
 393         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 394         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 395         ;
 396
 397 assignment~withelse {-> expr}
 398         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 399         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 400         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 401         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 402         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 403         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 404         ;
 405 assign_op
 406         = {plus} pluseq
 407         | {minus} minuseq
 408         ;
 409
 410 do~withelse {-> expr}
 411         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 412         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 413         ;
 414
 415 if~withelse {-> expr}
 416         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 417 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 418 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 419 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 420         ;
 421 elsepartblock {-> expr?}
 422         = {else} kwelse stmtso {-> stmtso.expr}
 423         | {empty} kwend {-> New expr.block([], kwend)}
 424         ;
 425
 426 loop~withelse {-> expr}
 427         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 428         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 429         ;
 430
 431 while~withelse {-> expr}
 432         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 433         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 434         ;
 435
 436 for~withelse {-> expr}
 437         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 438         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 439         ;
 440
 441 assert~withelse {-> expr}
 442         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 443 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 444         ;
 445 assertid {-> id}
 446         = id column {-> id};
 447
 448 /* EXPRESSIONS ***************************************************************/
 449 expr_final~nopar~withelse~nobra {-> expr}
 450         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 451         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 452 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 453         ;
 454
 455 expr~nopar~nobra {-> expr}
 456         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 457         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 458         ;
 459
 460 expr_and~nopar~nobra {-> expr}
 461         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 462         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 463         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 464         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 465         ;
 466
 467 expr_not~nopar~nobra {-> expr}
 468         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 469         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 470         ;
 471
 472 expr_eq~nopar~nobra {-> expr}
 473         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 474         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 475         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 476         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 477         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 478         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 479         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 480         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 481         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 482         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 483         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 484         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 485         ;
 486
 487 expr_add~nopar~nobra {-> expr}
 488         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 489         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 490         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 491         ;
 492
 493 expr_mul~nopar~nobra {-> expr}
 494         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 495         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 496         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 497         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 498         ;
 499
 500 expr_minus~nopar~nobra {-> expr}
 501         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 502         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 503         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 504         ;
 505
 506 expr_new~nopar~nobra {-> expr}
 507         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 508         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 509         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 510         ;
 511
 512 expr_atom~nopar~nobra {-> expr}
 513         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 514         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 515         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 516         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 517 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, [braargs.expr], [])}
 518         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 519 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 520 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 521 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 522 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 523         | {self} kwself {-> New expr.self(kwself)}
 524         | {true} kwtrue {-> New expr.true(kwtrue)}
 525         | {false} kwfalse {-> New expr.false(kwfalse)}
 526         | {null} kwnull {-> New expr.null(kwnull)}
 527         | {int} number  {-> New expr.int(number)}
 528         | {float} float  {-> New expr.float(float)}
 529         | {char} char  {-> New expr.char(char)}
 530         | {string} string  {-> New expr.string(string)}
 531         | {superstring} superstring  {-> superstring.expr}
 532 !nopar  | {par} opar expr cpar {-> expr}
 533         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 534         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 535         ;
 536
 537 superstring {-> expr}
 538         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 539 superstring_start {-> expr*}
 540         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 541 start_string_p {-> expr}
 542         = start_string {-> New expr.start_string(start_string)};
 543 superstring_middle {-> expr*}
 544         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 545 mid_string_p {-> expr}
 546         = mid_string {-> New expr.mid_string(mid_string)};
 547 superstring_end {-> expr}
 548         = end_string {-> New expr.end_string(end_string)};
 549
 550 /* MISC **********************************************************************/
 551
 552 recv~nopar~nobra {-> expr}
 553         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 554         | {implicit} {-> New expr.implicit_self()}
 555         ;
 556
 557 args {-> expr*}
 558         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 559         | {emptypar} opar no cpar {-> []}
 560         | {empty} {-> []}
 561         ;
 562 args_nopar {-> expr*}
 563         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 564         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 565         | {emptypar} opar no cpar {-> []}
 566         | {empty} {-> []}
 567         ;
 568 braargs {-> expr*}
 569         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 570 args_tail {-> expr}
 571         = comma no expr [n2]:no {-> expr};
 572 idlist {-> id*}
 573         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 574         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 575         ;
 576 idlist_nopar {-> id*}
 577         = {single} id {-> [id]}
 578         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 579         ;
 580
 581 module_name {-> module_name}
 582         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 583         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 584         ;
 585
 586 qualified
 587         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 588         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 589         ;
 590 modquad {-> id}
 591         = id quad no {-> id};
 592 classquad {-> classid}
 593         = classid quad no {-> classid};
 594
 595 n1      = {a} comment | {b} eol;
 596 n {-> doc?}
 597         = {a} n2? comment+ {-> New doc([comment])}
 598         | {b} n2 {-> Null}
 599         ;
 600 no {-> doc?}
 601         = {empty} {-> Null}
 602         | n {-> n.doc}
 603         ;
 604
 605 n2
 606         = {a} n2? comment+ eol+
 607         | {b} eol+
 608         ;
 609
 610 /*****************************************************************************/
 611 Abstract Syntax Tree
 612 /*****************************************************************************/
 613
 614 module  = moduledecl? [imports]:import* [classdefs]:classdef*;
 615
 616 moduledecl
 617         = doc? kwmodule [name]:module_name;
 618
 619 import  = {std} visibility kwimport [name]:module_name
 620         | {no} visibility kwimport kwend
 621         ;
 622
 623 visibility
 624         = {public}
 625         | {private} kwprivate
 626         | {protected} kwprotected
 627         | {intrude} kwintrude
 628         ;
 629
 630 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef* kwend
 631         | {top} [propdefs]:propdef*
 632         | {main} [propdefs]:propdef*
 633         ;
 634 classkind
 635         = {concrete} kwclass
 636         | {abstract} kwabstract kwclass
 637         | {interface} kwinterface
 638         | {enum} kwenum
 639         | {extern} kwextern
 640         ;
 641 formaldef = [id]:classid type?;
 642 superclass = kwspecial? kwsuper? type;
 643
 644
 645 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 646         | {meth} doc? kwredef? visibility methid signature
 647         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 648         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 649         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls?
 650         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 651         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 652         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls?
 653         | {main_meth} kwredef? [block]:expr?
 654         | {type} doc? kwredef? visibility kwtype [id]:classid type
 655         ;
 656
 657 able    = {read} kwredef? kwreadable
 658         | {write} kwredef? visibility? kwwritable
 659         ;
 660
 661 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 662
 663 signature = [params]:param* type? [closure_decls]:closure_decl*;
 664
 665 param   = id type? dotdotdot?
 666         ;
 667
 668 closure_decl = kwbreak? bang id signature expr?
 669         ;
 670
 671 type    = kwnullable? [id]:classid [types]:type*;
 672
 673 label = kwlabel id;
 674
 675 expr    = {block} expr* kwend?
 676         | {vardecl} kwvar id type? assign? expr?
 677         | {return} kwreturn? expr?
 678         | {break} kwbreak label? expr?
 679         | {abort} kwabort
 680         | {continue} kwcontinue? label? expr?
 681         | {do} kwdo [block]:expr? label?
 682         | {if} kwif expr [then]:expr? [else]:expr?
 683         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 684         | {while} kwwhile expr kwdo [block]:expr? label?
 685         | {loop} kwloop [block]:expr? label?
 686         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 687         | {assert} kwassert id? expr [else]:expr?
 688         | {once} kwonce expr
 689         | {send} expr
 690         | {binop} expr [expr2]:expr
 691         | {or} expr [expr2]:expr
 692         | {and} expr [expr2]:expr
 693         | {or_else} expr [expr2]:expr
 694         | {not} kwnot expr
 695         | {eq} expr [expr2]:expr
 696         | {ee} expr [expr2]:expr
 697         | {ne} expr [expr2]:expr
 698         | {lt} expr [expr2]:expr
 699         | {le} expr [expr2]:expr
 700         | {ll} expr [expr2]:expr
 701         | {gt} expr [expr2]:expr
 702         | {ge} expr [expr2]:expr
 703         | {gg} expr [expr2]:expr
 704         | {isa} expr type
 705         | {plus} expr [expr2]:expr
 706         | {minus} expr [expr2]:expr
 707         | {starship} expr [expr2]:expr
 708         | {star} expr [expr2]:expr
 709         | {slash} expr [expr2]:expr
 710         | {percent} expr [expr2]:expr
 711         | {uminus} minus expr
 712         | {new} kwnew type id? [args]:expr*
 713         | {attr} expr [id]:attrid
 714         | {attr_assign} expr [id]:attrid assign [value]:expr
 715         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 716         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 717         | {call_assign} expr id [args]:expr* assign [value]:expr
 718         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 719         | {super} qualified? kwsuper [args]:expr*
 720         | {init} expr kwinit [args]:expr*
 721         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 722         | {bra_assign} expr [args]:expr* assign [value]:expr
 723         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 724         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 725         | {var} id
 726         | {var_assign} id assign [value]:expr
 727         | {var_reassign} id assign_op [value]:expr
 728         | {range} expr [expr2]:expr
 729         | {crange} expr [expr2]:expr
 730         | {orange} expr [expr2]:expr
 731         | {array} [exprs]:expr*
 732         | {self} kwself
 733         | {implicit_self}
 734         | {true} kwtrue
 735         | {false} kwfalse
 736         | {null} kwnull
 737         | {int} number
 738         | {float} float
 739         | {char} char
 740         | {string} string
 741         | {start_string} [string]:start_string
 742         | {mid_string} [string]:mid_string
 743         | {end_string} [string]:end_string
 744         | {superstring} [exprs]:expr*
 745         | {par} expr
 746         | {as_cast} expr kwas type
 747         | {as_notnull} expr kwas kwnot kwnull
 748         | {isset_attr} kwisset expr [id]:attrid
 749         ;
 750 assign_op
 751         = {plus} pluseq
 752         | {minus} minuseq
 753         ;
 754
 755 closure_def
 756         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 757         ;
 758 closure_id
 759         = {simple} id
 760         | {break} kwbreak
 761         ;
 762
 763 module_name = quad? [path]:id* id;
 764 extern_calls = kwimport [extern_calls]:extern_call*
 765         ;
 766 extern_call =
 767         | {super} kwsuper
 768         | {local_prop} methid
 769         | {full_prop} classid quad? methid
 770         | {init_prop} classid
 771         | {cast_as} [from_type]:type kwas [to_type]:type
 772         | {as_nullable} type kwas kwnullable
 773         | {as_not_nullable} type kwas kwnot kwnullable
 774         ;
 775
 776 qualified = id* classid? ;
 777
 778 doc = comment+;
 779
 780 /*****************************************************************************/
 781