lib/sdl.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2011-2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # SDL display support (used in Linux for windows and inputes only)
  18 module sdl is
  19         c_compiler_option(exec("sdl-config", "--cflags"))
  20         c_linker_option(exec("sdl-config", "--libs"), "-lSDL_image -lSDL_ttf")
  21 end
  22
  23 import mnit_display
  24
  25 in "C header" `{
  26         #include <unistd.h>
  27         #include <SDL/SDL.h>
  28         #include <SDL/SDL_syswm.h>
  29         #include <SDL/SDL_image.h>
  30         #include <SDL/SDL_ttf.h>
  31 `}
  32
  33 # Represent a screen surface
  34 extern class SDLDisplay `{SDL_Surface *`}
  35         super Display
  36
  37         redef type I: SDLImage
  38
  39         # Initialize a surface with width and height
  40         new (w, h: Int) import enable_mouse_motion_events `{
  41                 SDL_Init(SDL_INIT_VIDEO);
  42
  43                 if(TTF_Init()==-1) {
  44                         printf("TTF_Init: %s\n", TTF_GetError());
  45                         exit(2);
  46                 }
  47
  48                 SDL_Surface *self = SDL_SetVideoMode(w, h, 24, SDL_HWSURFACE);
  49
  50                 if (!SDLDisplay_enable_mouse_motion_events(self)) {
  51                         /* ignores mousemotion for performance reasons */
  52                         SDL_EventState(SDL_MOUSEMOTION, SDL_IGNORE);
  53                 }
  54
  55                 return self;
  56         `}
  57
  58         # Indicates wether we want the SDL mouse motion event (or only clicks).
  59         # Disabled by defaut for performance reason. To activate, redef this method
  60         # andd return true
  61         fun enable_mouse_motion_events: Bool do return false
  62
  63         # Destroy the surface
  64         fun destroy `{
  65                 if (SDL_WasInit(SDL_INIT_VIDEO))
  66                         SDL_Quit();
  67
  68                 if (TTF_WasInit())
  69                         TTF_Quit();
  70         `}
  71
  72         redef fun finish `{ SDL_Flip(recv); `}
  73
  74         # Clear the entire window with given RGB color (integer values)
  75         fun clear_int(r, g, b: Int) `{
  76                 SDL_FillRect(recv, NULL, SDL_MapRGB(recv->format,r,g,b));
  77         `}
  78
  79         redef fun width: Int `{ return recv->w; `}
  80         redef fun height: Int `{ return recv->h; `}
  81
  82         # Fill a rectangle with given color
  83         fun fill_rect(rect: SDLRectangle, r, g, b: Int) `{
  84                 SDL_FillRect(recv, rect,  SDL_MapRGB(recv->format,r,g,b));
  85         `}
  86
  87         redef fun clear(r, g, b: Float) `{
  88                 Uint8 ri, gi, bi;
  89                 ri = (Uint8)r*255;
  90                 gi = (Uint8)g*255;
  91                 bi = (Uint8)b*255;
  92                 SDL_FillRect(recv, NULL, SDL_MapRGB(recv->format,ri,gi,bi));
  93         `}
  94
  95         # SDL events since the last call to this method
  96         fun events: Sequence[SDLInputEvent]
  97         do
  98                 var events = new Array[SDLInputEvent]
  99                 loop
 100                         var new_event = poll_event
 101                         if new_event == null then break
 102                         events.add new_event
 103                 end
 104                 return events
 105         end
 106
 107         private fun poll_event: nullable SDLInputEvent import SDLKeyEvent, SDLMouseButtonEvent, SDLMouseMotionEvent, SDLQuitEvent, NativeString.to_s, SDLMouseButtonEvent.as(nullable SDLInputEvent), SDLMouseMotionEvent.as(nullable SDLInputEvent), SDLKeyEvent.as(nullable SDLInputEvent), SDLQuitEvent.as(nullable SDLInputEvent) `{
 108                 SDL_Event event;
 109
 110                 SDL_PumpEvents();
 111
 112                 if (SDL_PollEvent(&event))
 113                 {
 114                         switch (event.type) {
 115                                 case SDL_KEYDOWN:
 116                                 case SDL_KEYUP:
 117         #ifdef DEBUG
 118                                         printf("The \"%s\" key was pressed!\n",
 119                                                    SDL_GetKeyName(event.key.keysym.sym));
 120         #endif
 121
 122                                         return SDLKeyEvent_as_nullable_SDLInputEvent(
 123                                                         new_SDLKeyEvent(NativeString_to_s(
 124                                                                 SDL_GetKeyName(event.key.keysym.sym)),
 125                                                                 event.type==SDL_KEYDOWN));
 126
 127                                 case SDL_MOUSEMOTION:
 128         #ifdef DEBUG
 129                                         printf("Mouse moved by %d,%d to (%d,%d)\n",
 130                                                    event.motion.xrel, event.motion.yrel,
 131                                                    event.motion.x, event.motion.y);
 132         #endif
 133
 134                                         return SDLMouseMotionEvent_as_nullable_SDLInputEvent(
 135                                                         new_SDLMouseMotionEvent(event.motion.x, event.motion.y,
 136                                                                 event.motion.xrel, event.motion.yrel, SDL_GetMouseState(NULL, NULL)&SDL_BUTTON(1)));
 137
 138                                 case SDL_MOUSEBUTTONDOWN:
 139                                 case SDL_MOUSEBUTTONUP:
 140         #ifdef DEBUG
 141                                         printf("Mouse button \"%d\" pressed at (%d,%d)\n",
 142                                                    event.button.button, event.button.x, event.button.y);
 143         #endif
 144                                         return SDLMouseButtonEvent_as_nullable_SDLInputEvent(
 145                                                         new_SDLMouseButtonEvent(event.button.x, event.button.y,
 146                                                                 event.button.button, event.type == SDL_MOUSEBUTTONDOWN));
 147
 148                                 case SDL_QUIT:
 149         #ifdef DEBUG
 150                                         printf("Quit event\n");
 151         #endif
 152                                         return SDLQuitEvent_as_nullable_SDLInputEvent(new_SDLQuitEvent());
 153                         }
 154                 }
 155
 156                 return null_SDLInputEvent();
 157         `}
 158
 159         # Set the position of the cursor to x,y
 160         fun warp_mouse(x,y: Int) `{ SDL_WarpMouse(x, y); `}
 161
 162         # Show or hide the cursor
 163         fun show_cursor(show: Bool) `{ SDL_ShowCursor(show); `}
 164 end
 165
 166 # Basic Drawing figures
 167 extern class SDLDrawable `{SDL_Surface*`}
 168         super Drawable
 169
 170         redef type I: SDLImage
 171
 172         redef fun blit(img, x, y) do native_blit(img, x.to_i, y.to_i)
 173         private fun native_blit(img: I, x, y: Int) `{
 174                 SDL_Rect dst;
 175                 dst.x = x;
 176                 dst.y = y;
 177                 dst.w = 0;
 178                 dst.h = 0;
 179
 180                 SDL_BlitSurface(img, NULL, recv, &dst);
 181         `}
 182
 183         redef fun blit_centered(img, x, y)
 184         do
 185                 x = x - img.width / 2
 186                 y = y - img.height / 2
 187                 blit(img, x, y)
 188         end
 189 end
 190
 191 # A drawable Image
 192 extern class SDLImage
 193         super DrawableImage
 194         super SDLDrawable
 195
 196         # Import image from a file
 197         new from_file(path: String) import String.to_cstring `{
 198                 SDL_Surface *image = IMG_Load(String_to_cstring(path));
 199                 return image;
 200         `}
 201
 202         # Copy of an existing SDLImage
 203         new copy_of(image: SDLImage) `{
 204                 SDL_Surface *new_image = SDL_CreateRGBSurface(
 205                         image->flags, image->w, image->h, 24,
 206                         0, 0, 0, 0);
 207
 208                 SDL_Rect dst;
 209                 dst.x = 0;
 210                 dst.y = 0;
 211                 dst.w = image->w;
 212                 dst.h = image->h;
 213                 SDL_BlitSurface(image, NULL, new_image, &dst);
 214
 215                 return new_image;
 216         `}
 217
 218         # Save the image into the specified file
 219         fun save_to_file(path: String) import String.to_cstring `{ `}
 220
 221         # Destroy the image and free the memory
 222         redef fun destroy `{ SDL_FreeSurface(recv); `}
 223
 224         redef fun width: Int `{ return recv->w; `}
 225         redef fun height: Int `{ return recv->h; `}
 226
 227         fun is_ok: Bool do return not address_is_null
 228 end
 229
 230 # A simple rectangle
 231 extern class SDLRectangle `{SDL_Rect*`}
 232         # Constructor with x,y positions width and height of the rectangle
 233         new (x: Int, y: Int, w: Int, h: Int) `{
 234                 SDL_Rect *rect = malloc(sizeof(SDL_Rect));
 235                 rect->x = (Sint16)x;
 236                 rect->y = (Sint16)y;
 237                 rect->w = (Uint16)w;
 238                 rect->h = (Uint16)h;
 239                 return rect;
 240         `}
 241
 242         fun x=(v: Int) `{ recv->x = (Sint16)v; `}
 243         fun x: Int `{ return recv->x; `}
 244
 245         fun y=(v: Int) `{ recv->y = (Sint16)v; `}
 246         fun y: Int `{ return recv->y; `}
 247
 248         fun w=(v: Int) `{ recv->w = (Uint16)v; `}
 249         fun w: Int `{ return recv->w; `}
 250
 251         fun h=(v: Int) `{ recv->h = (Uint16)v; `}
 252         fun h: Int `{ return recv->h; `}
 253 end
 254
 255 interface SDLInputEvent
 256         super InputEvent
 257 end
 258
 259 # MouseEvent class containing the cursor position
 260 class SDLMouseEvent
 261         super PointerEvent
 262         super SDLInputEvent
 263
 264         redef var x: Float
 265         redef var y: Float
 266
 267         private init (x, y: Float)
 268         do
 269                 self.x = x
 270                 self.y = y
 271         end
 272 end
 273
 274 # MouseButtonEvent used to get information when a button is pressed/depressed
 275 class SDLMouseButtonEvent
 276         super SDLMouseEvent
 277
 278         var button: Int
 279
 280         redef var pressed: Bool
 281         redef fun depressed: Bool do return not pressed
 282
 283         # Is this event raised by the left button?
 284         fun is_left_button: Bool do return button == 1
 285
 286         # Is this event raised by the right button?
 287         fun is_right_button: Bool do return button == 2
 288
 289         # Is this event raised by the middle button?
 290         fun is_middle_button: Bool do return button == 3
 291
 292         # Is this event raised by the wheel going down?
 293         fun is_down_wheel: Bool do return button == 4
 294
 295         # Is this event raised by the wheel going up?
 296         fun is_up_wheel: Bool do return button == 5
 297
 298         # Is this event raised by the wheel?
 299         fun is_wheel: Bool do return is_down_wheel or is_up_wheel
 300
 301         init (x, y: Float, button: Int, pressed: Bool)
 302         do
 303                 super(x, y)
 304
 305                 self.button = button
 306                 self.pressed = pressed
 307         end
 308
 309         redef fun to_s
 310         do
 311                 if pressed then
 312                         return "MouseButtonEvent button {button} down at {x}, {y}"
 313                 else
 314                         return "MouseButtonEvent button {button} up at {x}, {y}"
 315                 end
 316         end
 317 end
 318
 319 # MouseMotionEvent to get the cursor position when the mouse is moved
 320 class SDLMouseMotionEvent
 321         super SDLMouseEvent
 322
 323         var rel_x: Float
 324         var rel_y: Float
 325
 326         redef var pressed: Bool
 327         redef fun depressed: Bool do return not pressed
 328
 329         init (x, y, rel_x, rel_y: Float, pressed: Bool)
 330         do
 331                 super(x, y)
 332
 333                 self.rel_x = rel_x
 334                 self.rel_y = rel_y
 335                 self.pressed = pressed
 336         end
 337
 338         redef fun to_s do return "MouseMotionEvent at {x}, {y}"
 339 end
 340
 341 # SDLKeyEvent for when a key is pressed
 342 class SDLKeyEvent
 343         super KeyEvent
 344         super SDLInputEvent
 345
 346         var key_name: String
 347         var down: Bool
 348
 349         init (key_name: String, down: Bool)
 350         do
 351                 self.key_name = key_name
 352                 self.down = down
 353         end
 354
 355         redef fun to_c: nullable Char
 356         do
 357                 if key_name.length == 1 then return key_name.chars.first
 358                 return null
 359         end
 360
 361         redef fun to_s
 362         do
 363                 if down then
 364                         return "KeyboardEvent key {key_name} down"
 365                 else
 366                         return "KeyboardEvent key {key_name} up"
 367                 end
 368         end
 369
 370         # Return true if the key is down, false otherwise
 371         redef fun is_down do return down
 372
 373         # Return true if the key is the up arrow
 374         redef fun is_arrow_up do return key_name == "up"
 375         # Return true if the key is the left arrow
 376         redef fun is_arrow_left do return key_name == "left"
 377         # Return true if the key is the down arrow
 378         redef fun is_arrow_down do return key_name == "down"
 379         # Return true if the key is the right arrow
 380         redef fun is_arrow_right do return key_name == "right"
 381 end
 382
 383 class SDLQuitEvent
 384         super SDLInputEvent
 385         super QuitEvent
 386 end
 387
 388 redef class Int
 389         fun delay `{ SDL_Delay(recv); `}
 390 end
 391
 392 # Class to load and use TTF_Font
 393 extern class SDLFont `{TTF_Font *`}
 394         # Load a font with a specified name and size
 395         new (name: String, points: Int) import String.to_cstring `{
 396         char * cname = String_to_cstring(name);
 397
 398         TTF_Font *font = TTF_OpenFont(cname, (int)points);
 399         if(!font) {
 400                 printf("TTF_OpenFont: %s\n", TTF_GetError());
 401                 exit(1);
 402         }
 403
 404         return font;
 405         `}
 406
 407         fun destroy `{ TTF_CloseFont(recv); `}
 408
 409         # Create a String with the specified color, return an SDLImage
 410         fun render(text: String, r, g, b: Int): SDLImage import String.to_cstring `{
 411                 SDL_Color color;
 412                 SDL_Surface *text_surface;
 413                 char *ctext;
 414
 415                 color.r = r;
 416                 color.g = g;
 417                 color.b = b;
 418
 419                 ctext = String_to_cstring(text);
 420                 if(!(text_surface=TTF_RenderText_Blended(recv, ctext, color)))
 421                 {
 422                         fprintf(stderr, "SDL TFF error: %s\n", TTF_GetError());
 423                         exit(1);
 424                 }
 425                 else
 426                         return text_surface;
 427         `}
 428
 429         # TODO reactivate fun below when updating libsdl_ttf to 2.0.10 or above
 430         #fun outline: Int # TODO check to make inline/nitside only
 431         #fun outline=(v: Int) is extern
 432
 433         #fun kerning: Bool is extern
 434         #fun kerning=(v: Bool) is extern
 435
 436         # Maximum pixel height of all glyphs of this font.
 437         fun height: Int `{
 438                 return TTF_FontHeight(recv);
 439         `}
 440
 441         fun ascent: Int `{
 442                 return TTF_FontAscent(recv);
 443         `}
 444
 445         fun descent: Int `{
 446                 return TTF_FontDescent(recv);
 447         `}
 448
 449         # Get the recommended pixel height of a rendered line of text of the loaded font. This is usually larger than the Font.height.
 450         fun line_skip: Int `{
 451                 return TTF_FontLineSkip(recv);
 452         `}
 453
 454         # Return true is the font used fixed width for each char
 455         fun is_fixed_width: Bool `{
 456                 return TTF_FontFaceIsFixedWidth(recv);
 457         `}
 458
 459         # Return the family name of the font
 460         fun family_name: nullable String import String.to_cstring, String.as nullable  `{
 461                 char *fn = TTF_FontFaceFamilyName(recv);
 462
 463                 if (fn == NULL)
 464                         return null_String();
 465                 else
 466                         return String_as_nullable(NativeString_to_s(fn));
 467         `}
 468
 469         # Return the style name of the font
 470         fun style_name: nullable String import String.to_cstring, String.as nullable  `{
 471                 char *sn = TTF_FontFaceStyleName(recv);
 472
 473                 if (sn == NULL)
 474                         return null_String();
 475                 else
 476                         return String_as_nullable(NativeString_to_s(sn));
 477         `}
 478
 479         # Return the estimated width of a String if used with the current font
 480         fun width_of(text: String): Int import NativeString.to_s `{
 481                 char *ctext = String_to_cstring(text);
 482                 int w;
 483                 if (TTF_SizeText(recv, ctext, &w, NULL))
 484                 {
 485                         fprintf(stderr, "SDL TFF error: %s\n", TTF_GetError());
 486                         exit(1);
 487                 }
 488                 else
 489                         return w;
 490         `}
 491 end
 492
 493 # Information on the SDL window
 494 # Used in other modules to get window handle
 495 extern class SDLSystemWindowManagerInfo `{SDL_SysWMinfo *`}
 496
 497         new `{
 498                 SDL_SysWMinfo *val = malloc(sizeof(SDL_SysWMinfo));
 499
 500                 SDL_VERSION(&val->version);
 501
 502                 if(SDL_GetWMInfo(val) <= 0) {
 503                         printf("Unable to get window handle");
 504                         return 0;
 505                 }
 506
 507                 return val;
 508         `}
 509
 510         # Returns the handle of this window on a X11 window system
 511         fun x11_window_handle: Pointer `{
 512                 return (void*)recv->info.x11.window;
 513         `}
 514 end