lib/gamnit/textures.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Load textures, create subtextures and manage their life-cycle
  16 module textures
  17
  18 import display
  19
  20 # Texture composed of pixels, loaded from the assets folder by default
  21 #
  22 # Most textures should be created with `App` (as attributes)
  23 # for the method `on_create` to load them.
  24 #
  25 # ~~~
  26 # import gamnit::flat
  27 #
  28 # redef class App
  29 #     # Create the texture object, it will be loaded automatically
  30 #     var texture = new Texture("path/in/assets.png")
  31 #
  32 #     redef fun on_create()
  33 #     do
  34 #         # Let `on_create` load the texture
  35 #         super
  36 #
  37 #         # Use the texture
  38 #         var sprite = new Sprite(texture, new Point3d[Float](0.0, 0.0, 0.0))
  39 #         app.sprites.add sprite
  40 #     end
  41 # end
  42 # ~~~
  43 #
  44 # Otherwise, they can be loaded and error checked explicitly after `on_create`.
  45 #
  46 # ~~~nitish
  47 # var texture = new Texture("path/in/assets.png")
  48 # texture.load
  49 # var error = texture.error
  50 # if error != null then print_error error
  51 # ~~~
  52 #
  53 # A texture may also be created programmatically, like `CheckerTexture`,
  54 # or derived from another texture, using `subtexture`.
  55 # Textures with actual pixel data (not `Subtexture`) are `RootTexture`.
  56 # Texture loaded from the assets folder may in the PNG or JPG formats.
  57 abstract class Texture
  58
  59         # Prepare a texture located at `path` within the `assets` folder
  60         new (path: Text) do return new TextureAsset(path.to_s)
  61
  62         # Root texture from which `self` is derived
  63         fun root: RootTexture is abstract
  64
  65         # Width in pixels of this texture
  66         var width = 0.0
  67
  68         # Height in pixels of this texture
  69         var height = 0.0
  70
  71         # Load this texture, force reloading it if `force`
  72         fun load(force: nullable Bool) do end
  73
  74         # Last error on this texture
  75         var error: nullable Error = null
  76
  77         # OpenGL handle to this texture
  78         fun gl_texture: Int do return root.gl_texture
  79
  80         # Prepare a subtexture from this texture, from the given pixel offsets
  81         fun subtexture(left, top, width, height: Numeric): Subtexture
  82         do
  83                 # Setup the subtexture
  84                 var subtex = new Subtexture(root, self, left.to_f, top.to_f, width.to_f, height.to_f)
  85                 return subtex
  86         end
  87
  88         # Offset of the left border on `root` from 0.0 to 1.0
  89         fun offset_left: Float do return 0.0
  90
  91         # Offset of the top border on `root` from 0.0 to 1.0
  92         fun offset_top: Float do return 0.0
  93
  94         # Offset of the right border on `root` from 0.0 to 1.0
  95         fun offset_right: Float do return 1.0
  96
  97         # Offset of the bottom border on `root` from 0.0 to 1.0
  98         fun offset_bottom: Float do return 1.0
  99 end
 100
 101 # Colorful small texture of 32x32 pixels by default
 102 class CheckerTexture
 103         super RootTexture
 104
 105         # Width and height in pixels, defaults to 32
 106         var size = 32 is optional
 107
 108         redef fun load(force)
 109         do
 110                 if gl_texture != -1 then return
 111                 load_checker size
 112                 loaded = true
 113         end
 114 end
 115
 116 # Texture with its own pixels
 117 class RootTexture
 118         super Texture
 119
 120         redef fun root do return self
 121
 122         # Has this texture been loaded yet?
 123         var loaded = false
 124
 125         redef var gl_texture = -1
 126
 127         init do all_root_textures.add self
 128
 129         private fun load_from_pixels(pixels: Pointer, width, height: Int, format: GLPixelFormat)
 130         do
 131                 var max_texture_size = glGetIntegerv(gl_MAX_TEXTURE_SIZE, 0)
 132                 if width > max_texture_size or height > max_texture_size then
 133                         error = new Error("Texture {self} width or height is over the GL_MAX_TEXTURE_SIZE of {max_texture_size}")
 134                         return
 135                 end
 136
 137                 glPixelStorei(gl_UNPACK_ALIGNEMENT, 1)
 138                 var tex = glGenTextures(1)[0]
 139                 gl_texture = tex
 140
 141                 glBindTexture(gl_TEXTURE_2D, tex)
 142                 glTexImage2D(gl_TEXTURE_2D, 0, format, width, height, 0, format, gl_UNSIGNED_BYTE, pixels)
 143
 144                 glHint(gl_GENERATE_MIPMAP_HINT, gl_NICEST)
 145                 glGenerateMipmap(gl_TEXTURE_2D)
 146         end
 147
 148         private fun load_checker(size: Int)
 149         do
 150                 var cpixels = new CByteArray(3*size*size)
 151
 152                 var i = 0
 153                 for x in [0..size[ do
 154                         var quadrant_x = if x < size/2 then 0 else 1
 155                         for y in [0..size[ do
 156                                 var quadrant_y = if y < size/2 then 0 else 1
 157                                 var color = if quadrant_x == quadrant_y then
 158                                         [0u8, 0u8, 0u8, 255u8]
 159                                 else [255u8, 255u8, 255u8, 255u8]
 160
 161                                 for j in [0..3[ do cpixels[i+j] = color[j]
 162                                 i += 3
 163                         end
 164                 end
 165
 166                 width = size.to_f
 167                 height = size.to_f
 168                 load_from_pixels(cpixels.native_array, size, size, gl_RGB)
 169
 170                 cpixels.destroy
 171         end
 172
 173         # Set whether this texture should be pixelated when drawn, otherwise it is interpolated
 174         fun pixelated=(pixelated: Bool)
 175         do
 176                 # TODO this service could be made available in `Texture` when using
 177                 # the kind of texture wrapper of gles v2 or maybe 3
 178
 179                 glBindTexture(gl_TEXTURE_2D, gl_texture)
 180
 181                 var param = if pixelated then gl_NEAREST else gl_LINEAR
 182                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, param)
 183         end
 184
 185         # Has this resource been deleted?
 186         var deleted = false
 187
 188         # Delete this texture and free all its resources
 189         #
 190         # Use caution with this service as the subtextures may rely on the deleted data.
 191         fun delete
 192         do
 193                 if deleted or not loaded then return
 194
 195                 deleted = true
 196         end
 197 end
 198
 199 # Texture loaded from the assets folder
 200 class TextureAsset
 201         super RootTexture
 202
 203         # Path to this texture within the `assets` folder
 204         var path: String
 205
 206         redef fun load(force)
 207         do
 208                 if loaded and force != true then return
 209
 210                 load_from_platform
 211
 212                 loaded = true
 213         end
 214
 215         # Partially load this texture from platform-specific features
 216         #
 217         # This method should fill `width`, `height` and `pixels`.
 218         private fun load_from_platform is abstract
 219
 220         redef fun to_s do return "<{class_name} path:{path}>"
 221 end
 222
 223 # Texture derived from another texture, does not own its pixels
 224 class Subtexture
 225         super Texture
 226
 227         redef var root
 228
 229         # Parent texture, from which this texture was created
 230         var parent: Texture
 231
 232         # Left border of this texture compared to `parent`
 233         var left: Float
 234
 235         # Top border of this texture compared to `parent`
 236         var top: Float
 237
 238         private fun set_wh(width, height: Float)
 239         is autoinit do
 240                 self.width = width
 241                 self.height = height
 242         end
 243
 244         redef fun load(force) do root.load(force)
 245
 246         redef var offset_left = parent.offset_left + left / root.width is lazy
 247         redef var offset_top = parent.offset_top + top / root.height is lazy
 248         redef var offset_right = offset_left + width / root.width is lazy
 249         redef var offset_bottom = offset_top + height / root.height is lazy
 250 end
 251
 252 redef class Sys
 253         # All declared root textures
 254         var all_root_textures = new TextureSet
 255 end
 256
 257 # Group of `Texture`
 258 class TextureSet
 259         super HashSet[Texture]
 260
 261         # Load all texture of this set
 262         fun load_all do for t in self do t.load
 263 end