lib/android/audio.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Romain Chanoir <romain.chanoir@viacesi.fr>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Android audio services, wraps a part of android audio API
  18 # This module modifies the default behaviour of the audio loading:
  19 # It is first loaded from the `res/raw` folder.
  20 # The file extension is not needed for the `res/raw` loading part.
  21 # If it didn't work, it is loaded from the `assets` folder.
  22 # The file extension is needed for the `assets` loading part.
  23 #
  24 # `assets` contains the portable version of sounds, since the `res` folder exsists only in android projects.
  25 #
  26 # For this example, the sounds "test_sound" and "test_music" are located in the "assets/sounds" folder,
  27 # they both have ".ogg" extension. "test_sound" is a short sound and "test_music" a music track
  28 #
  29 # ~~~nitish
  30 # # Note that you need to specify the path from "assets" folder and the extension
  31 # var s = app.load_sound("sounds/test_sound.ogg")
  32 # var m = app.load_music("sounds/test_music.ogg")
  33 # s.play
  34 # m.play
  35 # ~~~
  36 #
  37 # Now, the sounds are in "res/raw"
  38 # ~~~nitish
  39 # s = app.load_sound_from_res("test_sound")
  40 # m = app.load_music_from_res("test_sound")
  41 # s.play
  42 # m.play
  43 # ~~~
  44 #
  45 # See http://developer.android.com/reference/android/media/package-summary.html for more infos
  46 module audio
  47
  48 import java
  49 import java::io
  50 intrude import assets_and_resources
  51 import native_app_glue # FIXME update this module to use nit_activity
  52 import app::audio
  53
  54 in "Java" `{
  55         import android.media.MediaPlayer;
  56         import android.media.SoundPool;
  57         import java.io.IOException;
  58         import android.media.AudioManager;
  59         import android.media.AudioManager.OnAudioFocusChangeListener;
  60         import android.content.Context;
  61         import android.util.Log;
  62 `}
  63
  64 # FIXME: This listener is not working at the moment, but is needed to gain or give up the audio focus
  65 # of the application
  66 in "Java inner" `{
  67         static OnAudioFocusChangeListener afChangeListener = new OnAudioFocusChangeListener() {
  68                 public void onAudioFocusChange(int focusChange) {
  69                         if(focusChange == AudioManager.AUDIOFOCUS_LOSS_TRANSIENT) {
  70                         }else if (focusChange == AudioManager.AUDIOFOCUS_GAIN) {
  71                         }else if (focusChange == AudioManager.AUDIOFOCUS_LOSS) {
  72                         }
  73                 }
  74         };
  75 `}
  76
  77 # AudioManager of the application, used to manage the audio mode
  78 private extern class NativeAudioManager in "Java" `{ android.media.AudioManager `}
  79         super JavaObject
  80
  81         # Current audio mode.
  82         # ( MODE_NORMAL = 0, MODE_RINGTONE = 1, MODE_IN_CALL = 2 or MODE_IN_COMMUNICATION = 3 )
  83         fun mode: Int in "Java" `{ return self.getMode(); `}
  84
  85         # Sets the audio mode.
  86         # ( MODE_NORMAL = 0, MODE_RINGTONE = 1, MODE_IN_CALL = 2 or MODE_IN_COMMUNICATION = 3 )
  87         fun mode=(i: Int) in "Java" `{ self.setMode((int)i); `}
  88
  89         # Sends a request to obtain audio focus
  90         fun request_audio_focus: Int in "Java" `{
  91                 return self.requestAudioFocus(afChangeListener, AudioManager.STREAM_MUSIC, AudioManager.AUDIOFOCUS_GAIN);
  92         `}
  93
  94         # Gives up audio focus
  95         fun abandon_audio_focus: Int in "Java" `{ return self.abandonAudioFocus(afChangeListener); `}
  96 end
  97
  98 # Media Player from Java, used to play long sounds or musics, not simultaneously
  99 # This is a low-level class, use `MediaPlater` instead
 100 private extern class NativeMediaPlayer in "Java" `{ android.media.MediaPlayer `}
 101         super JavaObject
 102
 103         new in "Java" `{
 104                 MediaPlayer mp = new MediaPlayer();
 105                 mp.setAudioStreamType(AudioManager.STREAM_MUSIC);
 106                 return mp;
 107         `}
 108         fun start in "Java" `{ self.start(); `}
 109         fun prepare in "Java" `{
 110                 try {
 111                         self.prepare();
 112                 }catch(Exception e) {
 113                         Log.e("Error preparing the Media Player", e.getMessage());
 114                         e.printStackTrace();
 115                 }
 116         `}
 117
 118         fun create(context: NativeActivity, id: Int): NativeMediaPlayer in "Java" `{
 119                 try {
 120                         return self.create(context, (int)id);
 121                 }catch(Exception e) {
 122                         return null;
 123                 }
 124         `}
 125
 126         fun pause in "Java" `{ self.pause(); `}
 127         fun stop in "Java" `{ self.stop(); `}
 128         fun playing: Bool in "Java" `{ return self.isPlaying(); `}
 129         fun release in "Java" `{ self.release(); `}
 130         fun duration: Int in "Java" `{ return self.getDuration(); `}
 131         fun looping: Bool in "Java" `{ return self.isLooping(); `}
 132         fun looping=(b: Bool) in "Java" `{ self.setLooping(b); `}
 133         fun volume=(vol: Float) in "Java" `{ self.setVolume((float)vol, (float)vol); `}
 134         fun both_volume(left_volume, right_volume: Float) in "Java" `{ self.setVolume((float)left_volume, (float)right_volume); `}
 135         fun stream_type=(stream_type: Int) in "Java" `{ self.setAudioStreamType((int)stream_type); `}
 136         fun data_source_fd(fd: NativeFileDescriptor, start_offset, length: Int): Int in "Java"  `{
 137                 try {
 138                         self.setDataSource(fd, start_offset, length);
 139                         return 1;
 140                 }catch(Exception e) {
 141                         Log.e("Error loading the Media Player with a file descriptor", e.getMessage());
 142                         return 0;
 143                 }
 144         `}
 145         fun data_source_path(path: JavaString): Int in "Java" `{
 146                 try {
 147                         self.setDataSource(path);
 148                         return 1;
 149                 }catch(Exception e) {
 150                         Log.e("Error loading the Media Player", e.getMessage());
 151                         return 0;
 152                 }
 153         `}
 154         fun reset in "Java" `{ self.reset(); `}
 155 end
 156
 157 # Sound Pool from Java, used to play sounds simultaneously
 158 # This is a low-level class, use `SoundPool`instead
 159 private extern class NativeSoundPool in "Java" `{ android.media.SoundPool `}
 160         super JavaObject
 161
 162         new(max_streams, stream_type, src_quality: Int) in "Java" `{
 163                 return new SoundPool((int)max_streams, (int)stream_type, (int)src_quality);
 164         `}
 165         fun load_asset_fd(afd: NativeAssetFileDescriptor, priority: Int): Int in "Java" `{
 166                 try {
 167                         int id =  self.load(afd, (int)priority);
 168                         return id;
 169                 }catch(Exception e){
 170                         return -1;
 171                 }
 172         `}
 173
 174         fun load_id(context: NativeActivity, resid, priority: Int): Int in "Java" `{
 175                 try {
 176                         int id =  self.load(context, (int)resid, (int)priority);
 177                         return id;
 178                 }catch(Exception e){
 179                         return -1;
 180                 }
 181         `}
 182
 183         fun load_path(path: JavaString, priority: Int): Int in "Java" `{
 184                 try {
 185                         int id =  self.load(path, (int)priority);
 186                         return id;
 187                 }catch(Exception e){
 188                         return -1;
 189                 }
 190         `}
 191
 192         fun play(sound_id: Int, left_volume, right_volume: Float, priority, l: Int, rate: Float): Int in "Java" `{
 193                 return self.play((int)sound_id, (float)left_volume, (float)right_volume, (int)priority, (int)l, (float)rate);
 194         `}
 195         fun pause(stream_id: Int) in "Java" `{ self.pause((int)stream_id); `}
 196         fun auto_pause in "Java" `{ self.autoPause(); `}
 197         fun auto_resume in "Java" `{ self.autoResume(); `}
 198         fun resume(stream_id: Int) in "Java" `{ self.resume((int)stream_id); `}
 199         fun set_loop(stream_id, l: Int) in "Java" `{ self.setLoop((int)stream_id, (int)l); `}
 200         fun set_priority(stream_id, priority: Int) in "Java" `{ self.setPriority((int)stream_id, (int)priority); `}
 201         fun set_rate(stream_id: Int, rate: Float) in "Java" `{ self.setRate((int)stream_id, (float)rate); `}
 202         fun set_volume(stream_id: Int, left_volume, right_volume: Float) in "Java" `{ self.setVolume((int)stream_id, (float)left_volume, (float)right_volume); `}
 203         fun stop(stream_id: Int) in "Java" `{ self.stop((int)stream_id); `}
 204         fun unload(sound_id: Int): Bool in "Java" `{ return self.unload((int)sound_id); `}
 205         fun release in "Java" `{ self.release(); `}
 206 end
 207
 208
 209 # Used to play sound, best suited for sounds effects in apps or games
 210 class SoundPool
 211
 212         # Error gestion
 213         var error: nullable Error = null
 214
 215         private var nsoundpool: NativeSoundPool is noinit
 216         # The maximum number of simultaneous streams for this SoundPool
 217         var max_streams = 10 is writable
 218
 219         # The audio stream type, 3 is STREAM_MUSIC, default for game application
 220         var stream_type = 3 is writable
 221
 222         # The sample-rate converter quality, currently has no effect
 223         var src_quality = 0 is writable
 224
 225         # Left volume value, range 0.0 to 1.0
 226         var left_volume = 1.0 is writable
 227
 228         # Right volume value, range 0.0 to 1.0
 229         var right_volume = 1.0 is writable
 230
 231         # Playback rate, 1.0 = normal playback, range 0.5 to 2.0
 232         var rate = 1.0 is writable
 233
 234         # Loop mode, 0 = no loop, -1 = loop forever
 235         var looping = 0 is writable
 236
 237         # Stream priority
 238         private var priority = 1
 239
 240         init do self.nsoundpool = new NativeSoundPool(max_streams, stream_type, src_quality)
 241
 242         # Load the sound from an asset file descriptor
 243         # this function is for advanced use
 244         private fun load_asset_fd(afd: NativeAssetFileDescriptor): Sound do
 245                 var resval = nsoundpool.load_asset_fd(afd, self.priority)
 246                 if  resval == -1 then
 247                         self.error = new Error("Unable to load sound from assets")
 248                         return new Sound.priv_init(null, -1, self, self.error)
 249                 else
 250                         return new Sound.priv_init(null, resval, self, null)
 251                 end
 252         end
 253
 254         # Returns only the id corresponding to the soundpool where the sound is loaded.
 255         # Needed by `load` of `Sound`.
 256         private fun load_asset_fd_rid(afd: NativeAssetFileDescriptor): Int do
 257                 return nsoundpool.load_asset_fd(afd, self.priority)
 258         end
 259
 260         # Load the sound from its resource id
 261         fun load_id(context: NativeActivity, id:Int): Sound do
 262                 var resval = nsoundpool.load_id(context, id, priority)
 263                         if  resval == -1 then
 264                         self.error = new Error("Unable to load sound from assets")
 265                         return new Sound.priv_init(null, -1, self, self.error)
 266                 else
 267                         return new Sound.priv_init(null, resval, self, null)
 268                 end
 269         end
 270
 271         # Returns only the id corresponding to the soundpool where the sound is loaded.
 272         private fun load_id_rid(context: NativeActivity, id: Int): Int do
 273                 return nsoundpool.load_id(context, id, priority)
 274         end
 275
 276         # Load the sound from the specified path
 277         fun load_path(path: String): Sound do
 278                 sys.jni_env.push_local_frame(1)
 279                 var resval = nsoundpool.load_path(path.to_java_string, priority)
 280                 sys.jni_env.pop_local_frame
 281                 if  resval == -1 then
 282                         self.error = new Error("Unable to load sound from path : " + path)
 283                         return new Sound.priv_init(null, -1, self, self.error)
 284                 else
 285                         return new Sound.priv_init(null, resval, self, null)
 286                 end
 287         end
 288
 289         # Play a sound from a sound ID
 290         # return non-zero streamID if successful, zero if failed
 291         fun play(id: Int): Int do
 292                 return nsoundpool.play(id, left_volume, right_volume, priority, looping, rate)
 293         end
 294
 295         # Load a sound by its name in the resources, the sound must be in the `res/raw` folder
 296         fun load_name(resource_manager: ResourcesManager, context: NativeActivity, sound: String): Sound do
 297                 var id = resource_manager.raw_id(sound)
 298                 var resval = nsoundpool.load_id(context, id, priority)
 299                 if  resval == -1 then
 300                         self.error = new Error("Unable to load sound from resources : " + sound)
 301                         return new Sound.priv_init(null, -1, self, self.error)
 302                 else
 303                         return new Sound.priv_init(null, resval, self, null)
 304                 end
 305         end
 306
 307         # Returns only the id corresponding to the soundpool where the sound is loaded.
 308         private fun load_name_rid(resource_manager: ResourcesManager, context: NativeActivity, sound: String): Int do
 309                 var id = resource_manager.raw_id(sound)
 310                 return nsoundpool.load_id(context, id, priority)
 311         end
 312
 313         # Pause a playback stream
 314         fun pause_stream(stream_id: Int) do nsoundpool.pause(stream_id)
 315
 316         # Pause all active_streams
 317         fun auto_pause do nsoundpool.auto_pause
 318
 319         # Resume all previously active streams
 320         fun auto_resume do nsoundpool.auto_resume
 321
 322         # Resume a playback stream
 323         fun resume(stream_id: Int) do nsoundpool.resume(stream_id)
 324
 325         # Set loop mode on a stream
 326         fun stream_loop=(stream_id, looping: Int) do nsoundpool.set_loop(stream_id, looping)
 327
 328         # Change stream priority
 329         fun stream_priority=(stream_id, priority: Int) do nsoundpool.set_priority(stream_id, priority)
 330
 331         # Change playback rate
 332         fun stream_rate=(stream_id: Int, rate: Float) do nsoundpool.set_rate(stream_id, rate)
 333
 334         # Set stream volume
 335         fun stream_volume(stream_id: Int, left_volume, right_volume: Float) do
 336                 nsoundpool.set_volume(stream_id, left_volume, right_volume)
 337         end
 338
 339         # Stop a playback stream
 340         fun stop_stream(stream_id: Int) do nsoundpool.stop(stream_id)
 341
 342         # Unload a sound from a sound ID
 343         fun unload(sound: Sound): Bool do return nsoundpool.unload(sound.soundpool_id)
 344
 345         # Destroys the object
 346         fun destroy do nsoundpool.release
 347 end
 348
 349 # Used to play sounds, designed to use with medium sized sounds or streams
 350 # The Android MediaPlayer has a complex state diagram that you'll need to
 351 # respect if you want your MediaPlayer to work fine, see the android doc
 352 class MediaPlayer
 353         private var nmedia_player: NativeMediaPlayer is noinit
 354
 355         # Used to control the state of the mediaplayer
 356         private var is_prepared = false is writable
 357
 358         # The sound associated with this mediaplayer
 359         var sound: nullable Music = null is writable
 360
 361         # Error gestion
 362         var error: nullable Error = null
 363
 364         # Create a new MediaPlayer, but no sound is attached, you'll need
 365         # to use `load_sound` before using it
 366         init do self.nmedia_player = new NativeMediaPlayer
 367
 368         # Init the mediaplayer with a sound resource id
 369         init from_id(context: NativeActivity, id: Int) do
 370                 self.nmedia_player = new NativeMediaPlayer
 371                 self.nmedia_player = nmedia_player.create(context, id)
 372                 if self.nmedia_player.is_java_null then
 373                         self.error = new Error("Failed to create the MediaPlayer")
 374                         self.sound = new Music.priv_init(id, self, self.error)
 375                 end
 376                 self.sound = new Music.priv_init(id, self, null)
 377         end
 378
 379         # Load a sound for a given resource id
 380         fun load_sound(id: Int, context: NativeActivity): Music do
 381                 self.nmedia_player = self.nmedia_player.create(context, id)
 382                 if self.nmedia_player.is_java_null then
 383                         self.error = new Error("Failed to load a sound")
 384                         self.sound = new Music.priv_init(id, self, new Error("Sound loading failed"))
 385                         return self.sound.as(not null)
 386                 else
 387                         if self.error != null then self.error = null
 388                         self.sound = new Music.priv_init(id, self, null)
 389                         self.is_prepared = true
 390                         return self.sound.as(not null)
 391                 end
 392         end
 393
 394         # Starts or resumes playback
 395         # REQUIRE `self.sound != null`
 396         fun start do
 397                 if self.error != null then return
 398                 if not is_prepared then prepare
 399                 nmedia_player.start
 400         end
 401
 402         # Stops playback after playback has been stopped or paused
 403         # REQUIRE `self.sound != null`
 404         fun stop do
 405                 if self.error != null then return
 406                 is_prepared = false
 407                 nmedia_player.stop
 408         end
 409
 410         # Prepares the player for playback, synchronously
 411         # REQUIRE `self.sound != null`
 412         fun prepare do
 413                 if self.error != null then return
 414                 assert sound != null
 415                 nmedia_player.prepare
 416                 is_prepared = true
 417         end
 418
 419         # Pauses playback
 420         # REQUIRE `self.sound != null`
 421         fun pause do
 422                 if self.error != null then return
 423                 assert sound != null
 424                 nmedia_player.pause
 425         end
 426
 427         # Checks whether the mediaplayer is playing
 428         fun playing: Bool do return nmedia_player.playing
 429
 430         # Releases the resources associated with this MediaPlayer
 431         fun destroy do
 432                 nmedia_player.release
 433                 self.sound = null
 434         end
 435
 436         # Reset MediaPlayer to its initial state
 437         fun reset do nmedia_player.reset
 438
 439         # Sets the datasource (file-path or http/rtsp URL) to use
 440         fun data_source(path: String): Music do
 441                 sys.jni_env.push_local_frame(1)
 442                 var retval = nmedia_player.data_source_path(path.to_java_string)
 443                 sys.jni_env.pop_local_frame
 444                 if retval == 0 then
 445                         self.error = new Error("could not load the sound " + path)
 446                         self.sound = new Music.priv_init(null, self, self.error)
 447
 448                 else
 449                         self.sound = new Music.priv_init(null, self, null)
 450                 end
 451                 return self.sound.as(not null)
 452         end
 453         # Sets the data source (NativeFileDescriptor) to use
 454         fun data_source_fd(fd: NativeAssetFileDescriptor): Music do
 455                 if not fd.is_java_null then
 456                         if nmedia_player.data_source_fd(fd.file_descriptor, fd.start_offset, fd.length) == 0 then
 457                                 self.error = new Error("could not load the sound")
 458                                 self.sound = new Music.priv_init(null, self, self.error)
 459                         else
 460                                 self.sound = new Music.priv_init(null, self, null)
 461                         end
 462                         return self.sound.as(not null)
 463                 else
 464                         var error = new Error("could not load the sound")
 465                         return new Music.priv_init(null, self, error)
 466                 end
 467         end
 468
 469         # Checks whether the MediaPlayer is looping or non-looping
 470         fun looping: Bool do return nmedia_player.looping
 471
 472         # Sets the player to be looping or non-looping
 473         fun looping=(b: Bool) do nmedia_player.looping = b
 474
 475         # Sets the volume on this player
 476         fun volume=(volume: Float) do nmedia_player.volume = volume
 477
 478         # Sets the left volume and the right volume of this player
 479         fun both_volume(left_volume, right_volume: Float) do nmedia_player.both_volume(left_volume, right_volume)
 480
 481         # Sets the audio stream type for this media player
 482         fun stream_type=(stream_type: Int) do nmedia_player.stream_type = stream_type
 483 end
 484
 485 redef class PlayableAudio
 486         redef init do app.add_to_sounds(self)
 487 end
 488
 489 redef class Sound
 490
 491         # Resource ID of this sound
 492         var id: nullable Int is noinit
 493
 494         # The SoundPool who loaded this sound
 495         var soundpool: SoundPool is noinit
 496
 497         # The SoundID of this sound in his SoundPool
 498         var soundpool_id: Int is noinit
 499
 500         private init priv_init(id: nullable Int, soundpool_id: Int, soundpool: SoundPool, error: nullable Error) is nosuper do
 501                 self.id = id
 502                 self.soundpool_id = soundpool_id
 503                 self.soundpool = soundpool
 504                 if error != null then
 505                         self.error = error
 506                 else
 507                         self.is_loaded = true
 508                 end
 509         end
 510
 511         redef fun load do
 512                 if is_loaded then return
 513                 var retval_resources = app.default_soundpool.load_name_rid(app.resource_manager, app.native_activity, self.name.strip_extension)
 514                 if retval_resources == -1 then
 515                         self.error = new Error("failed to load" + self.name)
 516                         var nam = app.asset_manager.open_fd(self.name)
 517                         if nam.is_java_null then
 518                                 self.error = new Error("Failed to get file descriptor for " + self.name)
 519                         else
 520                                 var retval_assets = app.default_soundpool.load_asset_fd_rid(nam)
 521                                 if retval_assets == -1 then
 522                                         self.error = new Error("Failed to load" + self.name)
 523                                 else
 524                                         self.soundpool_id = retval_assets
 525                                         self.soundpool = app.default_soundpool
 526                                         self.error = null
 527                                         self.soundpool.error = null
 528                                 end
 529                         end
 530                 else
 531                         self.soundpool_id = retval_resources
 532                         self.soundpool = app.default_soundpool
 533                         self.error = null
 534                         self.soundpool.error = null
 535                 end
 536                 is_loaded = true
 537         end
 538
 539         redef fun play do
 540                 if self.error != null then return
 541                 if not is_loaded then load
 542                 soundpool.play(soundpool_id)
 543         end
 544
 545         redef fun pause do
 546                 if self.error != null or not self.is_loaded then return
 547                 soundpool.pause_stream(soundpool_id)
 548         end
 549
 550         redef fun resume do
 551                 if self.error != null or not self.is_loaded then return
 552                 soundpool.resume(soundpool_id)
 553         end
 554
 555 end
 556
 557 redef class Music
 558
 559         # Resource ID of this sound
 560         var id: nullable Int is noinit
 561
 562         # The MediaPlayer who loaded this sound
 563         var media_player: MediaPlayer is noinit
 564
 565         private init priv_init(id: nullable Int, media_player: MediaPlayer, error: nullable Error) is nosuper do
 566                 self.id = id
 567                 self.media_player = media_player
 568                 if error != null then
 569                         self.error = error
 570                 else
 571                         self.is_loaded = true
 572                 end
 573         end
 574
 575         redef fun load do
 576                 if is_loaded then return
 577                 var mp_sound_resources = app.default_mediaplayer.load_sound(app.resource_manager.raw_id(self.name.strip_extension), app.native_activity)
 578                 if mp_sound_resources.error != null then
 579                         self.error = mp_sound_resources.error
 580                         var nam = app.asset_manager.open_fd(self.name)
 581                         if nam.is_java_null then
 582                                 self.error = new Error("Failed to get file descriptor for " + self.name)
 583                         else
 584                                 var mp_sound_assets = app.default_mediaplayer.data_source_fd(nam)
 585                                 if mp_sound_assets.error != null then
 586                                         self.error = mp_sound_assets.error
 587                                 else
 588                                         self.media_player = app.default_mediaplayer
 589                                         self.error = null
 590                                         self.media_player.error = null
 591                                 end
 592                         end
 593                 else
 594                         self.media_player = app.default_mediaplayer
 595                         self.error = null
 596                         self.media_player.error = null
 597                 end
 598                 is_loaded = true
 599         end
 600
 601         redef fun play do
 602                 if self.error != null then return
 603                 if not is_loaded then load
 604                 media_player.start
 605         end
 606
 607         redef fun pause do
 608                 if self.error != null or not self.is_loaded then return
 609                 media_player.pause
 610         end
 611
 612         redef fun resume do
 613                 if self.error != null or not self.is_loaded then return
 614                 play
 615         end
 616 end
 617
 618 redef class App
 619
 620         # Sounds handled by the application, when you load a sound, it's added to this list.
 621         # This array is used in `pause` and `resume`
 622         private var sounds = new Array[PlayableAudio]
 623
 624         # Returns the default MediaPlayer of the application.
 625         # When you load a music, it goes in this MediaPlayer.
 626         # Use it for advanced sound management
 627         var default_mediaplayer: MediaPlayer is lazy do return new MediaPlayer
 628
 629         # Returns the default MediaPlayer of the application.
 630         # When you load a short sound (not a music), it's added to this soundpool.
 631         # Use it for advanced sound management.
 632         var default_soundpool: SoundPool is lazy do return new SoundPool
 633
 634         # Get the native audio manager
 635         fun audio_manager: NativeAudioManager import native_activity in "Java" `{
 636                 return (AudioManager)App_native_activity(self).getSystemService(Context.AUDIO_SERVICE);
 637         `}
 638
 639         # Sets the stream of the app to STREAM_MUSIC.
 640         # STREAM_MUSIC is the default stream used by android apps.
 641         private fun manage_audio_stream import native_activity, native_app_glue in "Java" `{
 642                 App_native_activity(self).setVolumeControlStream(AudioManager.STREAM_MUSIC);
 643         `}
 644
 645         # Retrieves a sound with a soundpool in the `assets` folder using its name.
 646         # Used to play short songs, can play multiple sounds simultaneously
 647         redef fun load_sound(path) do
 648                 var fd = asset_manager.open_fd(path)
 649                 if not fd.is_java_null then
 650                         return add_to_sounds(default_soundpool.load_asset_fd(fd)).as(Sound)
 651                 else
 652                         var error = new Error("Failed to load Sound {path}")
 653                         return new Sound.priv_init(null, -1, default_soundpool, error)
 654                 end
 655         end
 656
 657         # Retrieves a music with a media player in the `assets` folder using its name.
 658         # Used to play long sounds or musics, can't play multiple sounds simultaneously
 659         redef fun load_music(path) do
 660                 var fd = asset_manager.open_fd(path)
 661                 if not fd.is_java_null then
 662                         return add_to_sounds(default_mediaplayer.data_source_fd(fd)).as(Music)
 663                 else
 664                         var error = new Error("Failed to load music {path}")
 665                         return new Music.priv_init(null, default_mediaplayer, error)
 666                 end
 667         end
 668
 669         # Same as `load_sound` but load the sound from the `res/raw` folder
 670         fun load_sound_from_res(sound_name: String): Sound do
 671                 return add_to_sounds(default_soundpool.load_name(resource_manager,self.native_activity, sound_name)).as(Sound)
 672         end
 673
 674         # Same as `load_music` but load the sound from the `res/raw` folder
 675         fun load_music_from_res(music: String): Music do
 676                 return add_to_sounds(default_mediaplayer.load_sound(resource_manager.raw_id(music), self.native_activity)).as(Music)
 677         end
 678
 679         # Factorizes `sounds.add` to use it in `load_music`, `load_sound`, `load_music_from_res` and `load_sound_from_res`
 680         private fun add_to_sounds(sound: PlayableAudio): PlayableAudio do
 681                 sounds.add(sound)
 682                 return sound
 683         end
 684
 685         redef fun pause do
 686                 super
 687                 for s in sounds do s.pause
 688                 audio_manager.abandon_audio_focus
 689         end
 690
 691         redef fun init_window do
 692                 super
 693                 audio_manager.request_audio_focus
 694                 manage_audio_stream
 695         end
 696
 697         redef fun resume do
 698                 super
 699                 audio_manager.request_audio_focus
 700                 for s in sounds do s.resume
 701         end
 702 end