src/model/mmodule.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # modules and module hierarchies in the metamodel
  18 module mmodule
  19
  20 import location
  21 import mproject
  22 private import more_collections
  23
  24 # The container class of a Nit object-oriented model.
  25 # A model knows modules, classes and properties and can retrieve them.
  26 redef class Model
  27         # All known modules
  28         var mmodules = new Array[MModule]
  29
  30         # Full module importation hierarchy including private or nested links.
  31         var mmodule_importation_hierarchy = new POSet[MModule]
  32
  33         # Collections of modules grouped by their short names
  34         private var mmodules_by_name = new MultiHashMap[String, MModule]
  35
  36         # Return all module named `name`
  37         # If such a module does not exist, null is returned (instead of an empty array)
  38         #
  39         # Visibility or modules are not considered
  40         fun get_mmodules_by_name(name: String): nullable Array[MModule]
  41         do
  42                 if mmodules_by_name.has_key(name) then
  43                         return mmodules_by_name[name]
  44                 else
  45                         return null
  46                 end
  47         end
  48 end
  49
  50 redef class MGroup
  51         # The loaded modules of this group
  52         var mmodules = new Array[MModule]
  53
  54         # The default module of a group (if any, and if loaded)
  55         #
  56         # The default module of a group is the one that has the same name.
  57         # Return `null` if the group has no default module or if the default
  58         # module is not loaded.
  59         var default_mmodule: nullable MModule = null
  60
  61         redef fun mdoc_or_fallback
  62         do
  63                 if mdoc != null then return mdoc
  64                 if default_mmodule == null then return null
  65                 return default_mmodule.mdoc_or_fallback
  66         end
  67 end
  68
  69 # A Nit module is usually associated with a Nit source file.
  70 class MModule
  71         super MConcern
  72
  73         # The model considered
  74         redef var model: Model
  75
  76         # The group of module in the project if any
  77         var mgroup: nullable MGroup
  78
  79         # The project of the module if any
  80         # Safe alias for `mgroup.mproject`
  81         fun mproject: nullable MProject
  82         do
  83                 var g = mgroup
  84                 if g == null then return null else return g.mproject
  85         end
  86
  87         # The short name of the module
  88         redef var name: String
  89
  90         # The origin of the definition
  91         var location: Location
  92
  93         # Alias for `name`
  94         redef fun to_s do return self.name
  95
  96         # The view of the module in the `model.mmodule_importation_hierarchy`
  97         var in_importation: POSetElement[MModule] is noinit
  98
  99         # The canonical name of the module.
 100         #
 101         # It is usually the `name` prefixed by the project's name.
 102         # Example: `"project::name"`
 103         #
 104         # If both names are the same (of if the module is project-less), then
 105         # the short-name is used alone.
 106         redef var full_name is lazy do
 107                 var mgroup = self.mgroup
 108                 if mgroup == null or mgroup.mproject.name == self.name then
 109                         return self.name
 110                 else
 111                         return "{mgroup.mproject.name}::{self.name}"
 112                 end
 113         end
 114
 115         # Return the name of the global C identifier associated to `self`.
 116         # This name is used to prefix files and other C identifiers associated with `self`.
 117         redef var c_name: String is lazy do
 118                 var g = mgroup
 119                 var res
 120                 if g != null and g.mproject.name != name then
 121                         res = g.mproject.name.to_cmangle + "__" + name.to_cmangle
 122                 else
 123                         res = name.to_cmangle
 124                 end
 125                 return res
 126         end
 127
 128
 129         # Create a new empty module and register it to a model
 130         init
 131         do
 132                 model.mmodules_by_name.add_one(name, self)
 133                 model.mmodules.add(self)
 134                 if mgroup != null then
 135                         mgroup.mmodules.add(self)
 136                         if mgroup.name == name then
 137                                 assert mgroup.default_mmodule == null
 138                                 mgroup.default_mmodule = self
 139                         end
 140                 end
 141                 self.in_importation = model.mmodule_importation_hierarchy.add_node(self)
 142         end
 143
 144         # Register the imported modules (ie "import some_module")
 145         # This function can only invoked once by mmodule.
 146         # The visibility must be set with `set_visibility_for`.
 147         fun set_imported_mmodules(imported_mmodules: Array[MModule])
 148         do
 149                 assert unique_invocation: self.in_importation.direct_greaters.is_empty
 150                 for m in imported_mmodules do
 151                         self.model.mmodule_importation_hierarchy.add_edge(self, m)
 152                 end
 153         end
 154
 155         private var intrude_mmodules = new HashSet[MModule]
 156         private var public_mmodules = new HashSet[MModule]
 157         private var private_mmodules = new HashSet[MModule]
 158
 159         # Return the visibility level of an imported module `m`
 160         fun visibility_for(m: MModule): MVisibility
 161         do
 162                 if m == self then return intrude_visibility
 163                 if self.intrude_mmodules.has(m) then return intrude_visibility
 164                 if self.public_mmodules.has(m) then return public_visibility
 165                 if self.private_mmodules.has(m) then return private_visibility
 166                 return none_visibility
 167         end
 168
 169         # Set the visibility of an imported module
 170         # REQUIRE: the visibility of the modules imported by `m` are already set for `m`
 171         fun set_visibility_for(m: MModule, v: MVisibility)
 172         do
 173                 if v == intrude_visibility then
 174                         self.intrude_mmodules.add(m)
 175                         self.intrude_mmodules.add_all(m.intrude_mmodules)
 176                         self.public_mmodules.add_all(m.public_mmodules)
 177                         self.private_mmodules.add_all(m.private_mmodules)
 178                 else if v == public_visibility then
 179                         self.public_mmodules.add(m)
 180                         self.public_mmodules.add_all(m.intrude_mmodules)
 181                         self.public_mmodules.add_all(m.public_mmodules)
 182                 else if v == private_visibility then
 183                         self.private_mmodules.add(m)
 184                         self.private_mmodules.add_all(m.intrude_mmodules)
 185                         self.private_mmodules.add_all(m.public_mmodules)
 186                 else
 187                         print "{self} visibility for {m} = {v}"
 188                         abort # invalid visibility
 189                 end
 190         end
 191
 192         # Return true if a class or a property introduced in `intro_mmodule` with a visibility of `visibility` is visible in self.
 193         fun is_visible(intro_mmodule: MModule, visibility: MVisibility): Bool
 194         do
 195                 var v = visibility_for(intro_mmodule)
 196                 if v == intrude_visibility then
 197                         return visibility >= private_visibility
 198                 else if v == public_visibility then
 199                         return visibility > private_visibility
 200                 else if v == private_visibility then
 201                         return visibility > private_visibility
 202                 else if v == none_visibility then
 203                         return false
 204                 else
 205                         abort
 206                 end
 207         end
 208
 209         # Is `self` created for internal purpose?
 210         # Fictive modules are instantiated internally but they should not be
 211         # exposed to the final user.
 212         var is_fictive: Bool = false is writable
 213
 214         redef fun parent_concern do return mgroup
 215 end