contrib/objcwrapper/src/objcwrapper.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Generator of Nit modules to wrap Objective-C services
  16 module objcwrapper
  17
  18 import nitcc_runtime
  19 import opts
  20
  21 import objc_visitor
  22 import objc_model
  23 import objc_generator
  24 import objc_lexer
  25 import objc_parser
  26 import preprocessing
  27
  28 var opt_help = new OptionBool("Show this help message", "-h", "--help")
  29
  30 var opts = new OptionContext
  31 opts.add_option(opt_help, opt_output, opt_init_as_methods, opt_gcc_options)
  32 opts.parse args
  33
  34 if opts.errors.not_empty or opts.rest.is_empty or opt_help.value then
  35         if opts.errors.not_empty then print_error opts.errors.join("\n")
  36
  37         print_error """
  38 Usage: objcwrapper [options] input_file [other_input_file [...]]
  39 Options:"""
  40         opts.usage
  41
  42         if opt_help.value then exit 0
  43         exit 1
  44 end
  45
  46 var v = new ObjcVisitor
  47
  48 for src in opts.rest do
  49         # Read input
  50         var content = src.preprocess_content
  51
  52         # Parse
  53         var lexer = new Lexer_objc(content)
  54         var parser = new Parser_objc
  55         var tokens = lexer.lex
  56         parser.tokens.add_all(tokens)
  57         var root = parser.parse
  58
  59         # Check for errors
  60         if root isa NError then
  61                 var pos = root.position
  62                 print_error "Syntax Error: {root.message}, at {pos or else ""}"
  63                 print_error "in {src}"
  64                 if pos != null then
  65                         var lines = content.split("\n")
  66                         for line in [pos.line_start..pos.line_end] do
  67                                 print_error lines[line-1]
  68                         end
  69
  70                         var ptr = " "*(pos.col_start-1).max(0) + "^"*(pos.col_end-pos.col_start)
  71                         print_error ptr
  72                 end
  73                 continue
  74         end
  75
  76         # Run analysis
  77         v.enter_visit root
  78 end
  79
  80 var g = new CodeGenerator(v.model)
  81 g.generate