lib/html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML output facilities
  16 module html
  17
  18 # A html page
  19 #
  20 # You can define subclass and override methods head and body
  21 #
  22 # class MyPage
  23 #       super HTMLPage
  24 #       redef body do add("p").text("Hello World!")
  25 # end
  26 #
  27 # HTMLPage use fluent interface so you can chain calls as:
  28 #       add("div").attr("id", "mydiv").text("My Div")
  29 class HTMLPage
  30
  31         # Define head content
  32         fun head do end
  33         # Define body content
  34         fun body do end
  35
  36         private var root = new HTMLTag("html")
  37         private var current: HTMLTag = root
  38         private var stack = new List[HTMLTag]
  39
  40         # Render the page as a html string
  41         fun render: String do
  42                 root.children.clear
  43                 open("head")
  44                 head
  45                 close("head")
  46                 open("body")
  47                 body
  48                 close("body")
  49                 return "<!DOCTYPE html>{root.html}"
  50         end
  51
  52         # Add a html tag to the current element
  53         # add("div").attr("id", "mydiv").text("My Div")
  54         fun add(tag: String): HTMLTag do
  55                 var node = new HTMLTag(tag)
  56                 current.add(node)
  57                 return node
  58         end
  59
  60         # Add a raw html string
  61         # add_html("<a href='#top'>top</a>")
  62         fun add_html(html: String) do current.add(new HTMLRaw(html))
  63
  64         # Open a html tag
  65         # open("ul")
  66         # add("li").text("item1")
  67         # add("li").text("item2")
  68         # close("ul")
  69         fun open(tag: String): HTMLTag do
  70                 stack.push(current)
  71                 current = add(tag)
  72                 return current
  73         end
  74
  75         # Close previously opened tag
  76         # Ensure: tag = previous.tag
  77         fun close(tag: String) do
  78                 if not tag == current.tag then
  79                         print "Error: Trying to close '{tag}', last opened tag was '{current.tag}'."
  80                         abort
  81                 end
  82                 current = stack.pop
  83         end
  84
  85         # Save html page in the specified file
  86         fun save(file: String) do
  87                 var out = new OFStream.open(file)
  88                 out.write(self.render)
  89                 out.close
  90         end
  91 end
  92
  93 class HTMLTag
  94         # HTML tagname: 'div' for <div></div>
  95         var tag: String
  96         init(tag: String) do self.tag = tag
  97
  98         init with_attrs(tag: String, attrs: Map[String, String]) do
  99                 self.tag = tag
 100                 self.attrs = attrs
 101         end
 102
 103         # Tag attributes map
 104         var attrs: Map[String, String] = new HashMap[String, String]
 105
 106         # Get the attributed value of 'prop' or null if 'prop' is undifened
 107         fun get_attr(key: String): nullable String do
 108                 if not attrs.has_key(key) then return null
 109                 return attrs[key]
 110         end
 111
 112         # Set a 'value' for 'key'
 113         # var img = new HTMLTag("img")
 114         # img.attr("src", "./image.png").attr("alt", "image")
 115         fun attr(key: String, value: String): HTMLTag do
 116                 attrs[key] = value
 117                 return self
 118         end
 119
 120         # Add a CSS class to the HTML tag
 121         # var img = new HTMLTag("img")
 122         # img.add_class("logo").add_class("fullpage")
 123         fun add_class(klass: String): HTMLTag do
 124                 classes.add(klass)
 125                 return self
 126         end
 127         private var classes: Set[String] = new HashSet[String]
 128
 129         # Set a CSS 'value' for 'prop'
 130         # var img = new HTMLTag("img")
 131         # img.css("border", "2px solid black").css("position", "absolute")
 132         fun css(prop: String, value: String): HTMLTag do
 133                 css_props[prop] = value
 134                 return self
 135         end
 136         private var css_props: Map[String, String] = new HashMap[String, String]
 137
 138         # Get CSS value for 'prop'
 139         fun get_css(prop: String): nullable String do
 140                 if not css_props.has_key(prop) then return null
 141                 return css_props[prop]
 142         end
 143
 144         # Add a HTML 'child' to self
 145         # var ul = new HTMLTag("ul")
 146         # ul.add(new HTMLTag("li"))
 147         fun add(child: HTMLTag) do children.add(child)
 148
 149         # List of children HTML elements
 150         var children: Set[HTMLTag] = new HashSet[HTMLTag]
 151
 152         # Set text of element
 153         # var p = new HTMLTag("p")
 154         # p.text("Hello World!")
 155         # Text is escaped see: standard::String::html_escape
 156         fun text(txt: String): HTMLTag do
 157                 content = txt
 158                 return self
 159         end
 160         private var content: String = ""
 161
 162         # Append text to element
 163         # var p = new HTMLTag("p")
 164         # p.append("Hello").append("<br/>").append("World!")
 165         # Text is escaped see: standard::String::html_escape
 166         fun append(txt: String): HTMLTag do
 167                 text("{content}{txt}")
 168                 return self
 169         end
 170
 171         # Render the element as HTML string
 172         fun html: String do
 173                 var content = render_content
 174                 if tag != "script" and content.is_empty then return "<{tag}{render_attrs}/>"
 175                 return "<{tag}{render_attrs}>{content}</{tag}>"
 176         end
 177
 178         private fun render_attrs: String do
 179                 var str = "{render_classes}{render_css}"
 180                 for key, value in attrs do
 181                         if key == "class" or key == "style" then continue
 182                         str = "{str} {key}='{value}'"
 183                 end
 184                 return str
 185         end
 186
 187         private fun render_css: String do
 188                 var css = ""
 189                 if attrs.has_key("style") then css = attrs["style"]
 190                 for key, value in self.css_props do
 191                         css = "{css}; {key}: {value}"
 192                 end
 193                 if css.is_empty then return ""
 194                 return " style='{css}'"
 195         end
 196
 197         private fun render_classes: String do
 198                 var cls = ""
 199                 if attrs.has_key("class") then cls = attrs["class"]
 200                 if not classes.is_empty then cls = " class='{cls} {classes.join(" ")}'"
 201                 if cls.is_empty then return ""
 202                 return cls
 203         end
 204
 205         private fun render_content: String do
 206                 var str = content.html_escape
 207                 for child in children do
 208                         str += child.html
 209                 end
 210                 return str
 211         end
 212 end
 213
 214 private class HTMLRaw
 215         super HTMLTag
 216
 217         init(content: String) do self.content = content
 218         redef fun html do return content
 219 end