src/common_ffi/common_ffi.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # FFI concers common between the compilers and the interpreter.
  18 # Offers services to compile modules using foreign code. Mainly allows
  19 # to wrap foreign code in Nit methods.
  20 module common_ffi
  21
  22 import parser
  23 import modelbuilder
  24
  25 import nitni
  26
  27 intrude import ffi_base
  28 import extern_classes
  29 import header_dependency
  30 import pkgconfig
  31 import c_compiler_options
  32 import c
  33 import cpp
  34 import java
  35 import extra_java_files
  36
  37 redef class MModule
  38         # Does this module uses the FFI?
  39         var uses_ffi: Bool = false
  40
  41         # C compilation unit for the FFI files
  42         private var ffi_ccu: nullable CCompilationUnit = null
  43
  44         # Foreign language used in this AModule
  45         private var present_languages = new HashSet[FFILanguage]
  46
  47         # Complete the compilation of the FFI code
  48         fun finalize_ffi_wrapper(compdir: String, mainmodule: MModule)
  49         do
  50                 for language in ffi_callbacks.keys do
  51                         for callback in ffi_callbacks[language] do
  52                                 language.compile_callback(callback, self, mainmodule, ffi_ccu.as(not null))
  53                         end
  54
  55                         language.compile_to_files(self, compdir)
  56                 end
  57
  58                 # include dependancies FFI
  59                 for mod in header_dependencies do
  60                         if mod.uses_ffi then ffi_ccu.header_custom.add("#include \"{mod.name}._ffi.h\"\n")
  61                 end
  62
  63                 ffi_ccu.write_as_impl(self, compdir)
  64                 for filename in ffi_ccu.files do ffi_files.add(new ExternCFile(filename, c_compiler_options))
  65         end
  66
  67         # Avoid the compile a ffi propdef more than once
  68         # See `AMethPropdef::compile_ffi_method`
  69         # FIXME find a better way
  70         private var compiled_ffi_methods = new HashSet[AMethPropdef]
  71 end
  72
  73 redef class AModule
  74
  75         # Ensures all of the general foreign code of the module has been analyzed.
  76         # Manages header blocks, extern class types and foreign dependancies between modules
  77         fun ensure_compile_ffi_wrapper
  78         do
  79                 var mmodule = mmodule
  80                 if mmodule == null or mmodule.ffi_ccu != null then return
  81
  82                 # ready extern code compiler
  83                 var ffi_ccu = new CCompilationUnit
  84                 mmodule.ffi_ccu = ffi_ccu
  85
  86                 # generate code
  87                 for block in n_extern_code_blocks do
  88                         var language = block.language
  89                         assert language != null
  90                         mmodule.present_languages.add(language)
  91                         language.compile_module_block(block, ffi_ccu, mmodule)
  92                 end
  93
  94                 ffi_ccu.header_c_base.add( "#include \"{mmodule.name}._nitni.h\"\n" )
  95
  96                 ffi_ccu.body_decl.add("#ifdef ANDROID\n")
  97                 ffi_ccu.body_decl.add(" #include <android/log.h>\n")
  98                 ffi_ccu.body_decl.add(" #define PRINT_ERROR(...) (void)__android_log_print(ANDROID_LOG_WARN, \"Nit\", __VA_ARGS__)\n")
  99                 ffi_ccu.body_decl.add("#else\n")
 100                 ffi_ccu.body_decl.add(" #define PRINT_ERROR(...) fprintf(stderr, __VA_ARGS__)\n")
 101                 ffi_ccu.body_decl.add("#endif\n")
 102
 103                 for nclassdef in n_classdefs do
 104                         # Does it declares an extern type?
 105                         if nclassdef isa AStdClassdef and nclassdef.n_extern_code_block != null then
 106                                 mmodule.uses_ffi = true
 107                                 var language = nclassdef.n_extern_code_block.language
 108                                 assert language != null
 109                                 mmodule.present_languages.add(language)
 110                                 nclassdef.n_extern_code_block.language.compile_extern_class(
 111                                         nclassdef.n_extern_code_block.as(not null), nclassdef, ffi_ccu, mmodule)
 112                         end
 113                 end
 114         end
 115 end
 116
 117 redef class AMethPropdef
 118         # Compile the necessary wrapper around this extern method or constructor
 119         fun compile_ffi_method(mmodule: MModule)
 120         do
 121                 assert n_extern_code_block != null
 122
 123                 if mmodule.compiled_ffi_methods.has(self) then return
 124                 mmodule.compiled_ffi_methods.add self
 125
 126                 var language = n_extern_code_block.language
 127                 assert language != null
 128                 mmodule.present_languages.add(language)
 129                 n_extern_code_block.language.compile_extern_method(
 130                         n_extern_code_block.as(not null), self, mmodule.ffi_ccu.as(not null), mmodule)
 131         end
 132 end
 133
 134 redef class VerifyNitniCallbacksPhase
 135         redef fun process_npropdef(npropdef)
 136         do
 137                 super
 138
 139                 if not npropdef isa AExternPropdef then return
 140
 141                 var code_block = npropdef.n_extern_code_block
 142                 if code_block == null then return
 143
 144                 var lang = code_block.language
 145                 assert lang != null
 146
 147                 # Associate callbacks used by an extern method to its foreign language
 148                 for callback in npropdef.foreign_callbacks.all do
 149                         var map = npropdef.mpropdef.mclassdef.mmodule.ffi_callbacks
 150                         if not map.keys.has(lang) then map[lang] = new HashSet[NitniCallback]
 151                         map[lang].add(callback)
 152                 end
 153         end
 154 end