src/nitni/nitni_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Native interface related services (used underneath the FFI)
  18 #
  19 # All nitni properties may not be visible to the user but they are
  20 # shared between engines
  21 module nitni_base
  22
  23 import parser
  24 import modelbuilder # builder only for externcalls
  25 private import compiler::abstract_compiler
  26
  27 redef class MMethod
  28         # Short name of this method in C (without the class name)
  29         fun short_cname: String do
  30                 var nit_name = name
  31
  32                 if nit_name == "+" then return "_plus"
  33                 if nit_name == "-" then return "_minus"
  34                 if nit_name == "unary -" then return "_unary_minus"
  35                 if nit_name == "*" then return "_star"
  36                 if nit_name == "/" then return "_slash"
  37                 if nit_name == "%" then return "_percent"
  38                 if nit_name == "[]" then return "_index"
  39                 if nit_name == "[]=" then return "_index_assign"
  40                 if nit_name == "==" then return "_equal"
  41                 if nit_name == "<" then return "_less"
  42                 if nit_name == ">" then return "_geater"
  43                 if nit_name == "<=" then return "_less_or_equal"
  44                 if nit_name == ">=" then return "_greater_or_equal"
  45                 if nit_name == "!=" then return "_not_equal"
  46                 if nit_name == "<<" then return "_left"
  47                 if nit_name == ">>" then return "_right"
  48                 if nit_name == "<=>" then return "_starship"
  49
  50                 if nit_name.chars.last == '=' then return "{nit_name.substring(0, nit_name.length-1)}__assign"
  51                 return nit_name
  52         end
  53 end
  54
  55 redef class MModule
  56         # Mangled name of this module in C
  57         fun cname: String do return c_name # FIXME this is a hack to keep the internal FFI
  58         # API independent of the compilers while still using the `MModule::c_name` service.
  59 end
  60
  61 redef class MMethodDef
  62         # Name of the function to callback this method from C,
  63         # also used in other functions names used for this method.
  64         fun cname: String do return "{mclassdef.mclass.name}_{mproperty.short_cname}"
  65 end
  66
  67 redef class MType
  68         # Representation of this type in pure C on the FFI extern side
  69         #   Object -> Object
  70         #   Pointer -> void*
  71         fun cname: String is abstract
  72
  73         # Representation of this type in C for the internal of the system
  74         # Hides extern types.
  75         fun cname_blind: String is abstract
  76
  77         # Representation of this type in mangled C
  78         #   Object -> Object
  79         #   Pointer -> Pointer
  80         fun mangled_cname: String is abstract
  81
  82         # Does this types has a primitive reprensentation
  83         #   type Object is_primitive? false
  84         #   type Pointer is_primitive? true
  85         fun is_cprimitive: Bool is abstract
  86 end
  87
  88 redef class MClassType
  89         redef fun cname
  90         do
  91                 var name = mclass.name
  92                 if name == "Bool" then return "int"
  93                 if name == "Char" then return "char"
  94                 if name == "Float" then return "double"
  95                 if name == "Int" then return "long"
  96                 if name == "NativeString" then return "char*"
  97                 if mclass.kind == extern_kind then
  98                         var ctype = mclass.ctype
  99                         assert ctype != null
 100                         return ctype
 101                 end
 102                 return mangled_cname
 103         end
 104
 105         redef fun cname_blind do
 106                 var name = mclass.name
 107                 if name == "Bool" then return "int"
 108                 if name == "Char" then return "char"
 109                 if name == "Float" then return "double"
 110                 if name == "Int" then return "long"
 111                 if name == "NativeString" then return "char*"
 112                 if mclass.kind == extern_kind then return "void*"
 113                 return "struct nitni_instance *"
 114         end
 115
 116         redef fun mangled_cname do return mclass.name
 117
 118         redef fun is_cprimitive do return mclass.kind == extern_kind or
 119                         (once ["Bool", "Char", "Float", "Int", "NativeString"]).has(mclass.name)
 120 end
 121
 122 redef class MNullableType
 123         redef fun cname do return mangled_cname
 124         redef fun cname_blind do return "struct nitni_instance *"
 125         redef fun mangled_cname do return "nullable_{mtype.mangled_cname}"
 126         redef fun is_cprimitive do return false
 127 end
 128
 129 redef class MVirtualType
 130         redef fun mangled_cname: String do return to_s
 131 end
 132
 133 redef class MGenericType
 134         redef fun cname do return mangled_cname
 135         redef fun mangled_cname
 136         do
 137                 var base = super
 138
 139                 var params = new Array[String]
 140                 for arg in arguments do params.add(arg.mangled_cname)
 141
 142                 return "{base}_of_{params.join("_")}"
 143         end
 144 end
 145
 146 redef class MClass
 147         fun ctype: nullable String
 148         do
 149                 assert kind == extern_kind
 150                 return "void*"
 151         end
 152 end