lib/standard/bytes.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Services for byte streams and arrays
  16 module bytes
  17
  18 import kernel
  19 import collection::array
  20 intrude import text::flat
  21
  22 # A buffer containing Byte-manipulation facilities
  23 #
  24 # Uses Copy-On-Write when persisted
  25 class Bytes
  26         super AbstractArray[Byte]
  27
  28         # A NativeString being a char*, it can be used as underlying representation here.
  29         private var items: NativeString
  30
  31         # Number of bytes in the array
  32         redef var length
  33
  34         # Capacity of the array
  35         private var capacity: Int
  36
  37         # Has this buffer been persisted (to_s'd)?
  38         #
  39         # Used for Copy-On-Write
  40         private var persisted = false
  41
  42         #     var b = new Bytes.empty
  43         #     assert b.to_s == ""
  44         init empty do
  45                 var ns = new NativeString(0)
  46                 init(ns, 0, 0)
  47         end
  48
  49         # Init a `Bytes` with capacity `cap`
  50         init with_capacity(cap: Int) do
  51                 var ns = new NativeString(cap)
  52                 init(ns, 0, cap)
  53         end
  54
  55         redef fun is_empty do return length != 0
  56
  57         #     var b = new Bytes.empty
  58         #     b.add 101u8
  59         #     assert b[0] == 101u8
  60         redef fun [](i) do
  61                 assert i >= 0
  62                 assert i < length
  63                 return items[i]
  64         end
  65
  66         #     var b = new Bytes.with_capacity(1)
  67         #     b[0] = 101u8
  68         #     assert b.to_s == "e"
  69         redef fun []=(i, v) do
  70                 if persisted then regen
  71                 assert i >= 0
  72                 assert i <= length
  73                 if i == length then add(v)
  74                 items[i] = v
  75         end
  76
  77         #     var b = new Bytes.empty
  78         #     b.add 101u8
  79         #     assert b.to_s == "e"
  80         redef fun add(c) do
  81                 if persisted then regen
  82                 if length >= capacity then
  83                         enlarge(length)
  84                 end
  85                 items[length] = c
  86                 length += 1
  87         end
  88
  89         #     var b = new Bytes.empty
  90         #     b.append([104u8, 101u8, 108u8, 108u8, 111u8])
  91         #     assert b.to_s == "hello"
  92         redef fun append(arr) do
  93                 if arr isa Bytes then
  94                         append_ns(arr.items, arr.length)
  95                 else
  96                         for i in arr do add i
  97                 end
  98         end
  99
 100         #     var b = new Bytes.empty
 101         #     b.append([0x41u8, 0x41u8, 0x18u8])
 102         #     b.pop
 103         #     assert b.to_s == "AA"
 104         redef fun pop do
 105                 assert length >= 1
 106                 length -= 1
 107                 return items[length]
 108         end
 109
 110         redef fun clear do length = 0
 111
 112         # Regenerates the buffer, necessary when it was persisted
 113         private fun regen do
 114                 var nns = new NativeString(capacity)
 115                 items.copy_to(nns, length, 0, 0)
 116                 persisted = false
 117         end
 118
 119         # Appends the `ln` first bytes of `ns` to self
 120         fun append_ns(ns: NativeString, ln: Int) do
 121                 if persisted then regen
 122                 var nlen = length + ln
 123                 if nlen > capacity then enlarge(nlen)
 124                 ns.copy_to(items, ln, 0, length)
 125                 length += ln
 126         end
 127
 128         # Appends `ln` bytes from `ns` starting at index `from` to self
 129         fun append_ns_from(ns: NativeString, ln, from: Int) do
 130                 if persisted then regen
 131                 var nlen = length + ln
 132                 if nlen > capacity then enlarge(nlen)
 133                 ns.copy_to(items, ln, from, length)
 134                 length += ln
 135         end
 136
 137         redef fun enlarge(sz) do
 138                 if capacity >= sz then return
 139                 persisted = false
 140                 while capacity < sz do capacity = capacity * 2 + 2
 141                 var ns = new NativeString(capacity)
 142                 items.copy_to(ns, length, 0, 0)
 143                 items = ns
 144         end
 145
 146         redef fun to_s do
 147                 persisted = true
 148                 return new FlatString.with_infos(items, length, 0, length -1)
 149         end
 150
 151         redef fun iterator do return new BytesIterator.with_buffer(self)
 152 end
 153
 154 private class BytesIterator
 155         super IndexedIterator[Byte]
 156
 157         var tgt: NativeString
 158
 159         redef var index
 160
 161         var max: Int
 162
 163         init with_buffer(b: Bytes) do init(b.items, 0, b.length - 1)
 164
 165         redef fun is_ok do return index < max
 166
 167         redef fun next do index += 1
 168
 169         redef fun item do return tgt[index]
 170 end
 171
 172 redef class NativeString
 173         # Creates a new `Bytes` object from `self` with `strlen` as length
 174         fun to_bytes: Bytes do
 175                 var len = cstring_length
 176                 return new Bytes(self, len, len)
 177         end
 178 end