src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'meth' | 'fun'; //FIXME: Remove the 'meth' alternative once the transition is done
  69 kwtype = 'type';
  70 kwattr = 'attr'; //FIXME: remove kwattr once the transition is done
  71 kwinit = 'init';
  72 kwredef = 'redef';
  73 kwis = 'is';
  74 kwdo = 'do';
  75 kwreadable = 'readable';
  76 kwwritable = 'writable';
  77 kwvar = 'var';
  78 kwintern = 'intern';
  79 kwextern = 'extern';
  80 kwprotected = 'protected';
  81 kwprivate = 'private';
  82 kwintrude = 'intrude';
  83 kwif = 'if';
  84 kwthen = 'then';
  85 kwelse = 'else';
  86 kwwhile = 'while';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwwith = 'with';
 107
 108 opar = '(';
 109 cpar = ')';
 110 obra = '[';
 111 cbra = ']';
 112 comma = ',';
 113 column = ':';
 114 quad = '::';
 115 assign = '=';
 116 pluseq = '+=';
 117 minuseq = '-=';
 118 dotdotdot = '...';
 119 dotdot = '..';
 120 dot = '.';
 121 plus = '+';
 122 minus = '-';
 123 star = '*';
 124 slash = '/';
 125 percent = '%';
 126 eq = '==';
 127 ne = '!=';
 128 lt = '<';
 129 le = '<=';
 130 gt = '>';
 131 ge = '>=';
 132 starship = '<=>';
 133
 134 classid = uppercase letter*;
 135 id = lowercase letter*;
 136 attrid = '_' lowercase letter*;
 137
 138 number = digit+;
 139 float = digit* '.' digit+;
 140 char = ''' [any - ''']* ''';
 141 string = '"' str_body '"';
 142 start_string = '"' str_body '{';
 143 mid_string = '}' str_body '{';
 144 end_string = '}' str_body '"';
 145
 146
 147 /*****************************************************************************/
 148 Ignored Tokens
 149 /*****************************************************************************/
 150
 151 blank;
 152
 153 /*****************************************************************************/
 154 Productions
 155 /*****************************************************************************/
 156
 157 /* MODULES *******************************************************************/
 158 module
 159         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 160
 161 packagedecl
 162         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 163
 164 import
 165         = [doc]:no visibility kwimport no id [n2]:n1            {-> New import(visibility, kwimport, id)}
 166         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 167         ;
 168
 169 implicit_top_class {-> classdef}
 170         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 171
 172 implicit_main_class {-> classdef?}
 173         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 174         | {null} n {-> Null}
 175         ;
 176 implicit_main_meth {-> propdef}
 177         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 178
 179 /* CLASSES *******************************************************************/
 180 classdef
 181         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 182 redef {-> kwredef?}
 183         = kwredef? {-> kwredef};
 184 classkind
 185         = {concrete} kwclass
 186         | {abstract} kwabstract kwclass
 187         | {interface} kwinterface
 188         | {universal} kwuniversal
 189         ;
 190
 191 formaldefs {-> formaldef*}
 192         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 193 formaldefs_tail {-> formaldef}
 194         = comma no formaldef {-> formaldef};
 195 formaldef
 196         = classid typing? {-> New formaldef(classid, typing.type)};
 197
 198 special {-> superclass}
 199         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 200
 201 propdefs~toplevel {-> propdef*}
 202         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 203         ;
 204 propdefs_tail~toplevel {-> propdef}
 205         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 206         ;
 207 propdef~toplevel {-> propdef}
 208         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 209 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 210 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 211         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 212 //FIXME: Remove attr alternative once the transition is done
 213 !toplevel| {attr} [doc]:no readable writable redef visibility kwattr attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, Null, attrid, typing.type, Null)}
 214 !toplevel| {attr2} [doc]:no readable writable redef visibility kwattr attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, Null, attrid, typing.type, expr)}
 215 !toplevel| {var} [doc]:no readable writable redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, Null, kwvar, attrid, typing.type, Null)}
 216 !toplevel| {var2} [doc]:no readable writable redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, Null, kwvar, attrid, typing.type, expr)}
 217 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 218 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 219         ;
 220 readable {-> able?}
 221         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 222         | {empty} {-> Null}
 223         ;
 224 writable {-> able?}
 225         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 226         | {empty} {-> Null}
 227         ;
 228
 229 visibility
 230         = {public} {-> New visibility.public()}
 231         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 232         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 233         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 234         ;
 235
 236 methid
 237         = {id} id
 238         | {plus} plus
 239         | {minus} minus
 240         | {star} star
 241         | {slash} slash
 242         | {percent} percent
 243         | {eq} eq
 244         | {ne} ne
 245         | {le} le
 246         | {ge} ge
 247         | {lt} lt
 248         | {gt} gt
 249         | {bra} obra cbra
 250         | {starship} starship
 251         | {assign} id assign
 252         | {braassign} obra cbra assign
 253         ;
 254
 255 signature
 256         = params? typing? closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 257         | {noclosures} params? typing? no {-> New signature([params.param], typing.type, [])}
 258         ;
 259
 260 signature_noclosures {-> signature}
 261         = params? typing? {-> New signature([params.param], typing.type, [])};
 262
 263 params {-> param*}
 264         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 265         | {empty} opar no cpar {-> []}
 266         ;
 267 params_tail {-> param}
 268         = comma no param {-> param};
 269 param
 270         = {untyped} id {-> New param(id, Null, Null)}
 271         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 272         ;
 273
 274 closure_decls {->closure_decl*}
 275         = no closure_decl+ {-> [closure_decl]};
 276 closure_decl
 277         = kwwith kwbreak? [no2]:no id signature_noclosures n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, Null)}
 278         | {optionnal} kwwith kwbreak? [no2]:no id signature_noclosures kwdo stmtso n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, stmtso.expr)}
 279         ;
 280
 281 /* TYPES *********************************************************************/
 282 type~nobra {-> type}
 283         = {simple} classid {-> New type(classid, [])}
 284 !nobra  | {generic} classid obra no types [n2]:no cbra {-> New type(classid, [types.type])}
 285         ;
 286 types {-> type*}
 287         = type types_tail* {-> [type, types_tail.type]};
 288 types_tail {-> type}
 289         = comma no type {-> type};
 290 typing {-> type}
 291         = column no type {-> type};
 292
 293 /* STATMENTS *****************************************************************/
 294 stmtso~withelse {-> expr?}
 295         = {oneline} stmt~withelse {-> stmt~withelse.expr}
 296         | {block} n stmts [n2]:n kwend {-> stmts.expr}
 297         | {emptyblock} n kwend {-> New expr.block([])}
 298         | {emptyoneline} kwend {-> New expr.block([])}
 299         ;
 300 stmts {-> expr}
 301         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 302 stmts_tail {-> expr}
 303         = n stmt {-> stmt.expr};
 304 stmt~withelse {-> expr}
 305         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 306         | {assign} assignment~withelse {-> assignment~withelse.expr}
 307         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 308         | {break} kwbreak expr_final~withelse? {-> New expr.break(kwbreak, expr_final~withelse.expr)}
 309         | {abort} kwabort {-> New expr.abort(kwabort)}
 310         | {continue} kwcontinue expr_final~withelse? {-> New expr.continue(kwcontinue, expr_final~withelse.expr)}
 311         | {do} do~withelse {-> do~withelse.expr}
 312         | {if} if~withelse {-> if~withelse.expr}
 313         | {while} while~withelse {-> while~withelse.expr}
 314         | {for} for~withelse {-> for~withelse.expr}
 315         | {assert} assert~withelse {-> assert~withelse.expr}
 316         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 317         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 318         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 319         ;
 320
 321 closure_defs~withelse {-> closure_def*}
 322         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 323         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 324         ;
 325
 326 closure_def_last~withelse {-> closure_def}
 327         = kwwith idlist? kwdo stmtso~withelse {-> New closure_def(kwwith, [idlist.id], kwdo, stmtso~withelse.expr)}
 328         ;
 329
 330 closure_def {-> closure_def}
 331         = kwwith idlist? kwdo n stmts [n2]:n {-> New closure_def(kwwith, [idlist.id], kwdo, stmts.expr)}
 332         | {empty} kwwith idlist? kwdo n {-> New closure_def(kwwith, [idlist.id], kwdo, Null)}
 333         ;
 334
 335 vardecl~withelse{-> expr}
 336         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 337         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 338         ;
 339
 340 assignment~withelse {-> expr}
 341         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 342         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 343         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 344         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 345         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 346         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 347         ;
 348 assign_op
 349         = {plus} pluseq
 350         | {minus} minuseq
 351         ;
 352
 353 do~withelse {-> expr}
 354         = kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr)}
 355         ;
 356
 357 if~withelse {-> expr}
 358         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 359 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 360 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 361 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 362         ;
 363 elsepartblock {-> expr?}
 364         = {else} kwelse stmtso {-> stmtso.expr}
 365         | {empty} kwend {-> Null}
 366         ;
 367
 368 while~withelse {-> expr}
 369         = kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr)};
 370
 371 for~withelse {-> expr}
 372         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse.expr)};
 373
 374 assert~withelse {-> expr}
 375         = kwassert assertid? expr_final~withelse {-> New expr.assert(kwassert, assertid.id, expr_final~withelse.expr)};
 376 assertid {-> id}
 377         = id column {-> id};
 378
 379 /* EXPRESSIONS ***************************************************************/
 380 expr_final~nopar~withelse~nobra {-> expr}
 381         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 382         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 383 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 384         ;
 385
 386 expr~nopar~nobra {-> expr}
 387         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 388         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 389         ;
 390
 391 expr_and~nopar~nobra {-> expr}
 392         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 393         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 394         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 395         ;
 396
 397 expr_not~nopar~nobra {-> expr}
 398         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 399         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 400         ;
 401
 402 expr_eq~nopar~nobra {-> expr}
 403         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 404         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 405         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 406         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 407         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 408         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 409         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 410         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 411         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 412         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 413         ;
 414
 415 expr_add~nopar~nobra {-> expr}
 416         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 417         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 418         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 419         ;
 420
 421 expr_mul~nopar~nobra {-> expr}
 422         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 423         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 424         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 425         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 426         ;
 427
 428 expr_minus~nopar~nobra {-> expr}
 429         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 430         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 431         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 432         ;
 433
 434 expr_new~nopar~nobra {-> expr}
 435         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 436         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 437         ;
 438
 439 expr_atom~nopar~nobra {-> expr}
 440         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 441         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 442         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 443         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 444 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 445         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 446 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 447 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 448 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 449         | {self} kwself {-> New expr.self(kwself)}
 450         | {true} kwtrue {-> New expr.true(kwtrue)}
 451         | {false} kwfalse {-> New expr.false(kwfalse)}
 452         | {null} kwnull {-> New expr.null(kwnull)}
 453         | {int} number  {-> New expr.int(number)}
 454         | {float} float  {-> New expr.float(float)}
 455         | {char} char  {-> New expr.char(char)}
 456         | {string} string  {-> New expr.string(string)}
 457         | {superstring} superstring  {-> superstring.expr}
 458 !nopar  | {par} opar expr cpar {-> expr}
 459         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 460         ;
 461
 462 superstring {-> expr}
 463         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 464 superstring_start {-> expr*}
 465         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 466 start_string_p {-> expr}
 467         = start_string {-> New expr.start_string(start_string)};
 468 superstring_middle {-> expr*}
 469         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 470 mid_string_p {-> expr}
 471         = mid_string {-> New expr.mid_string(mid_string)};
 472 superstring_end {-> expr}
 473         = end_string {-> New expr.end_string(end_string)};
 474
 475 /* MISC **********************************************************************/
 476
 477 recv~nopar~nobra {-> expr}
 478         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 479         | {implicit} {-> New expr.implicit_self()}
 480         ;
 481
 482 args {-> expr*}
 483         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 484         | {emptypar} opar no cpar {-> []}
 485         | {empty} {-> []}
 486         ;
 487 args_nopar {-> expr*}
 488         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 489         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 490         | {emptypar} opar no cpar {-> []}
 491         | {empty} {-> []}
 492         ;
 493 braargs {-> expr*}
 494         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 495 args_tail {-> expr}
 496         = comma no expr [n2]:no {-> expr};
 497 idlist {-> id*}
 498         = {single} id {-> [id]}
 499         | {more} idlist no comma [n2]:no id {-> [idlist.id, id]}
 500         ;
 501
 502 qualified
 503         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 504         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 505         ;
 506 modquad {-> id}
 507         = id quad no {-> id};
 508 classquad {-> classid}
 509         = classid quad no {-> classid};
 510
 511 n1      = {a} comment | {b} eol;
 512 n {-> doc?}
 513         = {a} n2? comment+ {-> New doc([comment])}
 514         | {b} n2 {-> Null}
 515         ;
 516 no {-> doc?}
 517         = {empty} {-> Null}
 518         | n {-> n.doc}
 519         ;
 520
 521 n2
 522         = {a} n2? comment+ eol+
 523         | {b} eol+
 524         ;
 525
 526 /*****************************************************************************/
 527 Abstract Syntax Tree
 528 /*****************************************************************************/
 529
 530 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 531
 532 packagedecl
 533         = doc? kwpackage id;
 534
 535 import  =  visibility kwimport id
 536         | {no} visibility kwimport kwend
 537         ;
 538
 539 visibility
 540         = {public}
 541         | {private} kwprivate
 542         | {protected} kwprotected
 543         | {intrude} kwintrude
 544         ;
 545
 546 classdef = doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 547         | {top} [propdefs]:propdef*
 548         | {main} [propdefs]:propdef*
 549         ;
 550 classkind
 551         = {concrete} kwclass
 552         | {abstract} kwabstract kwclass
 553         | {interface} kwinterface
 554         | {universal} kwuniversal
 555         ;
 556 formaldef = [id]:classid type?;
 557 superclass = kwspecial type;
 558
 559
 560 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwattr? kwvar? [id]:attrid type? expr? // Remove the kwattr? once the transition is done
 561         | {meth} doc? kwredef? visibility methid signature
 562         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 563         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 564         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 565         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 566         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 567         | {main_meth} kwredef? [block]:expr?
 568         | {type} doc? kwredef? visibility kwtype [id]:classid type
 569         ;
 570
 571 able    = {read} kwredef? kwreadable
 572         | {write} kwredef? kwwritable
 573         ;
 574
 575 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 576
 577 signature = [params]:param* type? [closure_decls]:closure_decl*;
 578
 579 param   = id type? dotdotdot?
 580         ;
 581
 582 closure_decl = kwwith kwbreak? id signature expr?
 583         ;
 584
 585 type    = [id]:classid [types]:type*;
 586
 587 expr    = {block} expr*
 588         | {vardecl} kwvar id type? assign? expr?
 589         | {return} kwreturn expr?
 590         | {break} kwbreak expr?
 591         | {abort} kwabort
 592         | {continue} kwcontinue expr?
 593         | {do} kwdo [block]:expr?
 594         | {if} kwif expr [then]:expr? [else]:expr?
 595         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 596         | {while} kwwhile expr kwdo [block]:expr?
 597         | {for} kwfor id expr kwdo [block]:expr?
 598         | {assert} kwassert id? expr
 599         | {once} kwonce expr
 600         | {send} expr
 601         | {binop} expr [expr2]:expr
 602         | {or} expr [expr2]:expr
 603         | {and} expr [expr2]:expr
 604         | {not} kwnot expr
 605         | {eq} expr [expr2]:expr
 606         | {ee} expr [expr2]:expr
 607         | {ne} expr [expr2]:expr
 608         | {lt} expr [expr2]:expr
 609         | {le} expr [expr2]:expr
 610         | {gt} expr [expr2]:expr
 611         | {ge} expr [expr2]:expr
 612         | {isa} expr type
 613         | {plus} expr [expr2]:expr
 614         | {minus} expr [expr2]:expr
 615         | {starship} expr [expr2]:expr
 616         | {star} expr [expr2]:expr
 617         | {slash} expr [expr2]:expr
 618         | {percent} expr [expr2]:expr
 619         | {uminus} minus expr
 620         | {new} kwnew type id? [args]:expr*
 621         | {attr} expr [id]:attrid
 622         | {attr_assign} expr [id]:attrid assign [value]:expr
 623         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 624         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 625         | {call_assign} expr id [args]:expr* assign [value]:expr
 626         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 627         | {super} qualified? kwsuper [args]:expr*
 628         | {init} expr kwinit [args]:expr*
 629         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 630         | {bra_assign} expr [args]:expr* assign [value]:expr
 631         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 632         | {var} id
 633         | {var_assign} id assign [value]:expr
 634         | {var_reassign} id assign_op [value]:expr
 635         | {range} expr [expr2]:expr
 636         | {crange} expr [expr2]:expr
 637         | {orange} expr [expr2]:expr
 638         | {array} [exprs]:expr*
 639         | {self} kwself
 640         | {implicit_self}
 641         | {true} kwtrue
 642         | {false} kwfalse
 643         | {null} kwnull
 644         | {int} number
 645         | {float} float
 646         | {char} char
 647         | {string} string
 648         | {start_string} [string]:start_string
 649         | {mid_string} [string]:mid_string
 650         | {end_string} [string]:end_string
 651         | {superstring} [exprs]:expr*
 652         | {par} expr
 653         | {as_cast} expr kwas type
 654         ;
 655 assign_op
 656         = {plus} pluseq
 657         | {minus} minuseq
 658         ;
 659
 660 closure_def
 661         = kwwith id* kwdo expr?
 662         ;
 663
 664 qualified = id* classid? ;
 665
 666 doc = comment+;
 667
 668 /*****************************************************************************/
 669