src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         | '`' [all - '}']
  82         ;
  83 extern_code_body = extern_code_char*;
  84
  85 /*****************************************************************************/
  86 States
  87 /*****************************************************************************/
  88 initial;
  89
  90
  91 /*****************************************************************************/
  92 Tokens
  93 /*****************************************************************************/
  94
  95 blank = (' ' | tab)+;
  96
  97 eol = eol_helper;
  98 comment = '#' any* eol_helper?;
  99
 100 kwpackage = 'package';
 101 kwmodule = 'module';
 102 kwimport = 'import';
 103 kwclass = 'class';
 104 kwabstract = 'abstract';
 105 kwinterface = 'interface';
 106 kwenum = 'universal'|'enum';
 107 kwend = 'end';
 108 kwmeth = 'fun';
 109 kwtype = 'type';
 110 kwinit = 'init';
 111 kwredef = 'redef';
 112 kwis = 'is';
 113 kwdo = 'do';
 114 kwvar = 'var';
 115 kwextern = 'extern';
 116 kwpublic = 'public';
 117 kwprotected = 'protected';
 118 kwprivate = 'private';
 119 kwintrude = 'intrude';
 120 kwif = 'if';
 121 kwthen = 'then';
 122 kwelse = 'else';
 123 kwwhile = 'while';
 124 kwloop = 'loop';
 125 kwfor = 'for';
 126 kwin = 'in';
 127 kwand = 'and';
 128 kwor = 'or';
 129 kwnot = 'not';
 130 kwimplies = 'implies';
 131 kwreturn = 'return';
 132 kwcontinue = 'continue';
 133 kwbreak = 'break';
 134 kwabort = 'abort';
 135 kwassert = 'assert';
 136 kwnew = 'new';
 137 kwisa = 'isa';
 138 kwonce = 'once';
 139 kwsuper = 'super';
 140 kwself = 'self';
 141 kwtrue = 'true';
 142 kwfalse = 'false';
 143 kwnull = 'null';
 144 kwas = 'as';
 145 kwnullable = 'nullable';
 146 kwisset = 'isset';
 147 kwlabel = 'label';
 148 kwdebug = '__debug__';
 149
 150 opar = '(';
 151 cpar = ')';
 152 obra = '[';
 153 cbra = ']';
 154 comma = ',';
 155 column = ':';
 156 quad = '::';
 157 assign = '=';
 158 pluseq = '+=';
 159 minuseq = '-=';
 160 dotdotdot = '...';
 161 dotdot = '..';
 162 dot = '.';
 163 plus = '+';
 164 minus = '-';
 165 star = '*';
 166 starstar = '**';
 167 slash = '/';
 168 percent = '%';
 169 eq = '==';
 170 ne = '!=';
 171 lt = '<';
 172 le = '<=';
 173 ll = '<<';
 174 gt = '>';
 175 ge = '>=';
 176 gg = '>>';
 177 starship = '<=>';
 178 bang='!';
 179 at='@';
 180
 181 classid = uppercase letter*;
 182 id = lowercase letter*;
 183 attrid = '_' lowercase letter*;
 184
 185 number = digit+;
 186 hex_number = ('0x' | '0X') hexdigit+;
 187 float = digit* '.' digit+;
 188 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 189 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 190 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 191 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 192 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 193 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 194 bad_char = ''' '\'? any;
 195
 196 extern_code_segment = '`' '{' extern_code_body '`' '}';
 197
 198 /*****************************************************************************/
 199 Ignored Tokens
 200 /*****************************************************************************/
 201
 202 blank;
 203
 204 /*****************************************************************************/
 205 Productions
 206 /*****************************************************************************/
 207
 208 /* MODULES *******************************************************************/
 209 module
 210         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 211
 212 moduledecl
 213         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 214
 215 import
 216         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 217         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 218         ;
 219
 220 topdef {-> classdef}
 221         = {classdef} classdef {-> classdef}
 222         | propdef_toplevel n1 {-> New classdef.top([propdef_toplevel.propdef])}
 223         ;
 224
 225 implicit_main_class {-> classdef?}
 226         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 227         | {null} n? {-> Null}
 228         ;
 229 implicit_main_meth {-> propdef}
 230         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 231         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 232         ;
 233
 234 /* CLASSES *******************************************************************/
 235 classdef
 236         = [doc]:no redef visibility classkind no qclassid formaldefs extern_code_block? propdefs kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], extern_code_block, [propdefs.propdef], kwend)};
 237 redef {-> kwredef?}
 238         = kwredef? {-> kwredef};
 239 classkind
 240         = {concrete} kwclass
 241         | {abstract} kwabstract kwclass
 242         | {interface} kwinterface
 243         | {enum} kwenum
 244         | {extern} kwextern kwclass
 245         ;
 246
 247 formaldefs {-> formaldef*}
 248         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 249         | {null} {-> []}
 250         ;
 251 formaldefs_tail {-> formaldef}
 252         = comma no formaldef {-> formaldef};
 253 formaldef
 254         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 255
 256 superclass {-> propdef}
 257         = {super} [doc]:no redef visibility kwsuper [n2]:no type annotation_withend {-> New propdef.super(doc.doc, redef.kwredef, visibility, kwsuper, type, annotation_withend.annotations)}
 258         ;
 259
 260 propdefs {-> propdef*}
 261         = propdefn+ no {-> [propdefn.propdef]}
 262         | {super} superclass {-> [superclass.propdef]}
 263         | {empty} no {-> []}
 264         ;
 265 propdefn {-> propdef}
 266         = propdef n1 {-> propdef.propdef}
 267         ;
 268 propdef~toplevel {-> propdef}
 269         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 270         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 271 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 272 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 273         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 274 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations, Null)}
 275 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations, Null)}
 276 !toplevel| {var5} [doc]:no redef visibility kwvar id typing_o annotation_noend? kwdo stmtso kwend? {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_noend.annotations, stmtso.expr)}
 277 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 278 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 279 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 280 !toplevel| {super} superclass {-> superclass.propdef}
 281         ;
 282 annotation_withend~nonull {-> annotations?}
 283         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 284         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 285 !nonull | {null} {-> Null}
 286         ;
 287 annotation_noend {-> annotations}
 288         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 289         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 290         ;
 291
 292 visibility
 293         = {public} {-> New visibility.public(Null)}
 294         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 295         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 296         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 297         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 298         ;
 299
 300 methid~noid {-> methid}
 301         = {plus} plus {-> New methid.plus(plus)}
 302         | {minus} minus {-> New methid.minus(minus)}
 303         | {star} star {-> New methid.star(star)}
 304         | {starstar} starstar {-> New methid.starstar(starstar)}
 305         | {slash} slash {-> New methid.slash(slash)}
 306         | {percent} percent {-> New methid.percent(percent)}
 307         | {eq} eq {-> New methid.eq(eq)}
 308         | {ne} ne {-> New methid.ne(ne)}
 309         | {le} le {-> New methid.le(le)}
 310         | {ge} ge {-> New methid.ge(ge)}
 311         | {lt} lt {-> New methid.lt(lt)}
 312         | {gt} gt {-> New methid.gt(gt)}
 313         | {ll} ll {-> New methid.ll(ll)}
 314         | {gg} gg {-> New methid.gg(gg)}
 315         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 316         | {starship} starship {-> New methid.starship(starship)}
 317         | {assign} id assign {-> New methid.assign(id, assign)}
 318         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 319 !noid   | {id} id {-> New methid.id(id)}
 320         ;
 321
 322 signature {-> signature}
 323         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 324         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 325         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 326         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 327         ;
 328
 329 params {-> param*}
 330         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 331         | {null} {-> []}
 332         ;
 333 params_tail {-> param}
 334         = comma no param {-> param};
 335 param
 336         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 337         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 338         ;
 339
 340 extern_calls {-> extern_calls?}
 341         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 342         | {null} {-> Null}
 343         ;
 344 extern_call_tail {-> extern_call}
 345         = comma no extern_call {-> extern_call};
 346 extern_call {-> extern_call}
 347         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 348         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 349         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 350         ;
 351 extern_call_prop {-> extern_call}
 352         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 353         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 354         | {init} type {-> New extern_call.init_prop( type )}
 355         ;
 356 extern_call_cast {-> extern_call}
 357         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 358         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 359         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 360         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 361         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 362         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 363         ;
 364
 365 string_o {->string?} = string? {-> string};
 366
 367 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 368 extern_code_block = in_language? extern_code_segment;
 369 extern_code_block_o {-> extern_code_block?}
 370         = extern_code_block {-> extern_code_block}
 371         | {null} {-> Null}
 372         ;
 373 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 374
 375 /* TYPES *********************************************************************/
 376 type~nobra~nopar {-> type}
 377         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 378 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 379         ;
 380 types {-> type*}
 381         = type types_tail* {-> [type, types_tail.type]};
 382 types_tail {-> type}
 383         = comma no type {-> type};
 384 typing {-> type}
 385         = column no type {-> type};
 386 typing_o {-> type?}
 387         = column no type {-> type}
 388         | {null} {-> Null}
 389         ;
 390
 391 /* STATMENTS *****************************************************************/
 392 stmtso~withelse~withend {-> expr?}
 393         = {block} n stmtsnend {-> stmtsnend.expr}
 394         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 395         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 396 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 397         ;
 398 stmts {-> expr}
 399         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 400 stmtsn {-> expr}
 401         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 402 stmtsnend {-> expr}
 403         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 404 stmts_tail {-> expr}
 405         = n stmt {-> stmt.expr};
 406 stmt~withelse~noexpr~nopar {-> expr}
 407         = {vardecl} vardecl {-> vardecl.expr}
 408         | {assign} assignment~nopar {-> assignment~nopar.expr}
 409         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 410         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 411         | {abort} kwabort {-> New expr.abort(kwabort)}
 412         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 413         | {do} do~withelse {-> do~withelse.expr}
 414 !noexpr | {if} if~withelse {-> if~withelse.expr}
 415         | {while} while~withelse {-> while~withelse.expr}
 416         | {loop} loop~withelse {-> loop~withelse.expr}
 417         | {for} for~withelse {-> for~withelse.expr}
 418         | {assert} assert~withelse {-> assert~withelse.expr}
 419 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 420 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 421 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 422         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 423         ;
 424
 425 label= kwlabel id?;
 426
 427 vardecl{-> expr}
 428         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 429         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 430         ;
 431
 432 assignment~nopar {-> expr}
 433         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 434         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 435         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 436         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 437         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 438         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 439         ;
 440 assign_op
 441         = {plus} pluseq
 442         | {minus} minuseq
 443         ;
 444
 445 do~withelse {-> expr}
 446         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 447         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 448         ;
 449
 450 if~withelse {-> expr}
 451         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 452 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 453 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 454 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 455         ;
 456 elsepartblock {-> expr?}
 457         = {else} kwelse stmtso {-> stmtso.expr}
 458         | {empty} kwend {-> New expr.block([], kwend)}
 459         ;
 460
 461 loop~withelse {-> expr}
 462         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 463         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 464         ;
 465
 466 while~withelse {-> expr}
 467         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 468         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 469         ;
 470
 471 for~withelse {-> expr}
 472         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 473         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 474         ;
 475
 476 assert~withelse {-> expr}
 477         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 478 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 479         ;
 480 assertid {-> id}
 481         = id column {-> id};
 482
 483 /* EXPRESSIONS ***************************************************************/
 484 expr~nopar~nobra {-> expr}
 485         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 486         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 487         ;
 488
 489 expr_and~nopar~nobra {-> expr}
 490         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 491         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 492         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 493         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 494         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 495         ;
 496
 497 expr_not~nopar~nobra {-> expr}
 498         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 499         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 500         ;
 501
 502 expr_eq~nopar~nobra {-> expr}
 503         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 504         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 505         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 506         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 507         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 508         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 509         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 510         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 511         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 512         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 513         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 514         ;
 515
 516 expr_add~nopar~nobra {-> expr}
 517         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 518         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 519         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 520         ;
 521
 522 expr_mul~nopar~nobra {-> expr}
 523         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 524         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 525         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 526         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 527         ;
 528
 529 expr_pow~nopar~nobra {-> expr}
 530         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 531         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 532         ;
 533
 534 expr_minus~nopar~nobra {-> expr}
 535         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 536         | {:uminus} minus expr_minus~nobra
 537         | {:once} kwonce :no expr_minus~nobra
 538         ;
 539
 540 expr_new~nopar~nobra {-> expr}
 541         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 542         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 543         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 544         ;
 545
 546 expr_atom~nopar~nobra {-> expr}
 547         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 548         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 549         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 550         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 551         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 552 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 553         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 554         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 555         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 556         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 557         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 558         ;
 559
 560 expr_single~nopar~nobra {-> expr}
 561         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 562         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 563         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 564         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 565         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 566         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 567         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 568         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 569         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 570         | {superstring} superstring  {-> superstring.expr}
 571 !nopar  | {par} expr_par {-> expr_par.expr}
 572 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 573 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 574 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 575 !nobra!nopar    | {array} obra no array_items typing_o cbra annotations_o {-> New expr.array(obra, [array_items.expr], typing_o.type, cbra, annotations_o.annotations)}
 576         ;
 577
 578 expr_par {-> expr}
 579         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 580         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 581         ;
 582
 583 many_expr {->expr}
 584         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 585         ;
 586
 587 many_expr_tail {->expr}
 588         = comma no any_expr {-> any_expr.expr}
 589         ;
 590
 591 array_items {-> expr*}
 592         = array_item array_items_tail* {-> [array_item.expr, array_items_tail.expr]}
 593         ;
 594 array_items_tail {-> expr}
 595         = comma no array_item {-> array_item.expr}
 596         ;
 597 array_item {-> expr}
 598         = expr no {-> expr}
 599         | {for} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo [block]:array_item {-> New expr.for(kwfor, [ids.id], expr, kwdo, block.expr, Null)}
 600         | {if} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:array_item {-> New expr.if(kwif, expr, then.expr, Null)}
 601         ;
 602
 603 superstring {-> expr}
 604         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 605 superstring_start {-> expr*}
 606         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 607         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 608         ;
 609 start_string_p {-> expr}
 610         = start_string {-> New expr.start_string(start_string)};
 611 superstring_middle {-> expr*}
 612         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 613         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 614         ;
 615 mid_string_p {-> expr}
 616         = mid_string {-> New expr.mid_string(mid_string)};
 617 superstring_end {-> expr}
 618         = end_string {-> New expr.end_string(end_string)};
 619
 620 /* ANNOTATIONS *******************************************************************/
 621
 622 annotations~nopar {-> annotations}
 623         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 624         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 625         ;
 626 annotations_o~nopar {-> annotations?}
 627         = annotations~nopar {-> annotations~nopar.annotations}
 628         | {null} {-> Null}
 629         ;
 630
 631 one_annotation~nopar {-> annotation}
 632         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 633 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 634 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 635         ;
 636
 637 many_annotations {-> annotations}
 638         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 639         ;
 640
 641 annotation_list {-> annotation*}
 642         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 643         ;
 644
 645 one_annotation_list~nopar {-> annotation}
 646         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 647 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 648 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 649 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 650         ;
 651 at_arg_single {-> expr}
 652 // FIXME: why expr_single but not expr_atom is not clear :(
 653         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 654         ;
 655
 656 annotations_tail {-> annotation}
 657         = comma no one_annotation_list {-> one_annotation_list.annotation}
 658         ;
 659
 660 line_annotations {-> annotations}
 661         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 662         ;
 663 line_annotation {-> annotation}
 664         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 665         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 666         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 667         ;
 668 line_annotations_forclass {-> annotations}
 669         = line_annotation_forclass+ {-> New annotations(Null, Null, [line_annotation_forclass.annotation], Null) }
 670         ;
 671 line_annotation_forclass {-> annotation}
 672         = [doc]:no atid_forclass annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 673         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 674         | {nopar} [doc]:no atid_forclass at_args_nopar n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 675         ;
 676
 677 at_args~nopar {-> expr* }
 678         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 679         ;
 680
 681 at_args_tail {-> expr}
 682         = comma no any_expr {-> any_expr.expr}
 683         ;
 684
 685 any_expr~nopar {-> expr}
 686         = {type} type {-> New expr.type(type)}
 687         | {expr} expr~nopar {-> expr~nopar.expr}
 688         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 689         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 690 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 691         ;
 692
 693 atid~forclass {-> atid}
 694         = {id}  id {-> New atid.id(id)}
 695 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 696 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 697         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 698         ;
 699
 700 /* MISC **********************************************************************/
 701
 702 recv~nopar~nobra {-> expr}
 703         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 704         | {implicit} {-> New expr.implicit_self()}
 705         ;
 706
 707 args {-> exprs}
 708         = args_n {-> args_n.exprs}
 709         | {empty} {-> New exprs.list([])}
 710         ;
 711 args_n {-> exprs}
 712         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 713         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 714         ;
 715 args_nopar {-> exprs}
 716         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 717         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 718         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 719         | {empty} {-> New exprs.list([])}
 720         ;
 721 braargs {-> exprs}
 722         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 723 args_list {-> exprs}
 724         = expr_list {-> New exprs.list([expr_list.expr])};
 725 expr_list {-> expr*}
 726         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 727 expr_tail {-> expr}
 728         = comma no expr [n2]:no {-> expr};
 729 idlist {-> id*}
 730         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 731         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 732         ;
 733 idlist_nopar {-> id*}
 734         = {single} id {-> [id]}
 735         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 736         ;
 737
 738 module_name {-> module_name}
 739         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 740         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 741         ;
 742
 743 qualified
 744         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 745         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 746         ;
 747 qualified_o {-> qualified?}
 748         = qualified {-> qualified}
 749         | {null} {-> Null}
 750         ;
 751 qid {-> id}
 752         = qualified? id {-> id}
 753         ;
 754 qclassid {-> classid}
 755         = qualified? classid {-> classid}
 756         ;
 757 qmethid~noid {-> methid}
 758         = qualified? methid~noid {-> methid~noid.methid}
 759         ;
 760 modquad {-> id}
 761         = id quad no {-> id};
 762 classquad {-> classid}
 763         = classid quad no {-> classid};
 764
 765 kwend_o {-> kwend?}
 766         = kwend? {-> kwend}
 767         ;
 768
 769 n1      = {a} comment | {b} eol;
 770 n {-> doc?}
 771         = {a} n2? comment+ {-> New doc([comment])}
 772         | {b} n2 {-> Null}
 773         ;
 774 no {-> doc?}
 775         = {empty} {-> Null}
 776         | n {-> n.doc}
 777         ;
 778
 779 n2
 780         = {a} n2? comment+ eol+
 781         | {b} eol+
 782         ;
 783
 784 /*****************************************************************************/
 785 Abstract Syntax Tree
 786 /*****************************************************************************/
 787
 788 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 789
 790 moduledecl
 791         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 792
 793 import  = {std} visibility kwimport [name]:module_name annotations?
 794         | {no} visibility kwimport kwend
 795         ;
 796
 797 visibility
 798         = {public} kwpublic?
 799         | {private} kwprivate
 800         | {protected} kwprotected
 801         | {intrude} kwintrude
 802         ;
 803
 804 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* extern_code_block? [propdefs]:propdef* kwend
 805         | {top} [propdefs]:propdef*
 806         | {main} [propdefs]:propdef*
 807         ;
 808 classkind
 809         = {concrete} kwclass
 810         | {abstract} kwabstract kwclass
 811         | {interface} kwinterface
 812         | {enum} kwenum
 813         | {extern} kwextern kwclass?
 814         ;
 815 formaldef = [id]:classid type? annotations?;
 816
 817
 818 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations? [block]:expr?
 819         | {main_meth} kwredef? [block]:expr?
 820         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 821         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 822         | {super} doc? kwredef? visibility kwsuper type annotations?
 823         ;
 824
 825 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 826
 827 signature = opar? [params]:param* cpar? type?;
 828
 829 param   = id type? dotdotdot? annotations?
 830         ;
 831
 832 type    = kwnullable? [id]:classid [types]:type* annotations?;
 833
 834 label = kwlabel id?;
 835
 836 expr    = {block} expr* kwend?
 837         | {vardecl} kwvar id type? assign? expr? annotations?
 838         | {return} kwreturn? expr?
 839         | {break} kwbreak label?
 840         | {abort} kwabort
 841         | {continue} kwcontinue? label?
 842         | {do} kwdo [block]:expr? label?
 843         | {if} kwif expr [then]:expr? [else]:expr?
 844         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 845         | {while} kwwhile expr kwdo [block]:expr? label?
 846         | {loop} kwloop [block]:expr? label?
 847         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 848         | {assert} kwassert id? expr [else]:expr?
 849         | {once} kwonce expr
 850         | {send} expr
 851         | {binop} expr [expr2]:expr
 852         | {or} expr [expr2]:expr
 853         | {and} expr [expr2]:expr
 854         | {or_else} expr [expr2]:expr
 855         | {implies} expr [expr2]:expr
 856         | {not} kwnot expr
 857         | {eq} expr [expr2]:expr
 858         | {ne} expr [expr2]:expr
 859         | {lt} expr [expr2]:expr
 860         | {le} expr [expr2]:expr
 861         | {ll} expr [expr2]:expr
 862         | {gt} expr [expr2]:expr
 863         | {ge} expr [expr2]:expr
 864         | {gg} expr [expr2]:expr
 865         | {isa} expr type
 866         | {plus} expr [expr2]:expr
 867         | {minus} expr [expr2]:expr
 868         | {starship} expr [expr2]:expr
 869         | {star} expr [expr2]:expr
 870         | {starstar} expr [expr2]:expr
 871         | {slash} expr [expr2]:expr
 872         | {percent} expr [expr2]:expr
 873         | {uminus} minus expr
 874         | {new} kwnew type id? [args]:exprs
 875         | {attr} expr [id]:attrid
 876         | {attr_assign} expr [id]:attrid assign [value]:expr
 877         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 878         | {call} expr id [args]:exprs
 879         | {call_assign} expr id [args]:exprs assign [value]:expr
 880         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 881         | {super} qualified? kwsuper [args]:exprs
 882         | {init} expr kwinit [args]:exprs
 883         | {bra} expr [args]:exprs
 884         | {bra_assign} expr [args]:exprs assign [value]:expr
 885         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 886         | {var} id
 887         | {var_assign} id assign [value]:expr
 888         | {var_reassign} id assign_op [value]:expr
 889         | {range} expr [expr2]:expr annotations?
 890         | {crange} obra expr [expr2]:expr cbra annotations?
 891         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 892         | {array} obra [exprs]:expr* type? cbra annotations?
 893         | {self} kwself annotations?
 894         | {implicit_self}
 895         | {true} kwtrue annotations?
 896         | {false} kwfalse annotations?
 897         | {null} kwnull annotations?
 898         | {dec_int} number annotations?
 899         | {hex_int} hex_number annotations?
 900         | {float} float annotations?
 901         | {char} char annotations?
 902         | {string} string annotations?
 903         | {start_string} [string]:start_string
 904         | {mid_string} [string]:mid_string
 905         | {end_string} [string]:end_string
 906         | {superstring} [exprs]:expr* annotations?
 907         | {par} opar expr cpar annotations?
 908         | {as_cast} expr kwas opar? type cpar?
 909         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 910         | {isset_attr} kwisset expr [id]:attrid
 911         | {debug_type} kwdebug kwtype expr type
 912         | {vararg} expr dotdotdot
 913         | {type} type
 914         | {methid} expr [id]:methid
 915         | {at} annotations
 916         | {many} [exprs]:expr*
 917         ;
 918 exprs
 919         = {list} [exprs]:expr*
 920         | {par} opar [exprs]:expr* cpar
 921         | {bra} obra [exprs]:expr* cbra
 922         ;
 923 assign_op
 924         = {plus} pluseq
 925         | {minus} minuseq
 926         ;
 927
 928 module_name = quad? [path]:id* id;
 929 extern_calls = kwimport [extern_calls]:extern_call*
 930         ;
 931 extern_call =
 932         | {super} kwsuper
 933         | {local_prop} methid
 934         | {full_prop} type dot? methid
 935         | {init_prop} type
 936         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 937         | {as_nullable} type kwas kwnullable
 938         | {as_not_nullable} type kwas kwnot kwnullable
 939         ;
 940 in_language = kwin string;
 941 extern_code_block = in_language? extern_code_segment;
 942
 943 qualified = id* classid? ;
 944
 945 doc = comment+;
 946
 947 annotations = at? opar? [items]:annotation* cpar?;
 948
 949 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 950
 951 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 952
 953 /*****************************************************************************/
 954