src/metrics/tables_metrics.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Metrics on table generation
  18 module tables_metrics
  19
  20 import model
  21 private import metrics_base
  22 import frontend
  23
  24 redef class ToolContext
  25         var tables_metrics_phase = new TablesMetricsPhase(self, null)
  26 end
  27
  28 private class TablesMetricsPhase
  29         super Phase
  30         redef fun process_mainmodule(mainmodule, given_mmodules)
  31         do
  32                 if not toolcontext.opt_tables.value and not toolcontext.opt_all.value then return
  33                 compute_tables_metrics(mainmodule)
  34         end
  35 end
  36
  37 # Print class tables metrics for the classes of the program main
  38 fun compute_tables_metrics(main: MModule)
  39 do
  40         var model = main.model
  41
  42         var nc = 0 # Number of runtime classes
  43         var nl = 0 # Number of usages of class definitions (a class definition can be used more than once)
  44         var nhp = 0 # Number of usages of properties (a property can be used more than once)
  45         var npas = 0 # Number of usages of properties without lookup (easy easy case, easier that CHA)
  46
  47         # Collect the full class hierarchy
  48         var hier = main.flatten_mclass_hierarchy
  49         for c in hier do
  50                 # Skip classes without direct instances
  51                 if c.kind == interface_kind or c.kind == abstract_kind then continue
  52
  53                 nc += 1
  54
  55                 # Now, we need to collect all properties defined/inherited/imported
  56                 # So, visit all definitions of all super-classes
  57                 for sup in hier[c].greaters do
  58                         for cd in sup.mclassdefs do
  59                                 nl += 1
  60
  61                                 # Now, search properties introduced
  62                                 for p in cd.intro_mproperties do
  63
  64                                         nhp += 1
  65                                         # Select property definition
  66                                         if p.mpropdefs.length == 1 then
  67                                                 npas += 1
  68                                         else
  69                                                 var sels = p.lookup_definitions(main, c.intro.bound_mtype)
  70                                                 if sels.length > 1 then
  71                                                         print "conflict for {p.full_name} in class {c.full_name}: {sels.join(", ")}"
  72                                                 else if sels.is_empty then
  73                                                         print "ERROR: no property for {p.full_name} in class {c.full_name}!"
  74                                                 end
  75                                         end
  76                                 end
  77                         end
  78                 end
  79         end
  80
  81         print "--- Construction of tables ---"
  82         print "Number of runtime classes: {nc} (excluding interfaces and abstract classes)"
  83         print "Average number of composing class definition by runtime class: {div(nl,nc)}"
  84         print "Total size of tables (classes and instances): {nhp} (not including stuff like info for subtyping or call-next-method)"
  85         print "Average size of table by runtime class: {div(nhp,nc)}"
  86         print "Values never redefined: {npas} ({div(npas*100,nhp)}%)"
  87 end