contrib/asteronits/src/asteronits.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Portable game to destroy asteroids
  16 module asteronits is
  17         app_name "Asteronits"
  18         app_namespace "org.nitlanguage.asteronits"
  19         app_version(1, 0, git_revision)
  20
  21         android_manifest_activity """android:screenOrientation="sensorLandscape""""
  22         android_api_target 15
  23 end
  24
  25 import gamnit::flat
  26
  27 import game_logic
  28 import spritesheet
  29 import app::audio
  30
  31 redef class Spritesheet
  32         # Largest meteors, organized by color
  33         var meteors_big: Array[Array[Texture]] = [
  34                 [meteor_brown_big1, meteor_brown_big2, meteor_brown_big3, meteor_brown_big4],
  35                 [meteor_grey_big1, meteor_grey_big2, meteor_grey_big3, meteor_grey_big4]]
  36
  37         # Medium size meteors, organized by color
  38         var meteors_med: Array[Array[Texture]] = [
  39                 [meteor_brown_med1, meteor_brown_med3],
  40                 [meteor_grey_med1, meteor_grey_med2]]
  41
  42         # Small meteors, organized by color
  43         var meteors_small: Array[Array[Texture]] = [
  44                 [meteor_brown_small1, meteor_brown_small2],
  45                 [meteor_grey_small1, meteor_grey_small2]]
  46
  47         # Tiny meteors, organized by color
  48         #
  49         # TODO use these in particles
  50         var meteors_tiny: Array[Array[Texture]] = [
  51                 [meteor_brown_tiny1, meteor_brown_tiny2],
  52                 [meteor_grey_tiny1, meteor_grey_tiny2]]
  53
  54         # Available ships
  55         var ships: Array[Texture] = [enemy_green1]
  56 end
  57
  58 redef class App
  59
  60         # Current world in play
  61         var world = new World(12, 2, display.aspect_ratio) is lazy
  62
  63         # Sound effects
  64         private var fx_fire = new Sound("sounds/fire.mp3")
  65         private var fx_explosion_ship = new Sound("sounds/explosion_ship.wav")
  66         private var fx_explosion_asteroids = new Sound("sounds/explosion_asteroids.wav")
  67
  68         redef fun on_create
  69         do
  70                 super
  71
  72                 # Move the camera to show all the world world in the screen range
  73                 world_camera.reset_height(world.half_height * 2.0)
  74         end
  75
  76         # Main spritesheet with ships, asteroids and beams
  77         var spritesheet = new Spritesheet
  78
  79         redef fun update(dt)
  80         do
  81                 # Update game logic
  82                 world.do_turn dt
  83
  84                 # Setup new world if all asteroids are destroyed
  85                 if world.asteroids.is_empty then
  86                         sprites.clear
  87                         world = new World(world.n_asteroids*2, world.n_asteroid_parts+1, display.aspect_ratio)
  88                 end
  89         end
  90
  91         redef fun accept_event(event)
  92         do
  93                 if event isa QuitEvent then
  94                         exit 0
  95                 else if event isa KeyEvent then
  96                         var thrust = event.thrust
  97                         if thrust != 0.0 then
  98                                 app.world.ship.applied_thrust = if event.is_down then thrust else 0.0
  99                                 return true
 100                         end
 101
 102                         var rot = event.rotation
 103                         if rot != 0.0 then
 104                                 app.world.ship.applied_rotation = if event.is_down then rot else 0.0
 105                                 return true
 106                         end
 107
 108                         if event.name == "space" and event.is_down then
 109                                 app.world.ship.fire
 110                                 return true
 111                         else if event.name == "escape" then
 112                                 exit 0
 113                         end
 114                 end
 115
 116                 return false
 117         end
 118 end
 119
 120 redef class SpacialObject
 121         # Main `Sprite` to draw for this object
 122         var sprite: Sprite is noinit
 123
 124         # All `Sprites` composing this object
 125         var sprites: Collection[Sprite] = new Ref[Sprite](sprite) is lazy
 126
 127         init do app.sprites.add_all sprites
 128
 129         redef fun do_turn(dt)
 130         do
 131                 super
 132                 sprite.rotation = rotation - pi/2.0
 133         end
 134
 135         redef fun destroy
 136         do
 137                 super
 138                 for s in sprites do app.sprites.remove s
 139         end
 140 end
 141
 142 redef class Asteroid
 143
 144         init
 145         do
 146                 # Select texture from `size` and `color`
 147                 var tex = if size == 3 then
 148                                 app.spritesheet.meteors_big[color].rand
 149                         else if size == 2 then
 150                                 app.spritesheet.meteors_med[color].rand
 151                         else app.spritesheet.meteors_small[color].rand
 152
 153                 sprite = new Sprite(tex, center)
 154                 super
 155         end
 156
 157         redef fun destroy
 158         do
 159                 super
 160                 app.fx_explosion_asteroids.play
 161         end
 162 end
 163
 164 redef class Bullet
 165         init
 166         do
 167                 sprite = new Sprite(app.spritesheet.laser_blue01, center)
 168                 super
 169         end
 170 end
 171
 172 redef class Ship
 173         init
 174         do
 175                 sprite = new Sprite(app.spritesheet.ships.rand, center)
 176                 sprites = [sprite, thrust_sprite]
 177
 178                 super
 179         end
 180
 181         private var thrust_sprite = new Sprite(app.spritesheet.fire09, new Point3d[Float](0.0, 0.0, 0.0))
 182
 183         private var sprites_with_fire: Array[Sprite] = [thrust_sprite, sprite] is lazy
 184
 185         redef fun do_turn(dt)
 186         do
 187                 super
 188
 189                 # Update position of the thrust sprite
 190                 var dist_to_engine = 45.0
 191                 thrust_sprite.center.x = center.x - dist_to_engine*rotation.cos
 192                 thrust_sprite.center.y = center.y - dist_to_engine*rotation.sin
 193                 thrust_sprite.center.z = center.z
 194                 thrust_sprite.rotation = rotation - pi/2.0
 195
 196                 # Show or hide the thrust sprite
 197                 if applied_thrust > 0.0 then
 198                         thrust_sprite.alpha = 1.0
 199
 200                 else if thrust_sprite.alpha > 0.0 then
 201                         thrust_sprite.alpha -= dt*4.0
 202                         if thrust_sprite.alpha < 0.0 then thrust_sprite.alpha = 0.0
 203                 end
 204
 205                 # HACK, the "enemy" ship used for the player points downwards
 206                 sprite.rotation += pi
 207         end
 208
 209         redef fun fire
 210         do
 211                 super
 212                 app.fx_fire.play
 213         end
 214
 215         redef fun hit
 216         do
 217                 super
 218                 app.fx_explosion_ship.play
 219         end
 220 end
 221
 222 redef class KeyEvent
 223
 224         # How does this event affect the ship thrust?
 225         fun thrust: Float
 226         do
 227                 if is_arrow_up or name == "w" then return 1.0
 228                 return 0.0
 229         end
 230
 231         # How does this event affect the ship thrust?
 232         fun rotation: Float
 233         do
 234                 if is_arrow_right or name == "d" then return -1.0
 235                 if is_arrow_left or name == "a" then return 1.0
 236                 return 0.0
 237         end
 238 end