src/model/mpackage.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Modelisation of a Nit package
  16 module mpackage
  17
  18 import model_base
  19 private import more_collections
  20 import poset
  21 import mdoc
  22
  23 # A Nit package, that encompass a product
  24 class MPackage
  25         super MConcern
  26
  27         # The name of the package
  28         redef var name
  29
  30         redef fun full_name do return name
  31
  32         redef var c_name = name.to_cmangle is lazy
  33
  34         # The model of the package
  35         redef var model
  36
  37         redef var location
  38
  39         # The root of the group tree
  40         var root: nullable MGroup = null is writable
  41
  42         # The group tree, as a POSet
  43         var mgroups = new POSet[MGroup]
  44
  45         redef fun to_s do return name
  46
  47         init
  48         do
  49                 model.mpackages.add(self)
  50                 model.mpackage_by_name.add_one(name, self)
  51         end
  52
  53         # MPackage are always roots of the concerns hierarchy
  54         redef fun parent_concern do return null
  55
  56         redef fun mdoc_or_fallback
  57         do
  58                 var mdoc = self.mdoc
  59                 if mdoc != null then return mdoc
  60                 var root = self.root
  61                 if root != null then return root.mdoc_or_fallback
  62                 return null
  63         end
  64
  65         # Does `self` have a source file?
  66         fun has_source: Bool do return location.file != null
  67
  68         # The path to `self`
  69         fun package_path: nullable String do
  70                 if not has_source then return null
  71                 return location.file.as(not null).filename
  72         end
  73
  74         # Is `self` in its own directory?
  75         fun is_expanded: Bool do
  76                 var path = package_path
  77                 if path == null then return false
  78                 return not path.has_suffix(".nit")
  79         end
  80
  81         # The path to `self` ini file
  82         fun ini_path: nullable String do
  83                 var path = package_path
  84                 if path == null then return null
  85                 if is_expanded then return path / "package.ini"
  86                 return path.dirname / "{name}.ini"
  87         end
  88
  89         # Does `self` have a ini file?
  90         fun has_ini: Bool do
  91                 var ini_path = self.ini_path
  92                 if ini_path == null then return false
  93                 return ini_path.file_exists
  94         end
  95 end
  96
  97 # A group of modules in a package
  98 class MGroup
  99         super MConcern
 100
 101         # The name of the group
 102         # empty name for a default group in a single-module package
 103         redef var name
 104
 105         redef var location
 106
 107         # The enclosing package
 108         var mpackage: MPackage
 109
 110         # The parent group if any
 111         # see `in_nesting` for more
 112         var parent: nullable MGroup
 113
 114         # Fully qualified name.
 115         # It includes each parent group separated by `>`.
 116         # The full_name is terminated by `>` to avoid collision with other entities.
 117         #
 118         # E.g. `core>` and `core>collection>`
 119         redef fun full_name
 120         do
 121                 var p = parent
 122                 if p == null then return "{name}>"
 123                 return "{p.full_name}{name}>"
 124         end
 125
 126         # The group is the group tree on the package (`mpackage.mgroups`)
 127         # nested groups (children) are smaller
 128         # nesting group (see `parent`) is bigger
 129         var in_nesting: POSetElement[MGroup] is noinit
 130
 131         # Is `self` the root of its package?
 132         fun is_root: Bool do return mpackage.root == self
 133
 134         # The filepath (usually a directory) of the group, if any
 135         #
 136         # safe alias to `location.file.filename`
 137         fun filepath: nullable String do
 138                 var res
 139                 res = self.location.file
 140                 if res == null then return null
 141                 return res.filename
 142         end
 143
 144         init
 145         do
 146                 var tree = mpackage.mgroups
 147                 self.in_nesting = tree.add_node(self)
 148                 var parent = self.parent
 149                 if parent != null then
 150                         tree.add_edge(self, parent)
 151                 end
 152         end
 153
 154         redef fun model do return mpackage.model
 155
 156         redef fun parent_concern do
 157                 if not is_root then return parent
 158                 return mpackage
 159         end
 160
 161         redef fun to_s do return name
 162 end
 163
 164 redef class Model
 165         # packages of the model
 166         var mpackages = new Array[MPackage]
 167
 168         # Collections of package grouped by their names
 169         private var mpackage_by_name = new MultiHashMap[String, MPackage]
 170
 171         # Return all package named `name`
 172         # If such a package is not yet loaded, null is returned (instead of an empty array)
 173         fun get_mpackages_by_name(name: String): nullable Array[MPackage]
 174         do
 175                 if mpackage_by_name.has_key(name) then
 176                         return mpackage_by_name[name]
 177                 else
 178                         return null
 179                 end
 180         end
 181 end