contrib/nitrpg/src/web.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014-2015 Alexandre Terrasa <alexandre@moz-code.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Display `nitrpg` data as a website.
  18 module web
  19
  20 import nitcorn
  21 import templates
  22
  23 # A custom action forn `nitrpg`.
  24 class RpgAction
  25         super Action
  26
  27         # Root URL is used as a prefix for all URL generated by the actions.
  28         var root_url: String
  29
  30         # Github oauth token used for GithubAPI.
  31         var auth: String is lazy do return get_github_oauth
  32
  33         # API client used to import data from Github.
  34         var api: GithubAPI is lazy do
  35                 var api = new GithubAPI(auth)
  36                 return api
  37         end
  38
  39         init do
  40                 super
  41                 if auth.is_empty then
  42                         print "Error: Invalid Github oauth token!"
  43                         exit 1
  44                 end
  45         end
  46
  47         # Return an Error reponse page.
  48         fun bad_request(msg: String): HttpResponse do
  49                 var rsp = new HttpResponse(400)
  50                 var page = new NitRpgPage(root_url)
  51                 var error = new ErrorPanel(msg)
  52                 page.flow_panels.add error
  53                 rsp.body = page.write_to_string
  54                 return rsp
  55         end
  56
  57         # Returns the game with `name` or null if no game exists with this name.
  58         fun load_game(name: String): nullable Game do
  59                 var repo = new Repo(api, name)
  60                 if api.was_error then return null
  61                 var game = new Game(api, repo)
  62                 game.root_url = root_url
  63                 return game
  64         end
  65
  66         # Returns the list of saved games from NitRPG data.
  67         fun load_games: Array[Game] do
  68                 var res = new Array[Game]
  69                 var rpgdir = "nitrpg_data"
  70                 if not rpgdir.file_exists then return res
  71                 for user in rpgdir.files do
  72                         for repo in "{rpgdir}/{user}".files do
  73                                 var game = load_game("{user}/{repo}")
  74                                 if game != null then res.add game
  75                         end
  76                 end
  77                 return res
  78         end
  79 end
  80
  81 # Repo overview page.
  82 class RpgHome
  83         super RpgAction
  84
  85         # Response page stub.
  86         var page: NitRpgPage is noinit
  87
  88         redef fun answer(request, url) do
  89                 var readme = load_readme
  90                 var games = load_games
  91                 var response = new HttpResponse(200)
  92                 page = new NitRpgPage(root_url)
  93                 page.side_panels.add new GamesShortListPanel(root_url, games)
  94                 page.flow_panels.add new MDPanel(readme)
  95                 response.body = page.write_to_string
  96                 return response
  97         end
  98
  99         # Load the string content of the nitrpg readme file.
 100         private fun load_readme: String do
 101                 var readme = "README.md"
 102                 if not readme.file_exists then
 103                         return "Unable to locate README file."
 104                 end
 105                 var file = new FileReader.open(readme)
 106                 var text = file.read_all
 107                 file.close
 108                 return text
 109         end
 110 end
 111
 112 # Display the list of active game.
 113 class ListGames
 114         super RpgAction
 115
 116         # Response page stub.
 117         var page: NitRpgPage is noinit
 118
 119         redef fun answer(request, url) do
 120                 var games = load_games
 121                 var response = new HttpResponse(200)
 122                 page = new NitRpgPage(root_url)
 123                 page.breadcrumbs = new Breadcrumbs
 124                 page.breadcrumbs.add_link(root_url / "games", "games")
 125                 page.flow_panels.add new GamesListPanel(root_url, games)
 126                 response.body = page.write_to_string
 127                 return response
 128         end
 129 end
 130
 131 # An action that require a game.
 132 class GameAction
 133         super RpgAction
 134
 135         # Response page stub.
 136         var page: NitRpgPage is noinit
 137
 138         # Target game.
 139         var game: Game is noinit
 140
 141         redef fun answer(request, url) is abstract
 142
 143         # Check errors and prepare response.
 144         private fun prepare_response(request: HttpRequest, url: String): HttpResponse do
 145                 var owner = request.param("owner")
 146                 var repo_name = request.param("repo")
 147                 if owner == null or repo_name == null then
 148                         var msg = "Bad request: should look like /games/:owner/:repo."
 149                         return bad_request(msg)
 150                 end
 151                 var game = load_game("{owner}/{repo_name}")
 152                 if game == null then
 153                         var msg = api.last_error.message
 154                         return bad_request("Repo Error: {msg}")
 155                 end
 156                 self.game = game
 157                 var response = new HttpResponse(200)
 158                 page = new NitRpgPage(root_url)
 159                 page.side_panels.add new GameStatusPanel(game)
 160                 page.breadcrumbs = new Breadcrumbs
 161                 page.breadcrumbs.add_link(game.url, game.name)
 162                 prepare_pagination(request)
 163                 return response
 164         end
 165
 166         # Parse pagination related parameters.
 167         private fun prepare_pagination(request: HttpRequest) do
 168                 var args = request.get_args
 169                 list_from = args.get_or_default("pfrom", "0").to_i
 170                 list_limit = args.get_or_default("plimit", "10").to_i
 171         end
 172
 173         # Limit of events to display in lists.
 174         var list_limit = 10
 175
 176         # From where to start the display of events related lists.
 177         var list_from = 0
 178 end
 179
 180 # Repo overview page.
 181 class RepoHome
 182         super GameAction
 183
 184         redef fun answer(request, url) do
 185                 var rsp = prepare_response(request, url)
 186                 page.side_panels.add new ShortListPlayersPanel(game)
 187                 page.flow_panels.add new PodiumPanel(game)
 188                 page.flow_panels.add new EventListPanel(game, list_limit, list_from)
 189                 page.flow_panels.add new AchievementsListPanel(game)
 190                 rsp.body = page.write_to_string
 191                 return rsp
 192         end
 193 end
 194
 195 # Repo players list.
 196 class ListPlayers
 197         super GameAction
 198
 199         redef fun answer(request, url) do
 200                 var rsp = prepare_response(request, url)
 201                 page.breadcrumbs.add_link(game.url / "players", "players")
 202                 page.flow_panels.add new ListPlayersPanel(game)
 203                 rsp.body = page.write_to_string
 204                 return rsp
 205         end
 206 end
 207
 208 # Player details page.
 209 class PlayerHome
 210         super GameAction
 211
 212         redef fun answer(request, url) do
 213                 var rsp = prepare_response(request, url)
 214                 var name = request.param("player")
 215                 if name == null then
 216                         var msg = "Bad request: should look like /:owner/:repo/:players/:name."
 217                         return bad_request(msg)
 218                 end
 219                 var player = game.load_player(name)
 220                 if player == null then
 221                         return bad_request("Request Error: unknown player {name}.")
 222                 end
 223                 page.breadcrumbs.add_link(game.url / "players", "players")
 224                 page.breadcrumbs.add_link(player.url, name)
 225                 page.side_panels.clear
 226                 page.side_panels.add new PlayerStatusPanel(game, player)
 227                 page.flow_panels.add new PlayerReviewsPanel(game, player)
 228                 page.flow_panels.add new AchievementsListPanel(player)
 229                 page.flow_panels.add new EventListPanel(player, list_limit, list_from)
 230                 rsp.body = page.write_to_string
 231                 return rsp
 232         end
 233 end
 234
 235 # Display the list of achievements unlocked for this game.
 236 class ListAchievements
 237         super GameAction
 238
 239         redef fun answer(request, url) do
 240                 var rsp = prepare_response(request, url)
 241                 page.breadcrumbs.add_link(game.url / "achievements", "achievements")
 242                 page.flow_panels.add new AchievementsListPanel(game)
 243                 rsp.body = page.write_to_string
 244                 return rsp
 245         end
 246 end
 247
 248 # Player details page.
 249 class AchievementHome
 250         super GameAction
 251
 252         redef fun answer(request, url) do
 253                 var rsp = prepare_response(request, url)
 254                 var name = request.param("achievement")
 255                 if name == null then
 256                         var msg = "Bad request: should look like /:owner/:repo/achievements/:achievement."
 257                         return bad_request(msg)
 258                 end
 259                 var achievement = game.load_achievement(name)
 260                 if achievement == null then
 261                         return bad_request("Request Error: unknown achievement {name}.")
 262                 end
 263                 page.breadcrumbs.add_link(game.url / "achievements", "achievements")
 264                 page.breadcrumbs.add_link(achievement.url, achievement.name)
 265                 page.flow_panels.add new AchievementPanel(achievement)
 266                 page.flow_panels.add new EventListPanel(achievement, list_limit, list_from)
 267                 rsp.body = page.write_to_string
 268                 return rsp
 269         end
 270 end
 271
 272 if args.length != 3 then
 273         print "Error: missing argument"
 274         print ""
 275         print "Usage:"
 276         print "web <host> <port> <root_url>"
 277         exit 1
 278 end
 279
 280 var host = args[0]
 281 var port = args[1]
 282 var root = args[2]
 283
 284 var iface = "{host}:{port}"
 285 var vh = new VirtualHost(iface)
 286 vh.routes.add new Route("/styles/", new FileServer("www/styles"))
 287 vh.routes.add new Route("/games/:owner/:repo/players/:player", new PlayerHome(root))
 288 vh.routes.add new Route("/games/:owner/:repo/players", new ListPlayers(root))
 289 vh.routes.add new Route("/games/:owner/:repo/achievements/:achievement", new AchievementHome(root))
 290 vh.routes.add new Route("/games/:owner/:repo/achievements", new ListAchievements(root))
 291 vh.routes.add new Route("/games/:owner/:repo", new RepoHome(root))
 292 vh.routes.add new Route("/games", new ListGames(root))
 293 vh.routes.add new Route("/", new RpgHome(root))
 294
 295 var fac = new HttpFactory.and_libevent
 296 fac.config.virtual_hosts.add vh
 297
 298 print "Launching server on http://{iface}/"
 299 fac.run