src/model/mproject.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Modelisation of a Nit project
  16 module mproject
  17
  18 import model_base
  19 private import more_collections
  20 import poset
  21 import mdoc
  22
  23 # A Nit project, that encompass a product
  24 class MProject
  25         super MConcern
  26
  27         # The name of the project
  28         redef var name: String
  29
  30         redef fun full_name do return name
  31
  32         redef var c_name = name.to_cmangle is lazy
  33
  34         # The model of the project
  35         redef var model: Model
  36
  37         # The root of the group tree
  38         var root: nullable MGroup = null is writable
  39
  40         # The group tree, as a POSet
  41         var mgroups = new POSet[MGroup]
  42
  43         redef fun to_s do return name
  44
  45         init
  46         do
  47                 model.mprojects.add(self)
  48                 model.mproject_by_name.add_one(name, self)
  49         end
  50
  51         # MProject are always roots of the concerns hierarchy
  52         redef fun parent_concern do return null
  53
  54         redef fun mdoc_or_fallback
  55         do
  56                 if mdoc != null then return mdoc
  57                 return root.mdoc_or_fallback
  58         end
  59 end
  60
  61 # A group of modules in a project
  62 class MGroup
  63         super MConcern
  64
  65         # The name of the group
  66         # empty name for a default group in a single-module project
  67         redef var name: String
  68
  69         # The enclosing project
  70         var mproject: MProject
  71
  72         # The parent group if any
  73         # see `in_nesting` for more
  74         var parent: nullable MGroup
  75
  76         # Fully qualified name.
  77         # It includes each parent group separated by `/`
  78         redef fun full_name
  79         do
  80                 var p = parent
  81                 if p == null then return name
  82                 return "{p.full_name}/{name}"
  83         end
  84
  85         # The group is the group tree on the project (`mproject.mgroups`)
  86         # nested groups (children) are smaller
  87         # nesting group (see `parent`) is bigger
  88         var in_nesting: POSetElement[MGroup] is noinit
  89
  90         # Is `self` the root of its project?
  91         fun is_root: Bool do return mproject.root == self
  92
  93         # The filepath (usually a directory) of the group, if any
  94         var filepath: nullable String = null is writable
  95
  96         init
  97         do
  98                 var tree = mproject.mgroups
  99                 self.in_nesting = tree.add_node(self)
 100                 var parent = self.parent
 101                 if parent != null then
 102                         tree.add_edge(self, parent)
 103                 end
 104         end
 105
 106         redef fun model do return mproject.model
 107
 108         redef fun parent_concern do
 109                 if not is_root then return parent
 110                 return mproject
 111         end
 112
 113         redef fun to_s do return name
 114 end
 115
 116 redef class Model
 117         # projects of the model
 118         var mprojects = new Array[MProject]
 119
 120         # Collections of project grouped by their names
 121         private var mproject_by_name = new MultiHashMap[String, MProject]
 122
 123         # Return all project named `name`
 124         # If such a project is not yet loaded, null is returned (instead of an empty array)
 125         fun get_mprojects_by_name(name: String): nullable Array[MProject]
 126         do
 127                 if mproject_by_name.has_key(name) then
 128                         return mproject_by_name[name]
 129                 else
 130                         return null
 131                 end
 132         end
 133 end