src/nitg.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # A global Nit compiler
  18 module nitg
  19
  20 import modelbuilder
  21 import frontend
  22 import transform
  23 import rapid_type_analysis
  24 import global_compiler
  25 import separate_erasure_compiler
  26 import separate_compiler
  27 import android_platform
  28 import compiler_ffi
  29
  30 # Create a tool context to handle options and paths
  31 var toolcontext = new ToolContext
  32
  33 # Create a new option for --global
  34 var opt_global = new OptionBool("Use global compilation", "--global")
  35 toolcontext.option_context.add_option(opt_global)
  36
  37 var opt_mixins = new OptionArray("Additionals module to min-in", "-m")
  38 toolcontext.option_context.add_option(opt_mixins)
  39
  40 toolcontext.tooldescription = "Usage: nitg [OPTION]... file.nit\nCompiles Nit programs."
  41
  42 # We do not add other options, so process them now!
  43 toolcontext.process_options(args)
  44
  45 # We need a model to collect stufs
  46 var model = new Model
  47 # An a model builder to parse files
  48 var modelbuilder = new ModelBuilder(model, toolcontext)
  49
  50 var arguments = toolcontext.option_context.rest
  51 if arguments.length > 1 then
  52         print "Too much arguments: {arguments.join(" ")}"
  53         print toolcontext.tooldescription
  54         exit 1
  55 end
  56 var progname = arguments.first
  57
  58 # Here we load an process all modules passed on the command line
  59 var mmodules = modelbuilder.parse([progname])
  60 mmodules.add_all modelbuilder.parse(opt_mixins.value)
  61
  62 if mmodules.is_empty then return
  63 modelbuilder.run_phases
  64
  65 var mainmodule
  66 if mmodules.length == 1 then
  67         mainmodule = mmodules.first
  68 else
  69         mainmodule = new MModule(model, null, mmodules.first.name, mmodules.first.location)
  70         mainmodule.set_imported_mmodules(mmodules)
  71 end
  72
  73 var platform = mainmodule.target_platform
  74 if platform != null and not platform.supports_libunwind then
  75         if toolcontext.opt_stacktrace.value == null then toolcontext.opt_stacktrace.value = "none" # default is none
  76 end
  77
  78 if toolcontext.opt_erasure.value then
  79         modelbuilder.run_separate_erasure_compiler(mainmodule, null)
  80 else if opt_global.value then
  81         var analysis = modelbuilder.do_rapid_type_analysis(mainmodule)
  82         modelbuilder.run_global_compiler(mainmodule, analysis)
  83 else
  84         var analysis = modelbuilder.do_rapid_type_analysis(mainmodule)
  85         modelbuilder.run_separate_compiler(mainmodule, analysis)
  86 end