lib/ordered_tree.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Manipulation and presentation of ordered trees.
  18 module ordered_tree
  19
  20 # Generic structure to manage and display an ordered tree
  21 #
  22 # Ordered tree are tree where the elements of a same parent are in a specific order
  23 #
  24 # Elements of the trees are added with the `add` method that takes a parent and
  25 # a sub-element.
  26 # If the parent is `null`, then the element is considered a root.
  27 #
  28 # ~~~~
  29 # var t = new OrderedTree[String]
  30 # t.add(null, "root")
  31 # t.add("root", "child1")
  32 # t.add("root", "child2")
  33 # t.add("child1", "grand-child")
  34 # assert t.length == 4
  35 # ~~~~
  36 #
  37 # By default, the elements with a same parent
  38 # are visited in the order they are added.
  39 #
  40 # ~~~
  41 # assert t.to_a == ["root", "child1", "grand-child", "child2"]
  42 # assert t.write_to_string == """
  43 # root
  44 # |--child1
  45 # |  `--grand-child
  46 # `--child2
  47 # """
  48 # ~~~
  49 #
  50 # The `sort_with` method can be used reorder elements
  51 #
  52 # ~~~
  53 # t.add("root", "aaa")
  54 # assert t.to_a == ["root", "child1", "grand-child", "child2", "aaa"]
  55 # t.sort_with(alpha_comparator)
  56 # assert t.to_a == ["root", "aaa", "child1", "grand-child", "child2"]
  57 # ~~~
  58 #
  59 # This class can be used as it to work with generic trees but can also be specialized to provide more specific
  60 # behavior or display. It is why the internal attributes are mutable.
  61 class OrderedTree[E: Object]
  62         super Writable
  63         super Collection[E]
  64         super Cloneable
  65
  66         # The roots of the tree (in sequence)
  67         var roots = new Array[E]
  68
  69         # The branches of the trees.
  70         # For each element, the ordered array of its direct sub-elements.
  71         var sub = new HashMap[E, Array[E]]
  72
  73         # The parent of each element.
  74         #
  75         # Roots have `null` as parent.
  76         private var parents = new HashMap[E, nullable E]
  77
  78         redef fun length do return parents.length
  79
  80         redef fun has(e) do return parents.has_key(e)
  81
  82         # The parent of the element `e`
  83         #
  84         # Roots have `null` as parent.
  85         #
  86         # ~~~
  87         # var tree = new OrderedTree[Int]
  88         # tree.add(1, 2)
  89         # assert tree.parent(2) == 1
  90         # assert tree.parent(1) == null
  91         # ~~~
  92         fun parent(e: E): nullable E do return parents[e]
  93
  94         # Add a new element `e` in the tree.
  95         #
  96         # `p` is the parent of `e`.
  97         # If `p` is null, then `e` is a root element.
  98         #
  99         # If `e` is already in the tree, it is detached from its old
 100         # parent and attached to the new parent `p`.
 101         fun add(p: nullable E, e: E)
 102         do
 103                 detach(e)
 104                 parents[e] = p
 105                 if p == null then
 106                         roots.add(e)
 107                 else
 108                         if not has(p) then add(null, p)
 109                         if sub.has_key(p) then
 110                                 sub[p].add(e)
 111                         else
 112                                 sub[p] = [e]
 113                         end
 114                 end
 115         end
 116
 117         # Append all nodes `es` as children of `p`.
 118         fun add_all(p: nullable E, es: Collection[E])
 119         do
 120                 for e in es do add(p, e)
 121         end
 122
 123         # Temporary remove `e`.
 124         #
 125         # Children of `e` are left untouched in the tree.
 126         # This make the tree inconstant until `e` is added back.
 127         private fun detach(e: E)
 128         do
 129                 var old_parent = parents.get_or_null(e)
 130                 if old_parent != null then
 131                         sub[old_parent].remove(e)
 132                 else if roots.has(e) then
 133                         roots.remove(e)
 134                 end
 135         end
 136
 137         # print the full tree on `o`
 138         # Write a ASCII-style tree and use the `display` method to label elements
 139         redef fun write_to(stream: Writer)
 140         do
 141                 for r in roots do
 142                         stream.write display(r)
 143                         stream.write "\n"
 144                         sub_write_to(stream, r, "")
 145                 end
 146         end
 147
 148         private fun sub_write_to(o: Writer, e: E, prefix: String)
 149         do
 150                 if not sub.has_key(e) then return
 151                 var subs = sub[e]
 152                 var last = subs.last
 153                 for e2 in subs do
 154                         if e2 != last then
 155                                 o.write "{prefix}|--{display(e2)}\n"
 156                                 sub_write_to(o, e2, prefix+"|  ")
 157                         else
 158                                 o.write "{prefix}`--{display(e2)}\n"
 159                                 sub_write_to(o, e2, prefix+"   ")
 160                         end
 161                 end
 162         end
 163
 164         # Sort roots and other elements using a comparator method
 165         # This method basically sorts roots then each group of children
 166         fun sort_with(comparator: Comparator)
 167         do
 168                 comparator.sort(roots)
 169                 for a in sub.values do
 170                         comparator.sort(a)
 171                 end
 172         end
 173
 174         # How to display a specific element of the tree
 175         # By defaut, uses `to_s`
 176         #
 177         # Subclasses should redefine this method to provide a specific output
 178         fun display(e: E): String do return e.to_s
 179
 180         # Get an array of the contained elements
 181         # Order is preserved
 182         #
 183         #     var tree = new OrderedTree[Int]
 184         #     tree.add_all(null, [1, 2])
 185         #     tree.add_all(1, [11, 12])
 186         #     tree.add_all(11, [111, 112])
 187         #     tree.add_all(12, [121, 122])
 188         #     tree.add_all(2, [21, 22])
 189         #     assert tree.to_a == [1, 11, 111, 112, 12, 121, 122, 2, 21, 22]
 190         redef fun to_a: Array[E] do
 191                 var res = new Array[E]
 192                 for r in roots do sub_to_a(r, res)
 193                 return res
 194         end
 195
 196         private fun sub_to_a(e: E, res: Array[E]) do
 197                 res.add e
 198                 if sub.has_key(e) then for e2 in sub[e] do sub_to_a(e2, res)
 199         end
 200
 201         #     var tree = new OrderedTree[Int]
 202         #     assert tree.is_empty
 203         #     tree.add(null, 1)
 204         #     assert not tree.is_empty
 205         redef fun is_empty: Bool do return roots.is_empty
 206
 207         #     var tree = new OrderedTree[Int]
 208         #     tree.add(null, 1)
 209         #     tree.add(1, 11)
 210         #     assert tree.first == 1
 211         redef fun first do return roots.first
 212
 213         #     var tree = new OrderedTree[Int]
 214         #     tree.add_all(null, [1, 2])
 215         #     tree.add_all(1, [11, 12])
 216         #     tree.add_all(11, [111, 112])
 217         #     tree.add_all(12, [121, 122])
 218         #     tree.add_all(2, [21, 22])
 219         #     var order = [1, 11, 111, 112, 12, 121, 122, 2, 21, 22]
 220         #     assert tree.iterator.to_a == order
 221         redef fun iterator do return new OrderedTreeIterator[E](self)
 222
 223         # Two trees are equal if they have the same nodes in the same order
 224         #
 225         # ~~~
 226         # var t1 = new OrderedTree[Int]
 227         # t1.add_all(null, [1, 2])
 228         # t1.add_all(1, [11, 12])
 229         #
 230         # var t2 = new OrderedTree[Int]
 231         # t2.add_all(null, [1, 2])
 232         #
 233         # assert t1 != t2
 234         #
 235         # t2.add_all(1, [11, 12])
 236         #
 237         # assert t1 == t2
 238         # ~~~
 239         redef fun ==(other)
 240         do
 241                 if not other isa OrderedTree[Object] then return false
 242                 return roots == other.roots and sub == other.sub
 243         end
 244
 245         redef fun hash
 246         do
 247                 return roots.hash + sub.hash
 248         end
 249
 250         # Shallow clone of the tree.
 251         #
 252         # ~~~
 253         # var t = new OrderedTree[Int]
 254         # t.add_all(null, [1, 2])
 255         # t.add_all(1, [11, 12])
 256         #
 257         # assert t.clone == t
 258         # ~~~
 259         redef fun clone
 260         do
 261                 var res = new OrderedTree[E]
 262                 res.add_all(null, roots)
 263                 for p, es in sub do
 264                         res.add_all(p, es)
 265                 end
 266                 return res
 267         end
 268 end
 269
 270 # An Iterator over an OrderedTree
 271 private class OrderedTreeIterator[E: Object]
 272         super Iterator[E]
 273
 274         var tree: OrderedTree[E]
 275
 276         var iterators = new Array[Iterator[E]]
 277
 278         init do
 279                 if not tree.is_empty then
 280                         iterators.add tree.roots.iterator
 281                 end
 282         end
 283
 284         redef fun is_ok do return not iterators.is_empty
 285
 286         redef fun item do
 287                 assert is_ok
 288                 return iterators.last.item
 289         end
 290
 291         redef fun next do
 292                 assert is_ok
 293                 if tree.sub.has_key(item) then
 294                         iterators.add tree.sub[item].iterator
 295                 else
 296                         iterators.last.next
 297                         while is_ok and not iterators.last.is_ok do
 298                                 iterators.pop
 299                                 if is_ok and iterators.last.is_ok then
 300                                         iterators.last.next
 301                                 end
 302                         end
 303                 end
 304         end
 305
 306         redef fun iterator do return new OrderedTreeIterator[E](tree)
 307 end