lib/sqlite3/native_sqlite3.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Guillaume Auger <jeho@resist.ca>
   4 # Copyright 2013-2014 Alexis Laferrière <alexis.laf@xymus.net>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 # Low-level Sqlite3 features
  19 module native_sqlite3 is pkgconfig("sqlite3")
  20
  21 in "C header" `{
  22         #include <sqlite3.h>
  23 `}
  24
  25 redef class Sys
  26         # Last error raised when calling `Sqlite3::open`
  27         var sqlite_open_error: nullable Sqlite3Code = null
  28 end
  29
  30 extern class Sqlite3Code `{int`}
  31         new ok `{ return SQLITE_OK; `} #         0   /* Successful result */
  32         fun is_ok: Bool `{ return self == SQLITE_OK; `}
  33
  34         # new  `{ return SQLITE_ERROR; `} #      1   /* SQL error or missing database */
  35         # new  `{ return SQLITE_INTERNAL; `} #    2   /* Internal logic error in SQLite */
  36         # new  `{ return SQLITE_PERM; `} #        3   /* Access permission denied */
  37         # new  `{ return SQLITE_ABORT; `} #       4   /* Callback routine requested an abort */
  38         # new  `{ return SQLITE_BUSY; `} #        5   /* The database file is locked */
  39         # new  `{ return SQLITE_LOCKED; `} #      6   /* A table in the database is locked */
  40         # new  `{ return SQLITE_NOMEM; `} #       7   /* A malloc() failed */
  41         # new  `{ return SQLITE_READONLY; `} #    8   /* Attempt to write a readonly database */
  42         # new  `{ return SQLITE_INTERRUPT; `} #   9   /* Operation terminated by sqlite3_interrupt()*/
  43         # new  `{ return SQLITE_IOERR; `} #      10   /* Some kind of disk I/O error occurred */
  44         # new  `{ return SQLITE_CORRUPT; `} #    11   /* The database disk image is malformed */
  45         # new  `{ return SQLITE_NOTFOUND; `} #   12   /* Unknown opcode in sqlite3_file_control() */
  46         # new  `{ return SQLITE_FULL; `} #       13   /* Insertion failed because database is full */
  47         # new  `{ return SQLITE_CANTOPEN; `} #   14   /* Unable to open the database file */
  48         # new  `{ return SQLITE_PROTOCOL; `} #   15   /* Database lock protocol error */
  49         # new  `{ return SQLITE_EMPTY; `} #      16   /* Database is empty */
  50         # new  `{ return SQLITE_SCHEMA; `} #     17   /* The database schema changed */
  51         # new  `{ return SQLITE_TOOBIG; `} #     18   /* String or BLOB exceeds size limit */
  52         # new  `{ return SQLITE_CONSTRAINT; `} # 19   /* Abort due to constraint violation */
  53         # new  `{ return SQLITE_MISMATCH; `} #   20   /* Data type mismatch */
  54         # new  `{ return SQLITE_MISUSE; `} #     21   /* Library used incorrectly */
  55         # new  `{ return SQLITE_NOLFS; `} #      22   /* Uses OS features not supported on host */
  56         # new  `{ return SQLITE_AUTH; `} #       23   /* Authorization denied */
  57         # new  `{ return SQLITE_FORMAT; `} #     24   /* Auxiliary database format error */
  58         # new  `{ return SQLITE_RANGE; `} #      25   /* 2nd parameter to sqlite3_bind out of range */
  59         # new  `{ return SQLITE_NOTADB; `} #     26   /* File opened that is not a database file */
  60         # new  `{ return SQLITE_NOTICE; `} #     27   /* Notifications from sqlite3_log() */
  61         # new  `{ return SQLITE_WARNING; `} #    28   /* Warnings from sqlite3_log() */
  62
  63         new row `{ return SQLITE_ROW; `} #        100  /* sqlite3_step() has another row ready */
  64         fun is_row: Bool `{ return self == SQLITE_ROW; `}
  65
  66         new done `{ return SQLITE_DONE; `} #       101  /* sqlite3_step() has finished executing */
  67         fun is_done: Bool `{ return self == SQLITE_DONE; `}
  68
  69         redef fun to_s
  70         do
  71                 var err = native_to_s
  72                 if err.address_is_null then return "Unknown error"
  73                 return err.to_s
  74         end
  75
  76         private fun native_to_s: NativeString `{
  77 #if SQLITE_VERSION_NUMBER >= 3007015
  78                 char *err = (char *)sqlite3_errstr(self);
  79 #else
  80                 char *err = "sqlite3_errstr supported only by version >= 3.7.15";
  81 #endif
  82                 return err;
  83         `}
  84 end
  85
  86 # A prepared statement
  87 extern class NativeStatement `{sqlite3_stmt*`}
  88
  89         # Evaluate the statement
  90         fun step: Sqlite3Code `{
  91                 return sqlite3_step(self);
  92         `}
  93
  94         fun column_name(i: Int) : String import NativeString.to_s `{
  95                 const char * name = (sqlite3_column_name(self, i));
  96                 if(name == NULL){
  97                         name = "";
  98                 }
  99                 char * ret = (char *) name;
 100                 return NativeString_to_s(ret);
 101         `}
 102
 103         # Number of bytes in the blob or string at row `i`
 104         fun column_bytes(i: Int) : Int `{
 105                 return sqlite3_column_bytes(self, i);
 106         `}
 107
 108         fun column_double(i: Int) : Float `{
 109                 return sqlite3_column_double(self, i);
 110         `}
 111
 112         fun column_int(i: Int) : Int `{
 113                 return sqlite3_column_int(self, i);
 114         `}
 115
 116         fun column_text(i: Int): NativeString `{
 117                 return (char *)sqlite3_column_text(self, i);
 118         `}
 119
 120         # Type of the entry at row `i`
 121         fun column_type(i: Int): DataType `{
 122                 return sqlite3_column_type(self, i);
 123         `}
 124
 125         fun column_blob(i: Int): Pointer `{ return (void*)sqlite3_column_blob(self, i); `}
 126
 127         fun column_count: Int `{
 128                 return sqlite3_column_count(self);
 129         `}
 130
 131         # Reset this statement to its original state, to be reexecuted
 132         fun reset: Sqlite3Code `{ return sqlite3_reset(self); `}
 133
 134         # Delete this statement
 135         fun finalize: Sqlite3Code `{ return sqlite3_finalize(self); `}
 136 end
 137
 138 # A database connection
 139 extern class NativeSqlite3 `{sqlite3 *`}
 140
 141         # Open a connection to a database in UTF-8
 142         new open(filename: NativeString) import set_sys_sqlite_open_error `{
 143                 sqlite3 *self = NULL;
 144                 int err = sqlite3_open(filename, &self);
 145                 NativeSqlite3_set_sys_sqlite_open_error(self, (void*)(long)err);
 146                 // The previous cast is a hack, using non pointers in extern classes is not
 147                 // yet in the spec of the FFI.
 148                 return self;
 149         `}
 150
 151         # Utility method to set `Sys.sqlite_open_error`
 152         private fun set_sys_sqlite_open_error(err: Sqlite3Code) do sys.sqlite_open_error = err
 153
 154         # Has this DB been correctly opened?
 155         #
 156         # To know if it has been closed or interrupted, you must check for errors with `error`.
 157         fun is_valid: Bool do return not address_is_null
 158
 159         fun destroy do close
 160
 161         # Close this connection
 162         fun close `{
 163 #if SQLITE_VERSION_NUMBER >= 3007014
 164                 sqlite3_close_v2(self);
 165 #else
 166                 // A program using the older version should not rely on the garbage-collector
 167                 // to close its connections. They must be closed manually after the associated
 168                 // prepare statements have been finalized.
 169                 sqlite3_close(self);
 170 #endif
 171         `}
 172
 173         # Execute a SQL statement
 174         fun exec(sql: String): Sqlite3Code import String.to_cstring `{
 175                 return sqlite3_exec(self, String_to_cstring(sql), 0, 0, 0);
 176         `}
 177
 178         # Prepare a SQL statement
 179         fun prepare(sql: String): nullable NativeStatement import String.to_cstring, NativeStatement.as nullable `{
 180                 sqlite3_stmt *stmt;
 181                 int res = sqlite3_prepare_v2(self, String_to_cstring(sql), -1, &stmt, 0);
 182                 if (res == SQLITE_OK)
 183                         return NativeStatement_as_nullable(stmt);
 184                 else
 185                         return null_NativeStatement();
 186         `}
 187
 188         fun last_insert_rowid: Int `{
 189                 return sqlite3_last_insert_rowid(self);
 190         `}
 191
 192         fun error: Sqlite3Code `{
 193                 return sqlite3_errcode(self);
 194         `}
 195 end
 196
 197 # Sqlite data types
 198 extern class DataType `{ int `}
 199         fun is_integer: Bool `{ return self == SQLITE_INTEGER; `}
 200         fun is_float: Bool `{ return self == SQLITE_FLOAT; `}
 201         fun is_blob: Bool `{ return self == SQLITE_BLOB; `}
 202         fun is_null: Bool `{ return self == SQLITE_NULL; `}
 203         fun is_text: Bool `{ return self == SQLITE_TEXT; `}
 204
 205         fun to_i: Int `{ return self; `}
 206 end