nitlanguage / nit.git / blob
? search:


847280ba31939697574f68b9fd43aac408e18658
[nit.git] / src / compiling / compiling_icode.nit
1 # This file is part of NIT ( http://www.nitlanguage.org ).
2 #
3 # Copyright 2009 Jean Privat <jean@pryen.org>
4 #
5 # Licensed under the Apache License, Version 2.0 (the "License");
6 # you may not use this file except in compliance with the License.
7 # You may obtain a copy of the License at
8 #
9 # http://www.apache.org/licenses/LICENSE-2.0
10 #
11 # Unless required by applicable law or agreed to in writing, software
12 # distributed under the License is distributed on an "AS IS" BASIS,
13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14 # See the License for the specific language governing permissions and
15 # limitations under the License.
16
17 # Generate C code from intermediate code representation
18 package compiling_icode
19
20 import icode
21 private import analysis
22 import compiling_base
23
24 # Compiler context from ICode to C
25 class I2CCompilerVisitor
26 # Associate things
27 var _ids: HashMap[Object, String] = new HashMap[Object, String]
28 # Associate other things
29 var _ids2: HashMap[Object, String] = new HashMap[Object, String]
30
31 # Return the string associated with a register
32 fun register(e: IRegister): String
33 do
34 if e.stype isa MMTypeNone then return "NIT_NULL"
35 var ids = _ids
36 if closure and not e.is_local then ids = _ids2
37 if ids.has_key(e) then
38 return ids[e]
39 else
40 var i = e.slot_index
41 if i == null then
42 # The register is dead
43 var s = "NIT_NULL"
44 ids[e] = s
45 return s
46 else
47 var s: String
48 var strs: HashMap[Int, String]
49 if e.in_tag_slots then
50 strs = once new HashMap[Int, String]
51 if not strs.has_key(i) then strs[i] = "REGB{i}"
52 else if closure and not e.is_local then
53 strs = once new HashMap[Int, String]
54 if not strs.has_key(i) then strs[i] = "closctx->variable[{i}]"
55 else
56 strs = once new HashMap[Int, String]
57 if not strs.has_key(i) then strs[i] = "REG[{i}]"
58 end
59 s = strs[i]
60 ids[e] = s
61 return s
62 end
63 end
64 end
65
66 # Return the strings associated with registers
67 fun registers(a: Collection[IRegister]): Array[String]
68 do
69 var r = new Array[String].with_capacity(a.length)
70 for e in a do
71 r.add(register(e))
72 end
73 return r
74 end
75
76 var _last_number: Int = 0
77 # Give a new unique number (unique for the visitor)
78 fun new_number: Int
79 do
80 _last_number += 1
81 return _last_number
82 end
83
84 # Return the string associated with a escape label
85 fun lab(e: ISeq): String
86 do
87 if _ids.has_key(e) then
88 return _ids[e]
89 else
90 var s = "label{new_number}"
91 _ids[e] = s
92 return s
93 end
94 end
95
96 # The rank (number) of each closure
97 readable var _closures: HashMap[IClosureDecl, Int] = new HashMap[IClosureDecl, Int]
98
99 # The functionnal type of each closure
100 readable var _clostypes: HashMap[IClosureDecl, String] = new HashMap[IClosureDecl, String]
101
102 # label locally accessibles
103 readable writable var _local_labels: HashSet[ISeq] = new HashSet[ISeq]
104
105 # Not local escaped labels
106 # The integer value is an index identifying the label
107 readable writable var _escaped_labels: HashMap[ISeq, Int] = new HashMap[ISeq, Int]
108
109 # Register a escape to a non local label and return an index identifying the label
110 fun register_escape_label(e: ISeq): Int
111 do
112 if _escaped_labels.has_key(e) then
113 return _escaped_labels[e]
114 else
115 var res = _escaped_labels.length + 1
116 _escaped_labels[e] = res
117 return res
118 end
119 end
120
121 # Add a C label mark (if needed)
122 fun add_label(e: ISeq)
123 do
124 if _ids.has_key(e) then
125 add_instr("{_ids[e]}: while(0);")
126 end
127 end
128
129 # Add a goto to a label (even outside a closure)
130 fun add_goto(seq: ISeq)
131 do
132 if local_labels.has(seq) then
133 add_instr("goto {lab(seq)};")
134 else
135 assert closure
136 var ind = register_escape_label(seq)
137 add_instr("closctx->has_broke = (val_t*){ind};")
138 add_instr("goto {lab(return_label.as(not null))};")
139 end
140 end
141
142 # Are we in a closure ?
143 readable writable var _closure: Bool = false
144
145 # The current compiler visitor
146 readable var _visitor: CompilerVisitor
147
148 # The current compiled iroutine
149 readable var _iroutine: IRoutine
150
151 # The return label of the current compiling C function
152 readable writable var _return_label: nullable ISeq = null
153
154 fun add_decl(s: String)
155 do
156 visitor.add_decl(s)
157 end
158
159 fun add_instr(s: String)
160 do
161 var l = _next_location
162 if l != null then
163 visitor.add_instr("/* ", l.file, ":", l.line_start.to_s, " */")
164 _next_location = null
165 end
166 visitor.add_instr(s)
167 end
168
169 fun indent
170 do
171 visitor.indent
172 end
173
174 fun unindent
175 do
176 visitor.unindent
177 end
178
179 fun add_assignment(to, from: String)
180 do
181 visitor.add_assignment(to, from)
182 end
183
184 var _last_location: nullable Location = null
185 var _next_location: nullable Location = null
186
187 # Add location information in a comment
188 # Do nothing if the last location added is the same
189 fun add_location(l: nullable Location)
190 do
191 var last = _last_location
192 if last == l or l == null then return
193 _last_location = l
194 if last != null and last.file == l.file and last.line_start == l.line_start then
195 return
196 else
197 _next_location = l
198 end
199 end
200
201 # The C fonction name of the iroutine
202 readable var _basecname: String
203
204 init(v: CompilerVisitor, ir: IRoutine, cname: String)
205 do
206 _visitor = v
207 _iroutine = ir
208 _basecname = cname
209 end
210 end
211
212 redef class IRoutine
213 # Declare and start a C function that match the routine
214 # Return what must be given to compile_inside_to_c or to compile_to_c
215 # After the method, an openinig { and and indent is added.
216 # So, do not forget to add a sub_context, to unintent and to add a closing }
217 fun compile_signature_to_c(v: CompilerVisitor, cname: String, human_name: nullable String, before_params, after_params: nullable String): Array[String]
218 do
219 var cargs = new Array[String]
220 var cparams = new Array[String]
221 if before_params != null then cparams.add(before_params)
222 for i in [0..params.length[ do
223 cargs.add("p{i}")
224 cparams.add("val_t p{i}")
225 end
226 if closure_decls != null then
227 for i in [0..closure_decls.length[ do
228 var closcn = "CLOS_{cname}_{i}"
229 var cs = closure_decls[i].closure.signature
230 var subparams = new Array[String] # Parameters of the closure
231 subparams.add("struct WBT_ *")
232 for j in [0..cs.arity[ do
233 subparams.add("val_t")
234 end
235 var rr = "void"
236 if cs.return_type != null then rr = "val_t"
237 v.add_decl("typedef {rr} (*{closcn})({subparams.join(", ")});")
238 cargs.add("wd{i}")
239 cparams.add("struct WBT_ *wd{i}")
240 end
241 end
242 if after_params != null then cparams.add(after_params)
243 var r = "void"
244 if result != null then r = "val_t"
245 var p: String
246 if cparams.is_empty then
247 p = "void"
248 else
249 p = cparams.join(", ")
250 end
251 if human_name != null then v.add_decl("#define LOCATE_", cname, " \"", human_name, "\"")
252 v.add_decl(r, " ", cname, "(", p, ");")
253 v.add_decl("typedef ", r, " (*", cname, "_t)(", p, ");")
254 v.add_instr(r, " ", cname, "(", p, ")\{")
255 v.indent
256 return cargs
257 end
258
259 # Compile the body of the routine, return the result value is any
260 fun compile_inside_to_c(v: I2CCompilerVisitor, args: Array[String]): nullable String
261 do
262 # Add the trace
263 var ll = 0
264 if location != null then
265 ll = location.line_start
266 end
267 v.add_decl("struct trace_t trace = \{NULL, NULL, {ll}, LOCATE_{v.basecname}\};")
268 v.add_instr("trace.prev = tracehead; tracehead = &trace;")
269 v.add_instr("trace.file = LOCATE_{v.visitor.module.name};")
270
271 # Add local variables
272 if std_slots_nb == 0 then
273 v.add_decl("val_t *REG = NULL;")
274 else
275 v.add_decl("val_t REG[{std_slots_nb}];")
276 end
277 for i in [0..tag_slots_nb[ do
278 v.add_decl("val_t REGB{i};")
279 end
280 var iclosdecls = closure_decls
281 if iclosdecls != null then
282 v.add_decl("struct WBT_ *CREG[{iclosdecls.length}];")
283 else
284 v.add_decl("struct WBT_ **CREG = NULL;")
285 end
286 var i = 0
287 for r in params do
288 if r.slot_index != null then v.add_assignment(v.register(r), args[i])
289 i += 1
290 end
291 var iclosdecls = closure_decls
292 if iclosdecls != null then
293 for i in [0..iclosdecls.length[ do
294 var iclosdecl = iclosdecls[i]
295 v.add_instr("CREG[{i}] = {args[params.length+i]};")
296 v.closures[iclosdecl] = i
297 var cs = iclosdecl.closure.signature # Closure signature
298 var subparams = new Array[String] # Parameters of the closure
299 subparams.add("struct WBT_ *")
300 for j in [0..cs.arity[ do
301 var p = "val_t"
302 subparams.add(p)
303 end
304 var r = "void"
305 if cs.return_type != null then r = "val_t"
306 v.clostypes[iclosdecl] = "{r} (*)({subparams.join(", ")})"
307 end
308 end
309 v.add_decl("val_t tmp;")
310
311 # Prepare return
312 var old_rl = v.return_label
313 v.return_label = body
314
315 # Compile body
316 body.compile_to_c(v)
317
318 v.add_instr("tracehead = trace.prev;")
319 v.return_label = old_rl
320 var r = result
321 if r != null then
322 return v.register(r)
323 else
324 return null
325 end
326 end
327
328 # Full compilation of the routine
329 # Including optimization and other stuff.
330 # cv must be in the correct function
331 fun compile_to_c(cv: CompilerVisitor, cname: String, args: Array[String]): nullable String
332 do
333 optimize
334 var v = new I2CCompilerVisitor(cv, self, cname)
335 return compile_inside_to_c(v, args)
336 end
337 end
338
339 redef class ICode
340 # Full compilation of the icode
341 fun compile_to_c(v: I2CCompilerVisitor)
342 do
343 v.add_location(location)
344 store_result(v, inner_compile_to_c(v))
345 end
346
347 # Is a result really needed
348 private fun need_result: Bool
349 do
350 var r = result
351 return r != null and r.slot_index != null
352 end
353
354 # Store s in the result value of self
355 private fun store_result(v: I2CCompilerVisitor, s: nullable String)
356 do
357 var r = result
358 if r != null and r.slot_index != null then
359 assert s != null
360 v.add_assignment(v.register(r), s)
361 else if s != null and not self isa IMove then
362 v.add_instr(s + ";")
363 end
364 end
365
366 # Compilation of without the result assigment
367 # Return the right value is case of expression
368 # Return the full expression (witout ;) in case of statement
369 private fun inner_compile_to_c(v: I2CCompilerVisitor): nullable String is abstract
370 end
371
372 redef class ISeq
373 redef fun inner_compile_to_c(v)
374 do
375 v.local_labels.add(self)
376 for ic in icodes do
377 ic.compile_to_c(v)
378 end
379 v.add_label(self)
380 return null
381 end
382 end
383
384 redef class IIf
385 redef fun inner_compile_to_c(v)
386 do
387 v.add_instr("if (UNTAG_Bool({v.register(expr)})) \{")
388 if not then_seq.icodes.is_empty then
389 v.indent
390 then_seq.inner_compile_to_c(v)
391 v.unindent
392 end
393 if not else_seq.icodes.is_empty then
394 v.add_instr("} else \{")
395 v.indent
396 else_seq.inner_compile_to_c(v)
397 v.unindent
398 end
399 v.add_instr("}")
400 return null
401 end
402 end
403
404 redef class ILoop
405 redef fun inner_compile_to_c(v)
406 do
407 v.local_labels.add(self)
408 v.add_instr("while(1) \{")
409 v.indent
410 for ic in icodes do
411 ic.compile_to_c(v)
412 end
413 v.unindent
414 v.add_instr("}")
415 v.add_label(self)
416 return null
417 end
418 end
419
420 redef class IEscape
421 redef fun inner_compile_to_c(v)
422 do
423 v.add_goto(seq)
424 return null
425 end
426 end
427
428 redef class IAbsCall
429 redef fun compile_to_c(v)
430 do
431 v.add_location(location)
432 var args = v.registers(exprs)
433
434 # Compile closure definitions
435 var old_el = v.escaped_labels
436 var closdefs = closure_defs
437 var closcns: nullable Array[String] = null
438 if closdefs != null then
439 v.escaped_labels = new HashMap[ISeq, Int]
440 closcns = new Array[String]
441 for cd in closdefs do
442 if cd != null then
443 var cn = cd.compile_closure(v)
444 args.add(cn)
445 closcns.add(cn)
446 else
447 args.add("NULL")
448 end
449 end
450 end
451
452 var s = compile_call_to_c(v, args)
453 var r: nullable String = s
454
455 # Intercept escapes
456 if closcns != null then
457 var els = v.escaped_labels
458 v.escaped_labels = old_el
459 # Is there possible escapes?
460 if not els.is_empty then
461 # Call in a tmp variable to avoid 'break' overwrite
462 if need_result then
463 r = "tmp"
464 v.add_assignment(r, s)
465 else
466 r = null
467 v.add_instr(s + ";")
468 end
469 # What is the escape index (if any?)
470 # It's computed as the union of has_broke
471 var switcha = new Array[String]
472 for cn in closcns do
473 switcha.add("((int)({cn}->has_broke))")
474 end
475 var switch = switcha.join(" | ")
476 # What are the expected escape indexes
477 v.add_instr("switch ({switch}) \{")
478 v.indent
479 # No escape occured, continue as usual
480 v.add_instr("case 0: break;")
481 var lls = v.local_labels
482 var iels = els.iterator
483 var forward_escape = false
484 while iels.is_ok do
485 var seq = iels.key
486 if lls.has(seq) then
487 # Local escape occured
488 v.add_instr("case {iels.item}: goto {v.lab(seq)};")
489 else
490 # Forward escape occured: register the escape label
491 assert v.closure
492 v.register_escape_label(seq)
493 forward_escape = true
494 end
495 iels.next
496 end
497 # Forward escape occured, just pass to the next one
498 if forward_escape then
499 v.add_instr("default: closctx->has_broke = (val_t*)({switch}); goto {v.lab(v.return_label.as(not null))};")
500 end
501 v.unindent
502 v.add_instr("\}")
503 end
504 end
505
506 store_result(v, r)
507 end
508
509 redef fun inner_compile_to_c(v) do abort
510
511 # The single invocation witout fancy stuffs
512 private fun compile_call_to_c(v: I2CCompilerVisitor, args: Array[String]): String is abstract
513 end
514
515 redef class ICall
516 redef fun compile_call_to_c(v, args)
517 do
518 var prop = property
519 if prop.global.is_init then args.add("init_table")
520 if prop.name == (once ("add".to_symbol)) and prop.local_class.name == (once ("Array".to_symbol)) then
521 return "{prop.cname}({args.join(", ")})"
522 else
523 return "{prop.global.meth_call}({args[0]})({args.join(", ")})"
524 end
525 end
526 end
527
528 redef class ISuper
529 redef fun compile_call_to_c(v, args)
530 do
531 var prop = property
532 if prop.global.is_init then args.add("init_table")
533 return "{prop.super_meth_call}({args[0]})({args.join(", ")})"
534 end
535 end
536
537 redef class INew
538 redef fun compile_call_to_c(v, args)
539 do
540 return "NEW_{stype.local_class}_{property.global.intro.cname}({args.join(", ")})"
541 end
542 end
543
544 redef class INative
545 redef fun inner_compile_to_c(v)
546 do
547 if exprs.is_empty then
548 return code
549 else
550 var res = new Buffer
551 var i = 0
552 var c = code.split_with("@@@")
553 for s in c do
554 res.append(s)
555 if i < exprs.length and i < c.length-1 then
556 res.append(v.register(exprs[i]))
557 end
558 i += 1
559 end
560 return res.to_s
561 end
562 end
563 end
564
565 redef class IAbort
566 redef fun inner_compile_to_c(v)
567 do
568 var s = new Buffer.from("fprintf(stderr")
569 for t in texts do
570 s.append(", \"{t}\"")
571 end
572 s.append(");")
573 v.add_instr(s.to_s)
574
575 var ll = location
576 var pl = property_location
577 s = new Buffer.from("fprintf(stderr, \"")
578 if pl != null then s.append(" in %s")
579 s.append(" (%s")
580 if ll != null then
581 s.append(":%d")
582 end
583 s.append(")\\n\", ")
584 if pl != null then s.append("LOCATE_{pl.cname}, ")
585 s.append("LOCATE_{module_location.name}")
586 if ll != null then
587 s.append(", {ll.line_start}")
588 end
589 s.append(");")
590 v.add_instr(s.to_s)
591
592 v.add_instr("nit_exit(1);")
593 return null
594 end
595 end
596
597 redef class IMove
598 redef fun inner_compile_to_c(v)
599 do
600 return v.register(expr)
601 end
602 end
603
604 redef class IAttrRead
605 redef fun inner_compile_to_c(v)
606 do
607 return "{property.global.attr_access}({v.register(expr)})"
608 end
609 end
610
611 redef class IAttrIsset
612 redef fun inner_compile_to_c(v)
613 do
614 return "TAG_Bool({property.global.attr_access}({v.register(expr)})!=NIT_NULL)"
615 end
616 end
617
618 redef class IAttrWrite
619 redef fun inner_compile_to_c(v)
620 do
621 v.add_instr("{property.global.attr_access}({v.register(expr1)}) = {v.register(expr2)};")
622 return null
623 end
624 end
625
626 redef class ITypeCheck
627 redef fun inner_compile_to_c(v)
628 do
629 # FIXME handle formaltypes
630 var g = stype.local_class.global
631 var recv = v.register(expr)
632 var s = ""
633 if expr.stype.is_nullable then
634 if stype.is_nullable then
635 s = "({recv}==NIT_NULL) || "
636 else if stype.as_nullable == expr.stype then
637 return "TAG_Bool({recv}!=NIT_NULL)"
638 else
639 s = "({recv}!=NIT_NULL) && "
640 end
641 end
642 return "TAG_Bool({s}VAL_ISA({recv}, {g.color_id}, {g.id_id})) /*cast {stype}*/"
643 end
644 end
645
646 redef class IIs
647 redef fun inner_compile_to_c(v)
648 do
649 var t1 = expr1.stype
650 var t2 = expr2.stype
651 if t1 isa MMTypeNone then
652 if t2 isa MMTypeNone then
653 return "TAG_Bool(1)"
654 else if t2.is_nullable then
655 return "TAG_Bool({v.register(expr2)}==NIT_NULL)"
656 else
657 return "TAG_Bool(0)"
658 end
659 else if t1.is_nullable then
660 if t2 isa MMTypeNone then
661 return "TAG_Bool({v.register(expr1)}==NIT_NULL)"
662 else if t2.is_nullable then
663 return "TAG_Bool(IS_EQUAL_NN({v.register(expr1)},{v.register(expr2)}))"
664 else
665 return "TAG_Bool(IS_EQUAL_ON({v.register(expr2)},{v.register(expr1)}))"
666 end
667 else
668 if t2 isa MMTypeNone then
669 return "TAG_Bool(0)"
670 else if t2.is_nullable then
671 return "TAG_Bool(IS_EQUAL_ON({v.register(expr1)},{v.register(expr2)}))"
672 else
673 return "TAG_Bool(IS_EQUAL_OO({v.register(expr1)},{v.register(expr2)}))"
674 end
675 end
676 end
677 end
678
679 redef class INot
680 redef fun inner_compile_to_c(v)
681 do
682 return "TAG_Bool(!UNTAG_Bool({v.register(expr)}))"
683 end
684 end
685
686 redef class IOnce
687 redef fun inner_compile_to_c(v)
688 do
689 var i = v.new_number
690 var res = result.as(not null)
691 if res.stype.is_nullable then
692 v.add_decl("static val_t once_value_{i}; static int once_bool_{i}; /* Once value */")
693 v.add_instr("if (!once_bool_{i}) \{")
694 else
695 # Since the value is not nullable, we use the null value to represent the boolean
696 v.add_decl("static val_t once_value_{i}; /* Once value */")
697 v.add_instr("if (!once_value_{i}) \{")
698 end
699 v.indent
700 body.compile_to_c(v)
701 var e = v.register(result.as(not null))
702 v.add_instr("once_value_{i} = {e};")
703 if res.stype.is_nullable then v.add_instr("once_bool_{i} = true;")
704 v.unindent
705 v.add_instr("} else {e} = once_value_{i};")
706 return e
707 end
708 end
709
710 redef class IClosCall
711 redef fun compile_to_c(v: I2CCompilerVisitor)
712 do
713 v.add_location(location)
714 var ivar: String
715 if v.closure then
716 ivar = "closctx->closurevariable[{v.closures[closure_decl]}]"
717 else
718 ivar = "CREG[{v.closures[closure_decl]}]"
719 end
720 var args = [ivar]
721 args.append(v.registers(exprs))
722
723 var s = "(({v.clostypes[closure_decl]})({ivar}->fun))({args.join(", ")})"
724 store_result(v, s)
725
726 v.add_instr("if ({ivar}->has_broke) \{")
727 v.indent
728 var bs = break_seq
729 if bs != null then
730 bs.compile_to_c(v)
731 end
732 v.add_goto(v.iroutine.body)
733 v.unindent
734 v.add_instr("\}")
735 end
736
737 redef fun inner_compile_to_c(v) do abort
738 end
739
740 redef class IHasClos
741 redef fun inner_compile_to_c(v)
742 do
743 var ivar: String
744 if v.closure then
745 ivar = "closctx->closurevariable[{v.closures[closure_decl]}]"
746 else
747 ivar = "CREG[{v.closures[closure_decl]}]"
748 end
749 return "TAG_Bool({ivar} != NULL)"
750 end
751 end
752
753
754 redef class IClosureDef
755 fun compile_closure(v: I2CCompilerVisitor): String
756 do
757 var cfc_old = v.closure
758 v.closure = true
759 var lls_old = v.local_labels
760 v.local_labels = new HashSet[ISeq]
761
762 var cv = v.visitor
763 var ctx_old = cv.ctx
764 cv.ctx = new CContext
765 cv.out_contexts.add(cv.ctx)
766
767 var cname = "OC_{v.basecname}_{v.new_number}"
768 var args = compile_signature_to_c(v.visitor, cname, null, "struct WBT_ *closctx", null)
769 var ctx_old2 = cv.ctx
770 cv.ctx = new CContext
771
772 var s = compile_inside_to_c(v, args)
773 if s == null then
774 v.add_instr("return;")
775 else
776 v.add_instr("return {s};")
777 end
778
779 ctx_old2.append(cv.ctx)
780 cv.ctx = ctx_old2
781 v.unindent
782 v.add_instr("}")
783 cv.ctx = ctx_old
784
785 v.closure = cfc_old
786
787 # Build closure
788 var closcnv = "wbclos{v.new_number}"
789 v.add_decl("struct WBT_ {closcnv};")
790 v.add_instr("{closcnv}.fun = (fun_t){cname};")
791 v.add_instr("{closcnv}.has_broke = NULL;")
792 if cfc_old then
793 v.add_instr("{closcnv}.variable = closctx->variable;")
794 v.add_instr("{closcnv}.closurevariable = closctx->closurevariable;")
795 else
796 v.add_instr("{closcnv}.variable = REG;")
797 v.add_instr("{closcnv}.closurevariable = CREG;")
798 end
799
800 v.local_labels = lls_old
801 return "(&{closcnv})"
802 end
803 end
Nit language project; an oo programing language and its tool suite.