src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         | '`' [all - '}']
  82         ;
  83 extern_code_body = extern_code_char*;
  84
  85 /*****************************************************************************/
  86 States
  87 /*****************************************************************************/
  88 initial;
  89
  90
  91 /*****************************************************************************/
  92 Tokens
  93 /*****************************************************************************/
  94
  95 blank = (' ' | tab)+;
  96
  97 eol = eol_helper;
  98 comment = '#' any* eol_helper?;
  99
 100 kwpackage = 'package';
 101 kwmodule = 'module';
 102 kwimport = 'import';
 103 kwclass = 'class';
 104 kwabstract = 'abstract';
 105 kwinterface = 'interface';
 106 kwenum = 'universal'|'enum';
 107 kwend = 'end';
 108 kwmeth = 'fun';
 109 kwtype = 'type';
 110 kwinit = 'init';
 111 kwredef = 'redef';
 112 kwis = 'is';
 113 kwdo = 'do';
 114 kwvar = 'var';
 115 kwextern = 'extern';
 116 kwpublic = 'public';
 117 kwprotected = 'protected';
 118 kwprivate = 'private';
 119 kwintrude = 'intrude';
 120 kwif = 'if';
 121 kwthen = 'then';
 122 kwelse = 'else';
 123 kwwhile = 'while';
 124 kwloop = 'loop';
 125 kwfor = 'for';
 126 kwin = 'in';
 127 kwand = 'and';
 128 kwor = 'or';
 129 kwnot = 'not';
 130 kwimplies = 'implies';
 131 kwreturn = 'return';
 132 kwcontinue = 'continue';
 133 kwbreak = 'break';
 134 kwabort = 'abort';
 135 kwassert = 'assert';
 136 kwnew = 'new';
 137 kwisa = 'isa';
 138 kwonce = 'once';
 139 kwsuper = 'super';
 140 kwself = 'self';
 141 kwtrue = 'true';
 142 kwfalse = 'false';
 143 kwnull = 'null';
 144 kwas = 'as';
 145 kwnullable = 'nullable';
 146 kwisset = 'isset';
 147 kwlabel = 'label';
 148 kwdebug = '__debug__';
 149
 150 opar = '(';
 151 cpar = ')';
 152 obra = '[';
 153 cbra = ']';
 154 comma = ',';
 155 column = ':';
 156 quad = '::';
 157 assign = '=';
 158 pluseq = '+=';
 159 minuseq = '-=';
 160 dotdotdot = '...';
 161 dotdot = '..';
 162 dot = '.';
 163 plus = '+';
 164 minus = '-';
 165 star = '*';
 166 starstar = '**';
 167 slash = '/';
 168 percent = '%';
 169 eq = '==';
 170 ne = '!=';
 171 lt = '<';
 172 le = '<=';
 173 ll = '<<';
 174 gt = '>';
 175 ge = '>=';
 176 gg = '>>';
 177 starship = '<=>';
 178 bang='!';
 179 at='@';
 180
 181 classid = uppercase letter*;
 182 id = lowercase letter*;
 183 attrid = '_' lowercase letter*;
 184
 185 number = digit+;
 186 hex_number = ('0x' | '0X') hexdigit+;
 187 float = digit* '.' digit+;
 188 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 189 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 190 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 191 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 192 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 193 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 194 bad_char = ''' '\'? any;
 195
 196 extern_code_segment = '`' '{' extern_code_body '`' '}';
 197
 198 /*****************************************************************************/
 199 Ignored Tokens
 200 /*****************************************************************************/
 201
 202 blank;
 203
 204 /*****************************************************************************/
 205 Productions
 206 /*****************************************************************************/
 207
 208 /* MODULES *******************************************************************/
 209 module
 210         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 211
 212 moduledecl
 213         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 214
 215 import
 216         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 217         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 218         ;
 219
 220 topdef {-> classdef}
 221         = {classdef} classdef {-> classdef}
 222         | propdef_toplevel n1 {-> New classdef.top([propdef_toplevel.propdef])}
 223         ;
 224
 225 implicit_main_class {-> classdef?}
 226         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 227         | {null} n? {-> Null}
 228         ;
 229 implicit_main_meth {-> propdef}
 230         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 231         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 232         ;
 233
 234 /* CLASSES *******************************************************************/
 235 classdef
 236         = [doc]:no redef visibility classkind no qclassid formaldefs extern_code_block? propdefs kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], extern_code_block, [propdefs.propdef], kwend)};
 237 redef {-> kwredef?}
 238         = kwredef? {-> kwredef};
 239 classkind
 240         = {concrete} kwclass
 241         | {abstract} kwabstract kwclass
 242         | {interface} kwinterface
 243         | {enum} kwenum
 244         | {extern} kwextern kwclass
 245         ;
 246
 247 formaldefs {-> formaldef*}
 248         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 249         | {null} {-> []}
 250         ;
 251 formaldefs_tail {-> formaldef}
 252         = comma no formaldef {-> formaldef};
 253 formaldef
 254         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 255
 256 superclass {-> superclass}
 257         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 258         ;
 259
 260 propdefs {-> propdef*}
 261         = propdefn+ no {-> [propdefn.propdef]}
 262         | {empty} no {-> []}
 263         ;
 264 propdefn {-> propdef}
 265         = propdef n1 {-> propdef.propdef}
 266         ;
 267 propdef~toplevel {-> propdef}
 268         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 269         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 270 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 271 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 272         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 273 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations, Null)}
 274 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations, Null)}
 275 !toplevel| {var5} [doc]:no redef visibility kwvar id typing_o annotation_noend? kwdo stmtso kwend? {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_noend.annotations, stmtso.expr)}
 276 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 277 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 278 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 279         ;
 280 annotation_withend~nonull {-> annotations?}
 281         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 282         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 283 !nonull | {null} {-> Null}
 284         ;
 285 annotation_noend {-> annotations}
 286         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 287         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 288         ;
 289
 290 visibility
 291         = {public} {-> New visibility.public(Null)}
 292         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 293         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 294         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 295         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 296         ;
 297
 298 methid~noid {-> methid}
 299         = {plus} plus {-> New methid.plus(plus)}
 300         | {minus} minus {-> New methid.minus(minus)}
 301         | {star} star {-> New methid.star(star)}
 302         | {starstar} starstar {-> New methid.starstar(starstar)}
 303         | {slash} slash {-> New methid.slash(slash)}
 304         | {percent} percent {-> New methid.percent(percent)}
 305         | {eq} eq {-> New methid.eq(eq)}
 306         | {ne} ne {-> New methid.ne(ne)}
 307         | {le} le {-> New methid.le(le)}
 308         | {ge} ge {-> New methid.ge(ge)}
 309         | {lt} lt {-> New methid.lt(lt)}
 310         | {gt} gt {-> New methid.gt(gt)}
 311         | {ll} ll {-> New methid.ll(ll)}
 312         | {gg} gg {-> New methid.gg(gg)}
 313         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 314         | {starship} starship {-> New methid.starship(starship)}
 315         | {assign} id assign {-> New methid.assign(id, assign)}
 316         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 317 !noid   | {id} id {-> New methid.id(id)}
 318         ;
 319
 320 signature {-> signature}
 321         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 322         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 323         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 324         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 325         ;
 326
 327 params {-> param*}
 328         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 329         | {null} {-> []}
 330         ;
 331 params_tail {-> param}
 332         = comma no param {-> param};
 333 param
 334         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 335         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 336         ;
 337
 338 extern_calls {-> extern_calls?}
 339         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 340         | {null} {-> Null}
 341         ;
 342 extern_call_tail {-> extern_call}
 343         = comma no extern_call {-> extern_call};
 344 extern_call {-> extern_call}
 345         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 346         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 347         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 348         ;
 349 extern_call_prop {-> extern_call}
 350         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 351         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 352         | {init} type {-> New extern_call.init_prop( type )}
 353         ;
 354 extern_call_cast {-> extern_call}
 355         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 356         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 357         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 358         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 359         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 360         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 361         ;
 362
 363 string_o {->string?} = string? {-> string};
 364
 365 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 366 extern_code_block = in_language? extern_code_segment;
 367 extern_code_block_o {-> extern_code_block?}
 368         = extern_code_block {-> extern_code_block}
 369         | {null} {-> Null}
 370         ;
 371 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 372
 373 /* TYPES *********************************************************************/
 374 type~nobra~nopar {-> type}
 375         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 376 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 377         ;
 378 types {-> type*}
 379         = type types_tail* {-> [type, types_tail.type]};
 380 types_tail {-> type}
 381         = comma no type {-> type};
 382 typing {-> type}
 383         = column no type {-> type};
 384 typing_o {-> type?}
 385         = column no type {-> type}
 386         | {null} {-> Null}
 387         ;
 388
 389 /* STATMENTS *****************************************************************/
 390 stmtso~withelse~withend {-> expr?}
 391         = {block} n stmtsnend {-> stmtsnend.expr}
 392         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 393         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 394 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 395         ;
 396 stmts {-> expr}
 397         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 398 stmtsn {-> expr}
 399         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 400 stmtsnend {-> expr}
 401         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 402 stmts_tail {-> expr}
 403         = n stmt {-> stmt.expr};
 404 stmt~withelse~noexpr~nopar {-> expr}
 405         = {vardecl} vardecl {-> vardecl.expr}
 406         | {assign} assignment~nopar {-> assignment~nopar.expr}
 407         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 408         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 409         | {abort} kwabort {-> New expr.abort(kwabort)}
 410         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 411         | {do} do~withelse {-> do~withelse.expr}
 412 !noexpr | {if} if~withelse {-> if~withelse.expr}
 413         | {while} while~withelse {-> while~withelse.expr}
 414         | {loop} loop~withelse {-> loop~withelse.expr}
 415         | {for} for~withelse {-> for~withelse.expr}
 416         | {assert} assert~withelse {-> assert~withelse.expr}
 417 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 418 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 419 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 420         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 421         ;
 422
 423 label= kwlabel id?;
 424
 425 vardecl{-> expr}
 426         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 427         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 428         ;
 429
 430 assignment~nopar {-> expr}
 431         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 432         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 433         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 434         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 435         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 436         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 437         ;
 438 assign_op
 439         = {plus} pluseq
 440         | {minus} minuseq
 441         ;
 442
 443 do~withelse {-> expr}
 444         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 445         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 446         ;
 447
 448 if~withelse {-> expr}
 449         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 450 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 451 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 452 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 453         ;
 454 elsepartblock {-> expr?}
 455         = {else} kwelse stmtso {-> stmtso.expr}
 456         | {empty} kwend {-> New expr.block([], kwend)}
 457         ;
 458
 459 loop~withelse {-> expr}
 460         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 461         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 462         ;
 463
 464 while~withelse {-> expr}
 465         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 466         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 467         ;
 468
 469 for~withelse {-> expr}
 470         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 471         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 472         ;
 473
 474 assert~withelse {-> expr}
 475         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 476 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 477         ;
 478 assertid {-> id}
 479         = id column {-> id};
 480
 481 /* EXPRESSIONS ***************************************************************/
 482 expr~nopar~nobra {-> expr}
 483         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 484         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 485         ;
 486
 487 expr_and~nopar~nobra {-> expr}
 488         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 489         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 490         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 491         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 492         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 493         ;
 494
 495 expr_not~nopar~nobra {-> expr}
 496         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 497         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 498         ;
 499
 500 expr_eq~nopar~nobra {-> expr}
 501         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 502         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 503         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 504         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 505         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 506         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 507         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 508         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 509         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 510         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 511         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 512         ;
 513
 514 expr_add~nopar~nobra {-> expr}
 515         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 516         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 517         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 518         ;
 519
 520 expr_mul~nopar~nobra {-> expr}
 521         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 522         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 523         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 524         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 525         ;
 526
 527 expr_pow~nopar~nobra {-> expr}
 528         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 529         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 530         ;
 531
 532 expr_minus~nopar~nobra {-> expr}
 533         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 534         | {:uminus} minus expr_minus~nobra
 535         | {:once} kwonce :no expr_minus~nobra
 536         ;
 537
 538 expr_new~nopar~nobra {-> expr}
 539         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 540         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 541         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 542         ;
 543
 544 expr_atom~nopar~nobra {-> expr}
 545         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 546         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 547         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 548         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 549         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 550 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 551         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 552         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 553         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 554         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 555         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 556         ;
 557
 558 expr_single~nopar~nobra {-> expr}
 559         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 560         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 561         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 562         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 563         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 564         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 565         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 566         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 567         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 568         | {superstring} superstring  {-> superstring.expr}
 569 !nopar  | {par} expr_par {-> expr_par.expr}
 570 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 571 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 572 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 573 !nobra!nopar    | {array} obra no array_items typing_o cbra annotations_o {-> New expr.array(obra, [array_items.expr], typing_o.type, cbra, annotations_o.annotations)}
 574         ;
 575
 576 expr_par {-> expr}
 577         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 578         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 579         ;
 580
 581 many_expr {->expr}
 582         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 583         ;
 584
 585 many_expr_tail {->expr}
 586         = comma no any_expr {-> any_expr.expr}
 587         ;
 588
 589 array_items {-> expr*}
 590         = array_item array_items_tail* {-> [array_item.expr, array_items_tail.expr]}
 591         ;
 592 array_items_tail {-> expr}
 593         = comma no array_item {-> array_item.expr}
 594         ;
 595 array_item {-> expr}
 596         = expr no {-> expr}
 597         | {for} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo [block]:array_item {-> New expr.for(kwfor, [ids.id], expr, kwdo, block.expr, Null)}
 598         | {if} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:array_item {-> New expr.if(kwif, expr, then.expr, Null)}
 599         ;
 600
 601 superstring {-> expr}
 602         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 603 superstring_start {-> expr*}
 604         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 605         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 606         ;
 607 start_string_p {-> expr}
 608         = start_string {-> New expr.start_string(start_string)};
 609 superstring_middle {-> expr*}
 610         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 611         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 612         ;
 613 mid_string_p {-> expr}
 614         = mid_string {-> New expr.mid_string(mid_string)};
 615 superstring_end {-> expr}
 616         = end_string {-> New expr.end_string(end_string)};
 617
 618 /* ANNOTATIONS *******************************************************************/
 619
 620 annotations~nopar {-> annotations}
 621         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 622         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 623         ;
 624 annotations_o~nopar {-> annotations?}
 625         = annotations~nopar {-> annotations~nopar.annotations}
 626         | {null} {-> Null}
 627         ;
 628
 629 one_annotation~nopar {-> annotation}
 630         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 631 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 632 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 633         ;
 634
 635 many_annotations {-> annotations}
 636         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 637         ;
 638
 639 annotation_list {-> annotation*}
 640         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 641         ;
 642
 643 one_annotation_list~nopar {-> annotation}
 644         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 645 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 646 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 647 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 648         ;
 649 at_arg_single {-> expr}
 650 // FIXME: why expr_single but not expr_atom is not clear :(
 651         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 652         ;
 653
 654 annotations_tail {-> annotation}
 655         = comma no one_annotation_list {-> one_annotation_list.annotation}
 656         ;
 657
 658 line_annotations {-> annotations}
 659         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 660         ;
 661 line_annotation {-> annotation}
 662         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 663         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 664         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 665         ;
 666 line_annotations_forclass {-> annotations}
 667         = line_annotation_forclass+ {-> New annotations(Null, Null, [line_annotation_forclass.annotation], Null) }
 668         ;
 669 line_annotation_forclass {-> annotation}
 670         = [doc]:no atid_forclass annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 671         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 672         | {nopar} [doc]:no atid_forclass at_args_nopar n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 673         ;
 674
 675 at_args~nopar {-> expr* }
 676         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 677         ;
 678
 679 at_args_tail {-> expr}
 680         = comma no any_expr {-> any_expr.expr}
 681         ;
 682
 683 any_expr~nopar {-> expr}
 684         = {type} type {-> New expr.type(type)}
 685         | {expr} expr~nopar {-> expr~nopar.expr}
 686         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 687         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 688 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 689         ;
 690
 691 atid~forclass {-> atid}
 692         = {id}  id {-> New atid.id(id)}
 693 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 694 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 695         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 696         ;
 697
 698 /* MISC **********************************************************************/
 699
 700 recv~nopar~nobra {-> expr}
 701         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 702         | {implicit} {-> New expr.implicit_self()}
 703         ;
 704
 705 args {-> exprs}
 706         = args_n {-> args_n.exprs}
 707         | {empty} {-> New exprs.list([])}
 708         ;
 709 args_n {-> exprs}
 710         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 711         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 712         ;
 713 args_nopar {-> exprs}
 714         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 715         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 716         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 717         | {empty} {-> New exprs.list([])}
 718         ;
 719 braargs {-> exprs}
 720         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 721 args_list {-> exprs}
 722         = expr_list {-> New exprs.list([expr_list.expr])};
 723 expr_list {-> expr*}
 724         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 725 expr_tail {-> expr}
 726         = comma no expr [n2]:no {-> expr};
 727 idlist {-> id*}
 728         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 729         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 730         ;
 731 idlist_nopar {-> id*}
 732         = {single} id {-> [id]}
 733         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 734         ;
 735
 736 module_name {-> module_name}
 737         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 738         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 739         ;
 740
 741 qualified
 742         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 743         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 744         ;
 745 qualified_o {-> qualified?}
 746         = qualified {-> qualified}
 747         | {null} {-> Null}
 748         ;
 749 qid {-> id}
 750         = qualified? id {-> id}
 751         ;
 752 qclassid {-> classid}
 753         = qualified? classid {-> classid}
 754         ;
 755 qmethid~noid {-> methid}
 756         = qualified? methid~noid {-> methid~noid.methid}
 757         ;
 758 modquad {-> id}
 759         = id quad no {-> id};
 760 classquad {-> classid}
 761         = classid quad no {-> classid};
 762
 763 kwend_o {-> kwend?}
 764         = kwend? {-> kwend}
 765         ;
 766
 767 n1      = {a} comment | {b} eol;
 768 n {-> doc?}
 769         = {a} n2? comment+ {-> New doc([comment])}
 770         | {b} n2 {-> Null}
 771         ;
 772 no {-> doc?}
 773         = {empty} {-> Null}
 774         | n {-> n.doc}
 775         ;
 776
 777 n2
 778         = {a} n2? comment+ eol+
 779         | {b} eol+
 780         ;
 781
 782 /*****************************************************************************/
 783 Abstract Syntax Tree
 784 /*****************************************************************************/
 785
 786 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 787
 788 moduledecl
 789         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 790
 791 import  = {std} visibility kwimport [name]:module_name annotations?
 792         | {no} visibility kwimport kwend
 793         ;
 794
 795 visibility
 796         = {public} kwpublic?
 797         | {private} kwprivate
 798         | {protected} kwprotected
 799         | {intrude} kwintrude
 800         ;
 801
 802 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* extern_code_block? [propdefs]:propdef* kwend
 803         | {top} [propdefs]:propdef*
 804         | {main} [propdefs]:propdef*
 805         ;
 806 classkind
 807         = {concrete} kwclass
 808         | {abstract} kwabstract kwclass
 809         | {interface} kwinterface
 810         | {enum} kwenum
 811         | {extern} kwextern kwclass?
 812         ;
 813 formaldef = [id]:classid type? annotations?;
 814 superclass = kwsuper type annotations?;
 815
 816
 817 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations? [block]:expr?
 818         | {main_meth} kwredef? [block]:expr?
 819         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 820         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 821         ;
 822
 823 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 824
 825 signature = opar? [params]:param* cpar? type?;
 826
 827 param   = id type? dotdotdot? annotations?
 828         ;
 829
 830 type    = kwnullable? [id]:classid [types]:type* annotations?;
 831
 832 label = kwlabel id?;
 833
 834 expr    = {block} expr* kwend?
 835         | {vardecl} kwvar id type? assign? expr? annotations?
 836         | {return} kwreturn? expr?
 837         | {break} kwbreak label?
 838         | {abort} kwabort
 839         | {continue} kwcontinue? label?
 840         | {do} kwdo [block]:expr? label?
 841         | {if} kwif expr [then]:expr? [else]:expr?
 842         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 843         | {while} kwwhile expr kwdo [block]:expr? label?
 844         | {loop} kwloop [block]:expr? label?
 845         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 846         | {assert} kwassert id? expr [else]:expr?
 847         | {once} kwonce expr
 848         | {send} expr
 849         | {binop} expr [expr2]:expr
 850         | {or} expr [expr2]:expr
 851         | {and} expr [expr2]:expr
 852         | {or_else} expr [expr2]:expr
 853         | {implies} expr [expr2]:expr
 854         | {not} kwnot expr
 855         | {eq} expr [expr2]:expr
 856         | {ne} expr [expr2]:expr
 857         | {lt} expr [expr2]:expr
 858         | {le} expr [expr2]:expr
 859         | {ll} expr [expr2]:expr
 860         | {gt} expr [expr2]:expr
 861         | {ge} expr [expr2]:expr
 862         | {gg} expr [expr2]:expr
 863         | {isa} expr type
 864         | {plus} expr [expr2]:expr
 865         | {minus} expr [expr2]:expr
 866         | {starship} expr [expr2]:expr
 867         | {star} expr [expr2]:expr
 868         | {starstar} expr [expr2]:expr
 869         | {slash} expr [expr2]:expr
 870         | {percent} expr [expr2]:expr
 871         | {uminus} minus expr
 872         | {new} kwnew type id? [args]:exprs
 873         | {attr} expr [id]:attrid
 874         | {attr_assign} expr [id]:attrid assign [value]:expr
 875         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 876         | {call} expr id [args]:exprs
 877         | {call_assign} expr id [args]:exprs assign [value]:expr
 878         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 879         | {super} qualified? kwsuper [args]:exprs
 880         | {init} expr kwinit [args]:exprs
 881         | {bra} expr [args]:exprs
 882         | {bra_assign} expr [args]:exprs assign [value]:expr
 883         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 884         | {var} id
 885         | {var_assign} id assign [value]:expr
 886         | {var_reassign} id assign_op [value]:expr
 887         | {range} expr [expr2]:expr annotations?
 888         | {crange} obra expr [expr2]:expr cbra annotations?
 889         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 890         | {array} obra [exprs]:expr* type? cbra annotations?
 891         | {self} kwself annotations?
 892         | {implicit_self}
 893         | {true} kwtrue annotations?
 894         | {false} kwfalse annotations?
 895         | {null} kwnull annotations?
 896         | {dec_int} number annotations?
 897         | {hex_int} hex_number annotations?
 898         | {float} float annotations?
 899         | {char} char annotations?
 900         | {string} string annotations?
 901         | {start_string} [string]:start_string
 902         | {mid_string} [string]:mid_string
 903         | {end_string} [string]:end_string
 904         | {superstring} [exprs]:expr* annotations?
 905         | {par} opar expr cpar annotations?
 906         | {as_cast} expr kwas opar? type cpar?
 907         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 908         | {isset_attr} kwisset expr [id]:attrid
 909         | {debug_type} kwdebug kwtype expr type
 910         | {vararg} expr dotdotdot
 911         | {type} type
 912         | {methid} expr [id]:methid
 913         | {at} annotations
 914         | {many} [exprs]:expr*
 915         ;
 916 exprs
 917         = {list} [exprs]:expr*
 918         | {par} opar [exprs]:expr* cpar
 919         | {bra} obra [exprs]:expr* cbra
 920         ;
 921 assign_op
 922         = {plus} pluseq
 923         | {minus} minuseq
 924         ;
 925
 926 module_name = quad? [path]:id* id;
 927 extern_calls = kwimport [extern_calls]:extern_call*
 928         ;
 929 extern_call =
 930         | {super} kwsuper
 931         | {local_prop} methid
 932         | {full_prop} type dot? methid
 933         | {init_prop} type
 934         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 935         | {as_nullable} type kwas kwnullable
 936         | {as_not_nullable} type kwas kwnot kwnullable
 937         ;
 938 in_language = kwin string;
 939 extern_code_block = in_language? extern_code_segment;
 940
 941 qualified = id* classid? ;
 942
 943 doc = comment+;
 944
 945 annotations = at? opar? [items]:annotation* cpar?;
 946
 947 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 948
 949 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 950
 951 /*****************************************************************************/
 952