lib/trees/bintree.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Binary Tree data-structure
  16 # A binary tree is a tree data structure in which each node has at most two children
  17 # (referred to as the left child and the right child).
  18 # In a binary tree, the degree of each node can be at most two.
  19 # Binary trees are used to implement binary search trees and binary heaps,
  20 # and are used for efficient searching and sorting.
  21 module bintree
  22
  23 import abstract_tree
  24
  25 # Binary Tree Map
  26 #
  27 # Properties:
  28 #  * unique root
  29 #  * node.left.key < node.key
  30 #  * node.right.key > node.key
  31 #  * no duplicates allowed
  32 #
  33 # Operations:
  34 #  * search average O(lg n) worst O(n)
  35 #  * insert average O(lg n) worst O(n)
  36 #  * delete average O(lg n) worst O(n)
  37 #
  38 # Usage:
  39 #     var tree = new BinTreeMap[Int, String]
  40 #     tree[1] = "n1"
  41 #     assert tree.min == "n1"
  42 class BinTreeMap[K: Comparable, E]
  43         super TreeMap[K, E]
  44
  45         redef type N: BinTreeNode[K, E]
  46
  47         private var len = 0
  48         private var first_node: nullable BinTreeNode[K, E] = null
  49         private var last_node: nullable BinTreeNode[K, E] = null
  50
  51         # O(n) in worst case, average is O(h) with h: tree height
  52         #
  53         #     var tree = new BinTreeMap[Int, String]
  54         #     assert tree.is_empty
  55         #     tree[1] = "n1"
  56         #     assert not tree.is_empty
  57         redef fun is_empty do return root == null
  58
  59         # O(n) in worst case, average is O(h) with h: tree height
  60         #
  61         #     var tree = new BinTreeMap[Int, String]
  62         #     assert not tree.has_key(1)
  63         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
  64         #     assert not tree.has_key(0)
  65         #     assert tree.has_key(2)
  66         #     assert not tree.has_key(6)
  67         redef fun has_key(key: K): Bool do
  68                 if is_empty then return false
  69                 var res = search_down(root.as(not null), key)
  70                 if res != null then
  71                         cache_node = res
  72                         return true
  73                 end
  74                 return false
  75         end
  76
  77         private var cache_node: nullable N = null
  78
  79         # Get the node value associated to `key`
  80         # O(n) in worst case, average is O(h) with h: tree height
  81         #
  82         #     var tree = new BinTreeMap[Int, String]
  83         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
  84         #     assert tree.has_key(1)
  85         #     assert tree[1] == "n1"
  86         #     assert tree.has_key(1)
  87         #     assert tree[2] == "n2"
  88         redef fun [](key: K): E do
  89                 assert not_empty: not is_empty
  90                 if cache_node != null and cache_node.key == key then return cache_node.value
  91                 var res = search_down(root.as(not null), key)
  92                 assert has_key: res != null
  93                 return res.value
  94         end
  95
  96         protected fun search_down(from: N, key: K): nullable N do
  97                 var cmp = key <=> from.key
  98                 if cmp == 0 then return from
  99                 if from.left != null and cmp < 0 then
 100                         return search_down(from.left.as(not null), key)
 101                 else if from.right != null then
 102                         return search_down(from.right.as(not null), key)
 103                 end
 104                 return null
 105         end
 106
 107         # Get the node with the minimum key
 108         # O(n) in worst case, average is O(h) with h: tree height
 109         #
 110         #     var tree = new BinTreeMap[Int, String]
 111         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
 112         #     assert tree.min == "n1"
 113         fun min: E do
 114                 assert not_empty: root != null
 115                 return min_from(root.as(not null)).value
 116         end
 117
 118         protected fun min_from(node: N): N do
 119                 if node.left == null then return node
 120                 return min_from(node.left.as(not null))
 121         end
 122
 123         # Get the node with the maximum key
 124         # O(n) in worst case, average is O(h) with h: tree height
 125         #
 126         #     var tree = new BinTreeMap[Int, String]
 127         #     for i in [4, 2, 1, 5, 3, 6, 7, 8] do tree[i] = "n{i}"
 128         #     assert tree.max == "n8"
 129         fun max: E do
 130                 assert not_empty: root != null
 131                 return max_from(root.as(not null)).value
 132         end
 133
 134         protected fun max_from(node: N): N do
 135                 if node.right == null then return node
 136                 return max_from(node.right.as(not null))
 137         end
 138
 139         # Insert a new node in tree using `key` and `item`
 140         # O(n) in worst case, average is O(h) with h: tree height
 141         #
 142         #     var tree = new BinTreeMap[Int, String]
 143         #     tree[1] = "n1"
 144         #     assert tree.max == "n1"
 145         #     tree[3] = "n3"
 146         #     assert tree.max == "n3"
 147         redef fun []=(key, item) do
 148                 insert_node(new BinTreeNode[K, E](key, item))
 149         end
 150
 151         protected fun insert_node(node: N) do
 152                 len += 1
 153                 if root == null then
 154                         root = node
 155                 else
 156                         shift_down(root.as(not null), node)
 157                 end
 158                 if first_node == null then
 159                         first_node = node
 160                 end
 161                 if last_node != null then
 162                         last_node.next = node
 163                         node.prev = last_node
 164                 end
 165                 last_node = node
 166         end
 167
 168         # Push down the `node` in tree from a specified `from` index
 169         protected fun shift_down(from, node: N) do
 170                 var cmp = node.key <=> from.key
 171                 if cmp < 0 then
 172                         if from.left == null then
 173                                 from.left = node
 174                                 node.parent = from
 175                         else
 176                                 shift_down(from.left.as(not null), node)
 177                         end
 178                 else if cmp > 0 then
 179                         if from.right == null then
 180                                 from.right = node
 181                                 node.parent = from
 182                         else
 183                                 shift_down(from.right.as(not null), node)
 184                         end
 185                 end
 186         end
 187
 188         # Delete node at `key` (also return the deleted node value)
 189         # O(n) in worst case, average is O(h) with h: tree height
 190         #
 191         #     var tree = new BinTreeMap[Int, String]
 192         #     tree[1] = "n1"
 193         #     assert tree.max == "n1"
 194         #     tree[3] = "n3"
 195         #     assert tree.max == "n3"
 196         #     tree.delete(3)
 197         #     assert tree.max == "n1"
 198         fun delete(key: K): nullable E do
 199                 assert is_empty: root != null
 200                 len -= 1
 201                 var node = search_down(root.as(not null), key)
 202                 if node == null then return null
 203                 if node.left == null then
 204                         transplant(node, node.right)
 205                 else if node.right == null then
 206                         transplant(node, node.left)
 207                 else
 208                         var min = min_from(node.right.as(not null))
 209                         if min.parent != node then
 210                                 transplant(min, min.right)
 211                                 min.right = node.right
 212                                 min.right.parent = min
 213                         end
 214                         transplant(node, min)
 215                         min.left = node.left
 216                         min.left.parent = min
 217                 end
 218                 if first_node == node then
 219                         first_node = null
 220                 end
 221                 if last_node == node then
 222                         last_node = node.prev
 223                         last_node.next = null
 224                 else
 225                         node.prev.next = node.next
 226                         node.next.prev = node.prev
 227                 end
 228                 return node.value
 229         end
 230
 231         # Swap a `node` with the `other` in this Tree
 232         # note: Nodes parents are updated, children still untouched
 233         protected fun transplant(node, other: nullable N) do
 234                 if node == null then return
 235                 if node.parent == null then
 236                         root = other
 237                 else if node == node.parent.left then
 238                         node.parent.left = other
 239                 else
 240                         node.parent.right = other
 241                 end
 242                 if other != null then other.parent = node.parent
 243         end
 244
 245         # Perform left rotation on `node`
 246         #
 247         #     N             Y
 248         #    / \     >     / \
 249         #   a   Y         N   c
 250         #      / \   <   / \
 251         #     b   c     a   b
 252         #
 253         protected fun rotate_left(node: N) do
 254                 var y = node.right
 255                 node.right = y.left
 256                 if y.left != null then
 257                         y.left.parent = node
 258                 end
 259                 y.parent = node.parent
 260                 if node.parent == null then
 261                         root = y
 262                 else if node == node.parent.left then
 263                         node.parent.left = y
 264                 else
 265                         node.parent.right = y
 266                 end
 267                 y.left = node
 268                 node.parent = y
 269         end
 270
 271         # Perform right rotation on `node`
 272         #
 273         #     N             Y
 274         #    / \     >     / \
 275         #   a   Y         N   c
 276         #      / \   <   / \
 277         #     b   c     a   b
 278         #
 279         protected fun rotate_right(node: N) do
 280                 var y = node.left
 281                 node.left = y.right
 282                 if y.right != null then
 283                         y.right.parent = node
 284                 end
 285                 y.parent = node.parent
 286                 if node.parent == null then
 287                         root = y
 288                 else if node == node.parent.right then
 289                         node.parent.right = y
 290                 else
 291                         node.parent.left = y
 292                 end
 293                 y.right = node
 294                 node.parent = y
 295         end
 296
 297         # Sort the tree into an array
 298         # O(n)
 299         #
 300         #     var tree = new BinTreeMap[Int, String]
 301         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
 302         #     assert tree.sort == ["n1", "n2", "n3", "n4", "n5"]
 303         fun sort: Array[E] do
 304                 var sorted = new Array[E]
 305                 if root == null then return sorted
 306                 sort_down(root.as(not null), sorted)
 307                 return sorted
 308         end
 309
 310         protected fun sort_down(node: N, sorted: Array[E]) do
 311                 if node.left != null then sort_down(node.left.as(not null), sorted)
 312                 sorted.add(node.value)
 313                 if node.right != null then sort_down(node.right.as(not null), sorted)
 314         end
 315
 316         redef fun to_s do
 317                 var root = self.root
 318                 if root == null then return "[]"
 319                 return "[{print_tree(root)}]"
 320         end
 321
 322         protected fun print_tree(node: N): String do
 323                 var s = new FlatBuffer
 324                 s.append(node.to_s)
 325                 if node.left != null then s.append(print_tree(node.left.as(not null)))
 326                 if node.right != null then s.append(print_tree(node.right.as(not null)))
 327                 return s.to_s
 328         end
 329
 330         redef fun show_dot do
 331                 assert not_empty: root != null
 332                 var f = new OProcess("dot", "-Txlib")
 333                 f.write "digraph \{\n"
 334                 dot_down(root.as(not null), f)
 335                 f.write "\}\n"
 336                 f.close
 337         end
 338
 339         protected fun dot_down(node: N, f: OProcess) do
 340                 if node.left != null then dot_down(node.left.as(not null), f)
 341                 f.write node.to_dot
 342                 if node.right != null then dot_down(node.right.as(not null), f)
 343         end
 344
 345         # O(n)
 346         #
 347         #     var tree = new BinTreeMap[Int, String]
 348         #     assert tree.length == 0
 349         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
 350         #     assert tree.length == 5
 351         redef fun length do return len
 352
 353         # Nodes are iterated in the same order in which they were added to the tree.
 354         # O(n)
 355         #
 356         #     var tree = new BinTreeMap[Int, String]
 357         #     for i in [4, 2, 1, 5, 3] do tree[i] = "n{i}"
 358         #     var keys = new Array[Int]
 359         #     for k, v in tree do
 360         #         keys.add k
 361         #     end
 362         #     assert keys == [4, 2, 1, 5, 3]
 363         redef fun iterator do return new BinTreeMapIterator[K, E](self)
 364 end
 365
 366 # TreeNode used by BinTree
 367 class BinTreeNode[K: Comparable, E]
 368         super TreeNode[K, E]
 369
 370         private var prev: nullable BinTreeNode[K, E]
 371         private var next: nullable BinTreeNode[K, E]
 372
 373         redef type N: BinTreeNode[K, E]
 374
 375         init(key: K, item: E) do
 376                 super(key, item)
 377         end
 378
 379         private var left_node: nullable N = null
 380
 381         # `left` tree node child (null if node has no left child)
 382         fun left: nullable N do return left_node
 383
 384         # set `left` child for this node (or null if left no child)
 385         # ENSURE: node.key < key (only if node != null)
 386         fun left=(node: nullable N) do
 387                 #assert node != null implies node.key < key
 388                 left_node = node
 389         end
 390
 391         private var right_node: nullable N = null
 392
 393         # `right` tree node child (null if node has no right child)
 394         fun right: nullable N do return right_node
 395
 396         # set `right` child for this node (or null if right no child)
 397         # ENSURE: node.key < key (only if node != null)
 398         fun right=(node: nullable N) do
 399                 #assert node != null implies node.key > key
 400                 right_node = node
 401         end
 402
 403         # `parent` of the `parent` of this node (null if root)
 404         fun grandparent: nullable N do
 405                 if parent == null then
 406                         return null
 407                 else
 408                         return parent.parent
 409                 end
 410         end
 411
 412         # Other child of the `grandparent`
 413         # `left` or `right` depends on the position of the current node against its parent
 414         fun uncle: nullable N do
 415                 var g = grandparent
 416                 if g == null then
 417                         return null
 418                 else
 419                         if parent == g.left then
 420                                 return g.right
 421                         else
 422                                 return g.left
 423                         end
 424                 end
 425         end
 426
 427         # Other child of the parent
 428         # `left` or `right` depends on the position of the current node against its parent
 429         fun sibling: nullable N do
 430                 if parent == null then
 431                         return null
 432                 else if self == parent.left then
 433                         return parent.right
 434                 else if self == parent.right then
 435                         return parent.left
 436                 else
 437                         return null
 438                 end
 439         end
 440
 441         redef fun to_s do return "\{{key}: {value or else ""}\}"
 442 end
 443
 444 private class BinTreeMapIterator[K: Comparable, E]
 445         super MapIterator[K, E]
 446
 447         var current: nullable BinTreeNode[K, E]
 448
 449         init(tree: BinTreeMap[K, E]) do
 450                 current = tree.first_node
 451         end
 452
 453         redef fun is_ok do return not current == null
 454         redef fun next do current = current.next
 455         redef fun item do return current.value
 456         redef fun key do do return current.key
 457 end