contrib/objcwrapper/src/objc_generator.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Code generation
  16 module objc_generator
  17
  18 import opts
  19
  20 import objc_model
  21
  22 redef class Sys
  23
  24         # Path to the output file
  25         var opt_output = new OptionString("Output file", "-o")
  26
  27         # Shall `init` methods/constructors be wrapped as methods?
  28         #
  29         # By default, these methods/constructors are wrapped as extern constructors.
  30         # So initializing an extern Objective-C object looks like:
  31         # ~~~nitish
  32         # var o = new NSArray.init_with_array(some_other_array)
  33         # ~~~
  34         #
  35         # If this option is set, the object must first be allocated and then initialized.
  36         # This is closer to the Objective-C behavior:
  37         # ~~~nitish
  38         # var o = new NSArray
  39         # o.init_with_array(some_other_array)
  40         # ~~~
  41         var opt_init_as_methods = new OptionBool(
  42                 "Wrap `init...` constructors as Nit methods instead of Nit constructors",
  43                 "--init-as-methods")
  44
  45         private var nit_to_java_types: Map[String, String] is lazy do
  46                 var types = new HashMap[String, String]
  47                 types["char"] = "Byte"
  48                 types["short"] = "Int"
  49                 types["short int"] = "Int"
  50                 types["int"] = "Int"
  51                 types["long"] = "Int"
  52                 types["long int"] = "Int"
  53                 types["long long"] = "Int"
  54                 types["long long int"] = "Int"
  55                 types["float"] = "Float"
  56                 types["double"] = "Float"
  57                 types["long double"] = "Float"
  58
  59                 types["NSUInteger"] = "Int"
  60                 types["BOOL"] = "Bool"
  61                 types["id"] = "NSObject"
  62                 types["constid"] = "NSObject"
  63                 types["SEL"] = "NSObject"
  64                 types["void"] = "Pointer"
  65
  66                 return types
  67         end
  68 end
  69
  70 redef class ObjcModel
  71         redef fun knows_type(objc_type) do return super or
  72                 nit_to_java_types.keys.has(objc_type)
  73 end
  74
  75 # Wrapper generator
  76 class CodeGenerator
  77
  78         # `ObjcModel` to wrap
  79         var model: ObjcModel
  80
  81         # Generate Nit code to wrap `classes`
  82         fun generate
  83         do
  84                 var classes = model.classes
  85
  86                 # Open specified path or stdin
  87                 var file
  88                 var path = opt_output.value
  89                 if path != null then
  90                         if path.file_extension != "nit" then
  91                                 print_error "Warning: output file path does not end with '.nit'"
  92                         end
  93
  94                         file = new FileWriter.open(path)
  95                 else
  96                         file = stdout
  97                 end
  98
  99                 # Generate code
 100                 file.write "import cocoa::foundation\n\n"
 101                 for classe in classes do
 102                         write_class(classe, file)
 103                 end
 104
 105                 if path != null then file.close
 106         end
 107
 108         private fun write_class(classe: ObjcClass, file: Writer)
 109         do
 110                 # Class header
 111                 file.write """
 112
 113 extern class {{{classe.name}}} in "ObjC" `{ {{{classe.name}}} * `}
 114 """
 115
 116                 # Supers
 117                 for super_name in classe.super_names do file.write """
 118         super {{{super_name}}}
 119 """
 120                 if classe.super_names.is_empty then file.write """
 121         super NSObject
 122 """
 123
 124                 file.write "\n"
 125
 126                 # Constructor or constructors
 127                 write_constructors(classe, file)
 128
 129                 # Attributes
 130                 for attribute in classe.attributes do
 131                         write_attribute(attribute, file)
 132                 end
 133
 134                 # Methods
 135                 for method in classe.methods do
 136
 137                         if not opt_init_as_methods.value and method.is_init then continue
 138
 139                         write_method_signature(method, file)
 140                         write_objc_method_call(method, file)
 141                 end
 142
 143                 file.write """
 144 end
 145 """
 146         end
 147
 148         private fun write_constructors(classe: ObjcClass, file: Writer)
 149         do
 150                 if opt_init_as_methods.value then
 151                         # A single constructor for `alloc`
 152                         file.write """
 153         new in "ObjC" `{
 154                 return [{{{classe.name}}} alloc];
 155         `}
 156
 157 """
 158                         return
 159                 end
 160
 161                 # A constructor per `init...` method
 162                 for method in classe.methods do
 163                         if not method.is_init then continue
 164
 165                         write_method_signature(method, file)
 166
 167                                 write_objc_init_call(classe.name, method, file)
 168                 end
 169         end
 170
 171         private fun write_attribute(attribute: ObjcAttribute, file: Writer)
 172         do
 173                 write_attribute_getter(attribute, file)
 174                 # TODO write_attribute_setter if there is no `readonly` annotation
 175         end
 176
 177         private fun write_attribute_getter(attribute: ObjcAttribute, file: Writer)
 178         do
 179                 var nit_attr_name = attribute.name.to_snake_case
 180                 var nit_attr_type = attribute.return_type.to_nit_type
 181
 182                 var c = attribute.comment_str
 183
 184                 file.write """
 185 {{{c}}} fun {{{nit_attr_name}}}: {{{nit_attr_type}}} in "ObjC" `{
 186 {{{c}}}         return [self {{{attribute.name}}}];
 187 {{{c}}} `}
 188
 189 """
 190         end
 191
 192         private fun write_attribute_setter(attribute: ObjcAttribute, file: Writer)
 193         do
 194                 var nit_attr_name = attribute.name.to_snake_case
 195                 var nit_attr_type = attribute.return_type.to_nit_type
 196
 197                 var c = attribute.comment_str
 198
 199                 file.write """
 200 {{{c}}} fun {{{nit_attr_name}}}=(value: {{{nit_attr_type}}}) in "ObjC" `{
 201 {{{c}}}         return self.{{{attribute.name}}} = value;
 202 {{{c}}} `}
 203
 204 """
 205         end
 206
 207         private fun write_method_signature(method: ObjcMethod, file: Writer)
 208         do
 209                 var c = method.comment_str
 210
 211                 # Build Nit method name
 212                 var name = ""
 213                 for param in method.params do
 214                         name += param.name[0].to_upper.to_s + param.name.substring_from(1)
 215                 end
 216                 name = name.to_snake_case
 217
 218                 if name == "init" then name = ""
 219
 220                 # Kind of method
 221                 var fun_keyword = "fun"
 222                 if not opt_init_as_methods.value and method.is_init then
 223                         fun_keyword = "new"
 224                 end
 225
 226                 # Params
 227                 var params = new Array[String]
 228                 for param in method.params do
 229                         if param.is_single then break
 230                         params.add "{param.variable_name}: {param.return_type.to_nit_type}"
 231                 end
 232
 233                 var params_with_par = ""
 234                 if params.not_empty then params_with_par = "({params.join(", ")})"
 235
 236                 # Return
 237                 var ret = ""
 238                 if method.return_type != "void" and fun_keyword != "new" then
 239                         ret = ": {method.return_type.to_nit_type}"
 240                 end
 241
 242                 file.write """
 243 {{{c}}} {{{fun_keyword}}} {{{name}}}{{{params_with_par}}}{{{ret}}} in "ObjC" `{
 244 """
 245         end
 246
 247         # Write a combined call to alloc and to a constructor/method
 248         private fun write_objc_init_call(class_name: String, method: ObjcMethod, file: Writer)
 249         do
 250                 # Method name and other params
 251                 var params = new Array[String]
 252                 for param in method.params do
 253                         if not param.is_single then
 254                                 params.add "{param.name}: {param.variable_name}"
 255                         else params.add param.name
 256                 end
 257
 258                 var c = method.comment_str
 259
 260                 file.write """
 261 {{{c}}}         return [[{{{class_name}}} alloc] {{{params.join(" ")}}}];
 262 {{{c}}} `}
 263
 264 """
 265         end
 266
 267         private fun write_objc_method_call(method: ObjcMethod, file: Writer)
 268         do
 269                 # Is there a value to return?
 270                 var ret = ""
 271                 if method.return_type != "void" then ret = "return "
 272
 273                 # Method name and other params
 274                 var params = new Array[String]
 275                 for param in method.params do
 276                         if not param.is_single then
 277                                 params.add "{param.name}: {param.variable_name}"
 278                         else params.add param.name
 279                 end
 280
 281                 var c = method.comment_str
 282
 283                 file.write """
 284 {{{c}}}         {{{ret}}}[self {{{params.join(" ")}}}];
 285 {{{c}}} `}
 286
 287 """
 288         end
 289 end
 290
 291 redef class Text
 292         # Nit equivalent to this type
 293         private fun to_nit_type: String
 294         do
 295                 var types = sys.nit_to_java_types
 296
 297                 if types.has_key(self) then
 298                         return types[self]
 299                 else
 300                         return to_s
 301                 end
 302         end
 303 end
 304
 305 redef class Property
 306         private fun comment_str: String do if is_commented then
 307                 return "#"
 308         else return ""
 309 end