src/common_ffi/pkgconfig.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Offers the `PkgconfigPhase` to use the external program "pkg-config" in order
  18 # to discover what options to pass to the C or C++ compiler.
  19 module pkgconfig
  20
  21 import c
  22 private import annotation
  23
  24 redef class ToolContext
  25         var pkgconfig_phase: Phase = new PkgconfigPhase(self, [literal_phase])
  26 end
  27
  28 # Detects the `pkgconfig` annotation on the module declaration only.
  29 class PkgconfigPhase
  30         super Phase
  31
  32         redef fun process_annotated_node(nmoduledecl, nat)
  33         do
  34                 # Skip if we are not interested
  35                 if nat.name != "pkgconfig" then return
  36
  37                 # Do some validity checks and print errors if the annotation is used incorrectly
  38                 var modelbuilder = toolcontext.modelbuilder
  39
  40                 if not nmoduledecl isa AModuledecl then
  41                         modelbuilder.error(nat, "Syntax error: only the declaration of modules may use \"pkgconfig\".")
  42                         return
  43                 end
  44
  45                 var args = nat.n_args
  46                 if args.is_empty then
  47                         modelbuilder.error(nat, "Syntax error: \"pkgconfig\" expects at least one argument.")
  48                         return
  49                 end
  50
  51                 var pkgs = new Array[String]
  52                 for arg in args do
  53                         var pkg = arg.as_string
  54                         if pkg == null then
  55                                 modelbuilder.error(nat, "Syntax error: \"pkgconfig\" expects its arguments to be the name of the package as String literals.")
  56                                 return
  57                         end
  58
  59                         pkgs.add(pkg)
  60                 end
  61
  62                 # retreive module
  63                 var nmodule = nmoduledecl.parent.as(AModule)
  64                 var mmodule = nmodule.mmodule.as(not null)
  65
  66                 # check availability of pkg-config
  67                 var proc_which = new IProcess("which", "pkg-config")
  68                 proc_which.wait
  69                 var status = proc_which.status
  70                 if status != 0 then
  71                         modelbuilder.error(nat, "Error: program pkg-config not found, make sure it is installed.")
  72                         return
  73                 end
  74
  75                 for pkg in pkgs do
  76                         var proc_exist = new Process("pkg-config", "--exists", pkg)
  77                         proc_exist.wait
  78                         status = proc_exist.status
  79                         if status == 1 then
  80                                 modelbuilder.error(nat, "Error: package \"{pkg}\" unknown by pkg-config, make sure the development package is be installed.")
  81                                 return
  82                         else if status != 0 then
  83                                 modelbuilder.error(nat, "Error: something went wrong calling pkg-config, make sure it is correctly installed.")
  84                                 return
  85                         end
  86
  87                         # compiler
  88                         var proc = new IProcess("pkg-config", "--cflags", pkg)
  89                         var compiler_opts = proc.read_all
  90                         mmodule.c_compiler_options = "{mmodule.c_compiler_options} {compiler_opts.replace("\n", " ")}"
  91
  92                         # linker
  93                         proc = new IProcess("pkg-config", "--libs", pkg)
  94                         var linker_opts = proc.read_all
  95                         mmodule.c_linker_options = "{mmodule.c_linker_options} {linker_opts.replace("\n", " ")}"
  96                 end
  97
  98         end
  99 end