src/mmloader.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2006-2008 Floréal Morandat <morandat@lirmm.fr>
   4 # Copyright 2008 Jean Privat <jean@pryen.org>
   5 #
   6 # Licensed under the Apache License, Version 2.0 (the "License");
   7 # you may not use this file except in compliance with the License.
   8 # You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 # This package is used to load a metamodel
  19 package mmloader
  20
  21 import metamodel
  22 import opts
  23
  24 # Global context for tools
  25 class ToolContext
  26 special MMContext
  27         # Number of errors
  28         readable attr _error_count: Int = 0
  29
  30         # Number of warnings
  31         readable attr _warning_count: Int = 0
  32
  33         # Display an error
  34         meth error(s: String)
  35         do
  36                 stderr.write("{s}\n")
  37                 _error_count = _error_count + 1
  38         end
  39
  40         # Display a warning
  41         meth warning(s: String)
  42         do
  43                 if _opt_warn.value == 0 then return
  44                 stderr.write("{s}\n")
  45                 if _opt_warn.value == 1 then
  46                         _warning_count = _warning_count + 1
  47                 else
  48                         _error_count = _error_count + 1
  49                 end
  50         end
  51
  52         # Paths where to locate modules files
  53         readable attr _paths: Array[String]
  54
  55         # List of module loaders
  56         attr _loaders: Array[ModuleLoader] = new Array[ModuleLoader]
  57
  58         # Global OptionContext
  59         readable attr _option_context: OptionContext = new OptionContext
  60
  61         # Option --warn
  62         readable attr _opt_warn: OptionCount = new OptionCount("Show warnings", "-W", "--warn")
  63
  64         # Option --path
  65         readable attr _opt_path: OptionArray = new OptionArray("Set include path for loaders (may be used more than once)", "-I", "--path")
  66
  67         # Option --lop
  68         readable attr _opt_log: OptionBool = new OptionBool("Generate various log files", "--log")
  69
  70         # Option --only-metamodel
  71         readable attr _opt_only_metamodel: OptionBool = new OptionBool("Stop after meta-model processing", "--only-metamodel")
  72
  73         # Option --only-parse
  74         readable attr _opt_only_parse: OptionBool = new OptionBool("Only proceed to parse step of loaders", "--only-parse")
  75
  76         # Option --help
  77         readable attr _opt_help: OptionBool = new OptionBool("Show Help (This screen)", "-h", "-?", "--help")
  78
  79         init
  80         do
  81                 super
  82                 option_context.add_option(opt_warn, opt_path, opt_log, opt_only_parse, opt_only_metamodel, opt_help)
  83         end
  84
  85         # Parse and process the options given on the command line
  86         meth process_options
  87         do
  88                 # init options
  89                 option_context.parse(args)
  90
  91                 # Setup the paths value
  92                 _paths = new Array[String]
  93                 paths.append(opt_path.value)
  94
  95                 var path_env = once ("NIT_PATH".to_symbol).environ
  96                 if not path_env.is_empty then
  97                         paths.append(path_env.split_with(':'))
  98                 end
  99
 100                 path_env = once ("NIT_DIR".to_symbol).environ
 101                 if not path_env.is_empty then
 102                         var libname = "{path_env}/lib"
 103                         if libname.file_exists then paths.add(libname)
 104                 end
 105
 106                 var libname = "{sys.program_name.dirname}/../lib"
 107                 if libname.file_exists then paths.add(libname)
 108         end
 109
 110         # Load and process a module in a directory (or a parent directory).
 111         # If the module is already loaded, just return it without further processing.
 112         # If no module is found, just return null without complaining.
 113         private meth try_to_load(module_name: Symbol, dir: MMDirectory): MMModule
 114         do
 115                 # Look in the module directory
 116                 for m in dir.modules do
 117                         if m.name == module_name then return m
 118                 end
 119
 120                 # print "try to load {module_name} in {dir.name} {_loaders.length}"
 121
 122                 for l in _loaders do
 123                         var dir2 = l.try_to_load_dir(module_name, dir)
 124                         if dir2 != null then
 125                                 var m = try_to_load(module_name, dir2)
 126                                 if m != null then
 127                                         dir2.owner = m
 128                                         dir.add_module(m)
 129                                         return m
 130                                 end
 131                         end
 132
 133                         if l.can_handle(module_name, dir) then
 134                                 var full_name = dir.full_name_for(module_name)
 135                                 if _processing_modules.has(full_name) then
 136                                         # FIXME: Generate better error
 137                                         error("Error: Dependency loop for module {full_name}")
 138                                         exit(1)
 139                                         abort
 140                                 end
 141                                 _processing_modules.add(full_name)
 142                                 var m = l.load_and_process_module(self, module_name, dir)
 143                                 _processing_modules.remove(full_name)
 144                                 #if m != null then print "loaded {m.name} in {m.directory.name} -> {m.full_name} ({m.full_name.object_id.to_hex})"
 145                                 dir.add_module(m)
 146                                 return m
 147                         end
 148                 end
 149                 return null
 150         end
 151
 152         # List of module currently processed.
 153         # Used to prevent dependence loops.
 154         attr _processing_modules: HashSet[Symbol] = new HashSet[Symbol]
 155
 156         # Locate, load and analysis a module (and its supermodules) from its file name.
 157         # If the module is already loaded, just return it without further processing.
 158         # Beware, the files are automatically considered root of their directory.
 159         meth get_module_from_filename(filename: String): MMModule
 160         do
 161                 var path = filename.dirname
 162                 var module_name = filename.basename(".nit").to_symbol
 163
 164                 var dir = directory_for(path)
 165
 166                 if module_name.to_s == filename then
 167                         # It's just a modulename
 168                         # look for it in the path directory "."
 169                         var m = try_to_load(module_name, dir)
 170                         if m != null then return m
 171
 172                         # Else look for it in the path
 173                         return get_module(module_name, null)
 174                 end
 175
 176                 if not filename.file_exists then
 177                         error("Error: File {filename} not found.")
 178                         exit(1)
 179                         abort
 180                 end
 181
 182                 # Try to load the module where mentionned
 183                 var m = try_to_load(module_name, dir)
 184                 if m != null then return m
 185
 186                 error("Error: {filename} is not a NIT source module.")
 187                 exit(1)
 188                 abort
 189         end
 190
 191         # Locate, load and analysis a module (and its supermodules).
 192         # If the module is already loaded, just return it without further processing.
 193         meth get_module(module_name: Symbol, from: MMModule): MMModule
 194         do
 195                 var m: MMModule
 196                 if from != null then
 197                         var dir = from.directory
 198                         while dir != null do
 199                                 var m = try_to_load(module_name, dir)
 200                                 if m != null then return m
 201                                 dir = dir.parent
 202                         end
 203                 end
 204
 205                 for p in paths do
 206                         var m = try_to_load(module_name, directory_for(p))
 207                         if m != null then return m
 208                 end
 209                 # FIXME: Generate better error
 210                 error("Error: No ressource found for module {module_name}.")
 211                 exit(1)
 212                 abort
 213         end
 214
 215         # Return the module directory associated with a given path
 216         private meth directory_for(path: String): MMDirectory
 217         do
 218                 if _path_dirs.has_key(path) then return _path_dirs[path]
 219                 var dir = new MMDirectory(path.to_symbol, path, null)
 220                 _path_dirs[path] = dir
 221                 return dir
 222         end
 223
 224         # Association bwtween plain path and module directories
 225         attr _path_dirs: Map[String, MMDirectory] = new HashMap[String, MMDirectory]
 226
 227         # Register a new module loader
 228         meth register_loader(ml: ModuleLoader) do _loaders.add(ml)
 229 end
 230
 231 # A load handler know how to load a specific module type
 232 class ModuleLoader
 233         # Type of module loaded by the loader
 234         type MODULE: MMModule
 235
 236         # Extension that the loadhandler accepts
 237         meth file_type: String is abstract
 238
 239         # Try to load a new module directory
 240         meth try_to_load_dir(dirname: Symbol, parent_dir: MMDirectory): MMDirectory
 241         do
 242                 var fname = "{parent_dir.path}/{dirname}/"
 243                 if not fname.file_exists then return null
 244
 245                 var dir = new MMDirectory(parent_dir.full_name_for(dirname), fname, parent_dir)
 246                 return dir
 247         end
 248
 249         # Can the loadhandler load a given module?
 250         # Return the file found
 251         meth can_handle(module_name: Symbol, dir: MMDirectory): Bool
 252         do
 253                 var fname = "{dir.path}/{module_name}.{file_type}"
 254                 if fname.file_exists then return true
 255                 return false
 256         end
 257
 258         # Load the module and process it
 259         # filename is the result of can_handle
 260         meth load_and_process_module(context: ToolContext, module_name: Symbol, dir: MMDirectory): MODULE
 261         do
 262                 var filename = "{dir.path}/{module_name}.{file_type}"
 263                 var m = load_module(context, module_name, dir, filename)
 264                 if not context.opt_only_parse.value then process_metamodel(context, m)
 265                 return m
 266         end
 267
 268         # Load an parse the module
 269         private meth load_module(context: ToolContext, module_name: Symbol, dir: MMDirectory, filename: String): MODULE
 270         do
 271                 var file: IFStream
 272                 if filename == "-" then
 273                         file = stdin
 274                 else
 275                         file = new IFStream.open(filename.to_s)
 276                 end
 277
 278                 if file.eof then
 279                         context.error("Error: Problem in opening file {filename}")
 280                         exit(1)
 281                         abort
 282                 end
 283                 var m = parse_file(context, file, filename, module_name, dir)
 284                 if file != stdin then file.close
 285                 return m
 286         end
 287
 288         # Parse the file to load a module
 289         protected meth parse_file(context: ToolContext, file: IFStream, filename: String, module_name: Symbol, dir: MMDirectory): MODULE is abstract
 290
 291         # Process a parsed module
 292         protected meth process_metamodel(context: ToolContext, module: MODULE) is abstract
 293 end
 294
 295 redef class MMModule
 296         # Recurcivelty process an import modules
 297         meth import_supers_modules(names: Collection[Symbol])
 298         do
 299                 var c = context
 300                 assert c isa ToolContext
 301                 var supers = new Array[MMModule]
 302                 for n in names do
 303                         var m = c.get_module(n, self)
 304                         supers.add(m)
 305                 end
 306                 c.add_module(self,supers)
 307         end
 308 end