lib/android/input_events.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Copyright 2012-2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Pointer and hardware key events
  18 module input_events
  19
  20 import mnit::input
  21 import android::game
  22
  23 in "C header" `{
  24         #include <android/log.h>
  25         #include <android_native_app_glue.h>
  26
  27         #define LOGW(...) ((void)__android_log_print(ANDROID_LOG_WARN, "mnit", __VA_ARGS__))
  28         #ifdef DEBUG
  29                 #define LOGI(...) ((void)__android_log_print(ANDROID_LOG_INFO, "mnit", __VA_ARGS__))
  30         #else
  31                 #define LOGI(...) (void)0
  32         #endif
  33 `}
  34
  35 in "C" `{
  36         /* Handle inputs from the Android platform and sort them before
  37            sending them in the Nit App */
  38         static int32_t mnit_handle_input(struct android_app* app, AInputEvent* event) {
  39                 App nit_app = app->userData;
  40                 LOGI("handle input %i", (int)pthread_self());
  41                 if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_KEY) {
  42                         LOGI("key");
  43                         return App_native_input_key(nit_app, event);
  44                 }
  45                 else if (AInputEvent_getType(event) == AINPUT_EVENT_TYPE_MOTION) {
  46                         LOGI("motion");
  47                         return App_native_input_motion(nit_app, event);
  48                 }
  49
  50                 return 0;
  51         }
  52 `}
  53
  54 private extern class NativeAndroidMotionEvent `{AInputEvent *`}
  55
  56         fun pointers_count: Int `{
  57                 return AMotionEvent_getPointerCount(self);
  58         `}
  59
  60         fun edge: Int `{
  61                 return AMotionEvent_getEdgeFlags(self);
  62         `}
  63
  64         # Get the non-primary pointer id that just went down (returns -1 or > 0)
  65         fun index_down_pointer: Int `{
  66                 int a = AMotionEvent_getAction(self);
  67                 if ((a & AMOTION_EVENT_ACTION_MASK) == AMOTION_EVENT_ACTION_POINTER_DOWN)
  68                         return (a & AMOTION_EVENT_ACTION_POINTER_INDEX_MASK) >> AMOTION_EVENT_ACTION_POINTER_INDEX_SHIFT;
  69                 else return -1;
  70         `}
  71
  72         fun action: AMotionEventAction `{ return AMotionEvent_getAction(self); `}
  73 end
  74
  75 private extern class AMotionEventAction `{ int32_t `}
  76         fun action: Int `{ return self & AMOTION_EVENT_ACTION_MASK; `}
  77
  78         # Pointer index concerned by this action
  79         #
  80         # Require: `is_pointer_down or is_pointer_up`
  81         fun pointer_index: Int `{
  82                 return (self & AMOTION_EVENT_ACTION_POINTER_INDEX_MASK) >> AMOTION_EVENT_ACTION_POINTER_INDEX_SHIFT;
  83         `}
  84
  85         fun is_down: Bool do return action == 0
  86         fun is_up: Bool do return action == 1
  87         fun is_move: Bool do return action == 2
  88         fun is_cancel: Bool do return action == 3
  89         fun is_outside: Bool do return action == 4
  90         fun is_pointer_down: Bool do return action == 5
  91         fun is_pointer_up: Bool do return action == 6
  92 end
  93
  94 # An input event on Android
  95 interface AndroidInputEvent
  96         super InputEvent
  97 end
  98
  99 # A motion event concerning a single or more `pointers`
 100 class AndroidMotionEvent
 101         super AndroidInputEvent
 102         super MotionEvent
 103
 104         private var native: NativeAndroidMotionEvent
 105
 106         # Pointers (or fingers) composing this motion event
 107         var pointers: Array[AndroidPointerEvent] is lazy do
 108                 return [for i in native.pointers_count.times do new AndroidPointerEvent(self, i)]
 109         end
 110
 111         # The pointer (or finger) causing this event
 112         var acting_pointer: AndroidPointerEvent is lazy do
 113                 var action = native.action
 114                 var index = 0
 115
 116                 if action.is_pointer_down or action.is_pointer_up then
 117                         index = native.action.pointer_index
 118                 end
 119
 120                 return new AndroidPointerEvent(self, index)
 121         end
 122
 123         redef fun just_went_down do return native.action.is_down or native.action.is_pointer_down
 124
 125         # Was the top edge of the screen intersected by this event?
 126         fun touch_to_edge: Bool do return native.edge == 1
 127
 128         # Was the bottom edge of the screen intersected by this event?
 129         fun touch_bottom_edge: Bool do return native.edge == 2
 130
 131         # Was the left edge of the screen intersected by this event?
 132         fun touch_left_edge: Bool do return native.edge == 4
 133
 134         # Was the right edge of the screen intersected by this event?
 135         fun touch_right_edge: Bool do return native.edge == 8
 136
 137         redef fun down_pointer: nullable AndroidPointerEvent
 138         do
 139                 if just_went_down then
 140                         # The primary pointer went down
 141                         return pointers[0]
 142                 end
 143
 144                 var i = native.index_down_pointer
 145                 if i > 0 then
 146                         # A secondary pointer went down
 147                         return pointers[i]
 148                 else
 149                         return null
 150                 end
 151         end
 152 end
 153
 154 # A pointer event
 155 class AndroidPointerEvent
 156         super PointerEvent
 157         super AndroidInputEvent
 158
 159         private var motion_event: AndroidMotionEvent
 160
 161         private var pointer_index: Int
 162
 163         redef fun x do return native_x(motion_event.native, pointer_index)
 164
 165         private fun native_x(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 166                 return AMotionEvent_getX(motion_event, pointer_index);
 167         `}
 168
 169         redef fun y do return native_y(motion_event.native, pointer_index)
 170
 171         private fun native_y(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 172                 return AMotionEvent_getY(motion_event, pointer_index);
 173         `}
 174
 175         # Pressure applied by this pointer
 176         fun pressure: Float do return native_pressure(motion_event.native, pointer_index)
 177
 178         private fun native_pressure(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Float `{
 179                 return AMotionEvent_getPressure(motion_event, pointer_index);
 180         `}
 181
 182         redef fun pressed
 183         do
 184                 var action = motion_event.native.action
 185                 return action.is_down or action.is_move or action.is_pointer_down
 186         end
 187
 188         redef fun is_move do return motion_event.acting_pointer == self and
 189                 motion_event.native.action.is_move
 190
 191         # Does this pointer just began touching the screen?
 192         fun just_went_down: Bool do return motion_event.acting_pointer == self and
 193                 motion_event.just_went_down
 194
 195         # Unique id of this pointer since the beginning of the gesture
 196         fun pointer_id: Int do return native_pointer_id(motion_event.native, pointer_index)
 197
 198         private fun native_pointer_id(motion_event: NativeAndroidMotionEvent, pointer_index: Int): Int `{
 199                 return AMotionEvent_getPointerId(motion_event, pointer_index);
 200         `}
 201 end
 202
 203 # An hardware key event
 204 extern class AndroidKeyEvent `{AInputEvent *`}
 205         super KeyEvent
 206         super AndroidInputEvent
 207
 208         private fun action: Int `{ return AKeyEvent_getAction(self); `}
 209
 210         redef fun is_down do return action == 0
 211         redef fun is_up do return action == 1
 212
 213         # Hardware code of the key raising this event
 214         fun key_code: Int `{ return AKeyEvent_getKeyCode(self); `}
 215
 216         redef fun to_c
 217         do
 218                 var i = native_to_c
 219                 if i == 0 then return null
 220                 return i.code_point
 221         end
 222
 223         private fun native_to_c: Int `{
 224                 int code = AKeyEvent_getKeyCode(self);
 225                 if (code >= AKEYCODE_0 && code <= AKEYCODE_9)
 226                         return '0'+code-AKEYCODE_0;
 227                 if (code >= AKEYCODE_A && code <= AKEYCODE_Z)
 228                         return 'a'+code-AKEYCODE_A;
 229                 return 0;
 230         `}
 231
 232         redef fun name do return key_code.to_s
 233
 234         # Was this event raised by the back key?
 235         fun is_back_key: Bool do return key_code == 4
 236
 237         # Was this event raised by the menu key?
 238         fun is_menu_key: Bool do return key_code == 82
 239
 240         # Was this event raised by the search key?
 241         fun is_search_key: Bool do return key_code == 84
 242
 243         # Was this event raised by the volume up key?
 244         fun is_volume_up: Bool do return key_code == 24
 245
 246         # Was this event raised by the volume down key?
 247         fun is_volume_down: Bool do return key_code == 25
 248 end
 249
 250 redef class App
 251
 252         redef fun init_window
 253         do
 254                 set_as_input_handler native_app_glue
 255                 super
 256         end
 257
 258         private fun set_as_input_handler(app_glue: NativeAppGlue)
 259         import native_input_key, native_input_motion `{
 260                 app_glue->onInputEvent = mnit_handle_input;
 261         `}
 262
 263         # these are used as a callback from native to type incoming events
 264         private fun native_input_key(event: AndroidKeyEvent): Bool is abstract
 265
 266         private fun native_input_motion(event: NativeAndroidMotionEvent): Bool is abstract
 267 end