lib/android/audio.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Romain Chanoir <romain.chanoir@viacesi.fr>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Android audio services, wraps a part of android audio API
  18 # This module modifies the default behaviour of the audio loading:
  19 # It is first loaded from the `res/raw` folder.
  20 # The file extension is not needed for the `res/raw` loading part.
  21 # If it didn't work, it is loaded from the `assets` folder.
  22 # The file extension is needed for the `assets` loading part.
  23 #
  24 # `assets` contains the portable version of sounds, since the `res` folder exsists only in android projects.
  25 #
  26 # For this example, the sounds "test_sound" and "test_music" are located in the "assets/sounds" folder,
  27 # they both have ".ogg" extension. "test_sound" is a short sound and "test_music" a music track
  28 #
  29 # ~~~nitish
  30 # # Note that you need to specify the path from "assets" folder and the extension
  31 # var s = app.load_sound("sounds/test_sound.ogg")
  32 # var m = app.load_music("sounds/test_music.ogg")
  33 # s.play
  34 # m.play
  35 # ~~~
  36 #
  37 # Now, the sounds are in "res/raw"
  38 # ~~~nitish
  39 # s = app.load_sound_from_res("test_sound")
  40 # m = app.load_music_from_res("test_sound")
  41 # s.play
  42 # m.play
  43 # ~~~
  44 #
  45 # See http://developer.android.com/reference/android/media/package-summary.html for more infos
  46 module audio
  47
  48 import java
  49 import java::io
  50 intrude import assets_and_resources
  51 import activities
  52 import app::audio
  53
  54 in "Java" `{
  55         import android.media.MediaPlayer;
  56         import android.media.SoundPool;
  57         import java.io.IOException;
  58         import android.media.AudioManager;
  59         import android.media.AudioManager.OnAudioFocusChangeListener;
  60         import android.content.Context;
  61         import android.util.Log;
  62 `}
  63
  64 # FIXME: This listener is not working at the moment, but is needed to gain or give up the audio focus
  65 # of the application
  66 in "Java inner" `{
  67         static OnAudioFocusChangeListener afChangeListener = new OnAudioFocusChangeListener() {
  68                 public void onAudioFocusChange(int focusChange) {
  69                         if(focusChange == AudioManager.AUDIOFOCUS_LOSS_TRANSIENT) {
  70                         }else if (focusChange == AudioManager.AUDIOFOCUS_GAIN) {
  71                         }else if (focusChange == AudioManager.AUDIOFOCUS_LOSS) {
  72                         }
  73                 }
  74         };
  75 `}
  76
  77 # AudioManager of the application, used to manage the audio mode
  78 private extern class NativeAudioManager in "Java" `{ android.media.AudioManager `}
  79         super JavaObject
  80
  81         # Current audio mode.
  82         # ( MODE_NORMAL = 0, MODE_RINGTONE = 1, MODE_IN_CALL = 2 or MODE_IN_COMMUNICATION = 3 )
  83         fun mode: Int in "Java" `{ return self.getMode(); `}
  84
  85         # Sets the audio mode.
  86         # ( MODE_NORMAL = 0, MODE_RINGTONE = 1, MODE_IN_CALL = 2 or MODE_IN_COMMUNICATION = 3 )
  87         fun mode=(i: Int) in "Java" `{ self.setMode((int)i); `}
  88
  89         # Sends a request to obtain audio focus
  90         fun request_audio_focus: Int in "Java" `{
  91                 return self.requestAudioFocus(afChangeListener, AudioManager.STREAM_MUSIC, AudioManager.AUDIOFOCUS_GAIN);
  92         `}
  93
  94         # Gives up audio focus
  95         fun abandon_audio_focus: Int in "Java" `{ return self.abandonAudioFocus(afChangeListener); `}
  96 end
  97
  98 # Media Player from Java, used to play long sounds or musics, not simultaneously
  99 # This is a low-level class, use `MediaPlater` instead
 100 private extern class NativeMediaPlayer in "Java" `{ android.media.MediaPlayer `}
 101         super JavaObject
 102
 103         new in "Java" `{
 104                 MediaPlayer mp = new MediaPlayer();
 105                 mp.setAudioStreamType(AudioManager.STREAM_MUSIC);
 106                 return mp;
 107         `}
 108         fun start in "Java" `{ self.start(); `}
 109         fun prepare in "Java" `{
 110                 try {
 111                         self.prepare();
 112                 }catch(Exception e) {
 113                         Log.e("Error preparing the Media Player", e.getMessage());
 114                         e.printStackTrace();
 115                 }
 116         `}
 117
 118         fun create(context: NativeActivity, id: Int): NativeMediaPlayer in "Java" `{
 119                 try {
 120                         return self.create(context, (int)id);
 121                 }catch(Exception e) {
 122                         return null;
 123                 }
 124         `}
 125
 126         fun pause in "Java" `{ self.pause(); `}
 127         fun stop in "Java" `{ self.stop(); `}
 128         fun playing: Bool in "Java" `{ return self.isPlaying(); `}
 129         fun release in "Java" `{ self.release(); `}
 130         fun duration: Int in "Java" `{ return self.getDuration(); `}
 131         fun looping: Bool in "Java" `{ return self.isLooping(); `}
 132         fun looping=(b: Bool) in "Java" `{ self.setLooping(b); `}
 133         fun volume=(vol: Float) in "Java" `{ self.setVolume((float)vol, (float)vol); `}
 134         fun both_volume(left_volume, right_volume: Float) in "Java" `{ self.setVolume((float)left_volume, (float)right_volume); `}
 135         fun stream_type=(stream_type: Int) in "Java" `{ self.setAudioStreamType((int)stream_type); `}
 136         fun data_source_fd(fd: NativeFileDescriptor, start_offset, length: Int): Int in "Java"  `{
 137                 try {
 138                         self.setDataSource(fd, start_offset, length);
 139                         return 1;
 140                 }catch(Exception e) {
 141                         return 0;
 142                 }
 143         `}
 144         fun data_source_path(path: JavaString): Int in "Java" `{
 145                 try {
 146                         self.setDataSource(path);
 147                         return 1;
 148                 }catch(Exception e) {
 149                         Log.e("Error loading the Media Player", e.getMessage());
 150                         return 0;
 151                 }
 152         `}
 153         fun reset in "Java" `{ self.reset(); `}
 154 end
 155
 156 # Sound Pool from Java, used to play sounds simultaneously
 157 # This is a low-level class, use `SoundPool`instead
 158 private extern class NativeSoundPool in "Java" `{ android.media.SoundPool `}
 159         super JavaObject
 160
 161         new(max_streams, stream_type, src_quality: Int) in "Java" `{
 162                 return new SoundPool((int)max_streams, (int)stream_type, (int)src_quality);
 163         `}
 164         fun load_asset_fd(afd: NativeAssetFileDescriptor, priority: Int): Int in "Java" `{
 165                 try {
 166                         int id =  self.load(afd, (int)priority);
 167                         return id;
 168                 }catch(Exception e){
 169                         return -1;
 170                 }
 171         `}
 172
 173         fun load_id(context: NativeActivity, resid, priority: Int): Int in "Java" `{
 174                 try {
 175                         int id =  self.load(context, (int)resid, (int)priority);
 176                         return id;
 177                 }catch(Exception e){
 178                         return -1;
 179                 }
 180         `}
 181
 182         fun load_path(path: JavaString, priority: Int): Int in "Java" `{
 183                 try {
 184                         int id =  self.load(path, (int)priority);
 185                         return id;
 186                 }catch(Exception e){
 187                         return -1;
 188                 }
 189         `}
 190
 191         fun play(sound_id: Int, left_volume, right_volume: Float, priority, l: Int, rate: Float): Int in "Java" `{
 192                 return self.play((int)sound_id, (float)left_volume, (float)right_volume, (int)priority, (int)l, (float)rate);
 193         `}
 194         fun pause(stream_id: Int) in "Java" `{ self.pause((int)stream_id); `}
 195         fun auto_pause in "Java" `{ self.autoPause(); `}
 196         fun auto_resume in "Java" `{ self.autoResume(); `}
 197         fun resume(stream_id: Int) in "Java" `{ self.resume((int)stream_id); `}
 198         fun set_loop(stream_id, l: Int) in "Java" `{ self.setLoop((int)stream_id, (int)l); `}
 199         fun set_priority(stream_id, priority: Int) in "Java" `{ self.setPriority((int)stream_id, (int)priority); `}
 200         fun set_rate(stream_id: Int, rate: Float) in "Java" `{ self.setRate((int)stream_id, (float)rate); `}
 201         fun set_volume(stream_id: Int, left_volume, right_volume: Float) in "Java" `{ self.setVolume((int)stream_id, (float)left_volume, (float)right_volume); `}
 202         fun stop(stream_id: Int) in "Java" `{ self.stop((int)stream_id); `}
 203         fun unload(sound_id: Int): Bool in "Java" `{ return self.unload((int)sound_id); `}
 204         fun release in "Java" `{ self.release(); `}
 205 end
 206
 207
 208 # Used to play sound, best suited for sounds effects in apps or games
 209 class SoundPool
 210
 211         # Error gestion
 212         var error: nullable Error = null
 213
 214         private var nsoundpool: NativeSoundPool is noinit
 215         # The maximum number of simultaneous streams for this SoundPool
 216         var max_streams = 10 is writable
 217
 218         # The audio stream type, 3 is STREAM_MUSIC, default for game application
 219         var stream_type = 3 is writable
 220
 221         # The sample-rate converter quality, currently has no effect
 222         var src_quality = 0 is writable
 223
 224         # Left volume value, range 0.0 to 1.0
 225         var left_volume = 1.0 is writable
 226
 227         # Right volume value, range 0.0 to 1.0
 228         var right_volume = 1.0 is writable
 229
 230         # Playback rate, 1.0 = normal playback, range 0.5 to 2.0
 231         var rate = 1.0 is writable
 232
 233         # Loop mode, 0 = no loop, -1 = loop forever
 234         var looping = 0 is writable
 235
 236         # Stream priority
 237         private var priority = 1
 238
 239         init do self.nsoundpool = new NativeSoundPool(max_streams, stream_type, src_quality)
 240
 241         # Load the sound from an asset file descriptor
 242         # this function is for advanced use
 243         private fun load_asset_fd(afd: NativeAssetFileDescriptor): Sound do
 244                 var resval = nsoundpool.load_asset_fd(afd, self.priority)
 245                 if  resval == -1 then
 246                         self.error = new Error("Unable to load sound from assets")
 247                         return new Sound.priv_init(null, -1, self, self.error)
 248                 else
 249                         return new Sound.priv_init(null, resval, self, null)
 250                 end
 251         end
 252
 253         # Returns only the id corresponding to the soundpool where the sound is loaded.
 254         # Needed by `load` of `Sound`.
 255         private fun load_asset_fd_rid(afd: NativeAssetFileDescriptor): Int do
 256                 return nsoundpool.load_asset_fd(afd, self.priority)
 257         end
 258
 259         # Load the sound from its resource id
 260         fun load_id(context: NativeActivity, id:Int): Sound do
 261                 var resval = nsoundpool.load_id(context, id, priority)
 262                         if  resval == -1 then
 263                         self.error = new Error("Unable to load sound from assets")
 264                         return new Sound.priv_init(null, -1, self, self.error)
 265                 else
 266                         return new Sound.priv_init(null, resval, self, null)
 267                 end
 268         end
 269
 270         # Returns only the id corresponding to the soundpool where the sound is loaded.
 271         private fun load_id_rid(context: NativeActivity, id: Int): Int do
 272                 return nsoundpool.load_id(context, id, priority)
 273         end
 274
 275         # Load the sound from the specified path
 276         fun load_path(path: String): Sound do
 277                 sys.jni_env.push_local_frame(1)
 278                 var resval = nsoundpool.load_path(path.to_java_string, priority)
 279                 sys.jni_env.pop_local_frame
 280                 if  resval == -1 then
 281                         self.error = new Error("Unable to load sound from path : " + path)
 282                         return new Sound.priv_init(null, -1, self, self.error)
 283                 else
 284                         return new Sound.priv_init(null, resval, self, null)
 285                 end
 286         end
 287
 288         # Play a sound from a sound ID
 289         # return non-zero streamID if successful, zero if failed
 290         fun play(id: Int): Int do
 291                 return nsoundpool.play(id, left_volume, right_volume, priority, looping, rate)
 292         end
 293
 294         # Load a sound by its name in the resources, the sound must be in the `res/raw` folder
 295         fun load_name(resource_manager: ResourcesManager, context: NativeActivity, sound: String): Sound do
 296                 var id = resource_manager.raw_id(sound)
 297                 var resval = nsoundpool.load_id(context, id, priority)
 298                 if  resval == -1 then
 299                         self.error = new Error("Unable to load sound from resources : " + sound)
 300                         return new Sound.priv_init(null, -1, self, self.error)
 301                 else
 302                         return new Sound.priv_init(null, resval, self, null)
 303                 end
 304         end
 305
 306         # Returns only the id corresponding to the soundpool where the sound is loaded.
 307         private fun load_name_rid(resource_manager: ResourcesManager, context: NativeActivity, sound: String): Int do
 308                 var id = resource_manager.raw_id(sound)
 309                 return nsoundpool.load_id(context, id, priority)
 310         end
 311
 312         # Pause a playback stream
 313         fun pause_stream(stream_id: Int) do nsoundpool.pause(stream_id)
 314
 315         # Pause all active_streams
 316         fun auto_pause do nsoundpool.auto_pause
 317
 318         # Resume all previously active streams
 319         fun auto_resume do nsoundpool.auto_resume
 320
 321         # Resume a playback stream
 322         fun resume(stream_id: Int) do nsoundpool.resume(stream_id)
 323
 324         # Set loop mode on a stream
 325         fun stream_loop=(stream_id, looping: Int) do nsoundpool.set_loop(stream_id, looping)
 326
 327         # Change stream priority
 328         fun stream_priority=(stream_id, priority: Int) do nsoundpool.set_priority(stream_id, priority)
 329
 330         # Change playback rate
 331         fun stream_rate=(stream_id: Int, rate: Float) do nsoundpool.set_rate(stream_id, rate)
 332
 333         # Set stream volume
 334         fun stream_volume(stream_id: Int, left_volume, right_volume: Float) do
 335                 nsoundpool.set_volume(stream_id, left_volume, right_volume)
 336         end
 337
 338         # Stop a playback stream
 339         fun stop_stream(stream_id: Int) do nsoundpool.stop(stream_id)
 340
 341         # Unload a sound from a sound ID
 342         fun unload(sound: Sound): Bool do return nsoundpool.unload(sound.soundpool_id)
 343
 344         # Destroys the object
 345         fun destroy do nsoundpool.release
 346 end
 347
 348 # Used to play sounds, designed to use with medium sized sounds or streams
 349 # The Android MediaPlayer has a complex state diagram that you'll need to
 350 # respect if you want your MediaPlayer to work fine, see the android doc
 351 class MediaPlayer
 352         private var nmedia_player: NativeMediaPlayer is noinit
 353
 354         # Used to control the state of the mediaplayer
 355         private var is_prepared = false is writable
 356
 357         # The sound associated with this mediaplayer
 358         var sound: nullable Music = null is writable
 359
 360         # Error gestion
 361         var error: nullable Error = null
 362
 363         # Create a new MediaPlayer, but no sound is attached, you'll need
 364         # to use `load_sound` before using it
 365         init do self.nmedia_player = new NativeMediaPlayer
 366
 367         # Init the mediaplayer with a sound resource id
 368         init from_id(context: NativeActivity, id: Int) do
 369                 self.nmedia_player = new NativeMediaPlayer
 370                 self.nmedia_player = nmedia_player.create(context, id)
 371                 if self.nmedia_player.is_java_null then
 372                         self.error = new Error("Failed to create the MediaPlayer")
 373                         self.sound = new Music.priv_init(id, self, self.error)
 374                 end
 375                 self.sound = new Music.priv_init(id, self, null)
 376         end
 377
 378         # Load a sound for a given resource id
 379         fun load_sound(id: Int, context: NativeActivity): Music do
 380                 self.nmedia_player = self.nmedia_player.create(context, id)
 381                 if self.nmedia_player.is_java_null then
 382                         self.error = new Error("Failed to load a sound")
 383                         self.sound = new Music.priv_init(id, self, new Error("Sound loading failed"))
 384                         return self.sound.as(not null)
 385                 else
 386                         if self.error != null then self.error = null
 387                         self.sound = new Music.priv_init(id, self, null)
 388                         self.is_prepared = true
 389                         return self.sound.as(not null)
 390                 end
 391         end
 392
 393         # Starts or resumes playback
 394         # REQUIRE `self.sound != null`
 395         fun start do
 396                 if self.error != null then return
 397                 if not is_prepared then prepare
 398                 nmedia_player.start
 399         end
 400
 401         # Stops playback after playback has been stopped or paused
 402         # REQUIRE `self.sound != null`
 403         fun stop do
 404                 if self.error != null then return
 405                 is_prepared = false
 406                 nmedia_player.stop
 407         end
 408
 409         # Prepares the player for playback, synchronously
 410         # REQUIRE `self.sound != null`
 411         fun prepare do
 412                 if self.error != null then return
 413                 assert sound != null
 414                 nmedia_player.prepare
 415                 is_prepared = true
 416         end
 417
 418         # Pauses playback
 419         # REQUIRE `self.sound != null`
 420         fun pause do
 421                 if self.error != null then return
 422                 assert sound != null
 423                 nmedia_player.pause
 424         end
 425
 426         # Checks whether the mediaplayer is playing
 427         fun playing: Bool do return nmedia_player.playing
 428
 429         # Releases the resources associated with this MediaPlayer
 430         fun destroy do
 431                 nmedia_player.release
 432                 self.sound = null
 433         end
 434
 435         # Reset MediaPlayer to its initial state
 436         fun reset do nmedia_player.reset
 437
 438         # Sets the datasource (file-path or http/rtsp URL) to use
 439         fun data_source(path: String): Music do
 440                 sys.jni_env.push_local_frame(1)
 441                 var retval = nmedia_player.data_source_path(path.to_java_string)
 442                 sys.jni_env.pop_local_frame
 443                 if retval == 0 then
 444                         self.error = new Error("could not load the sound " + path)
 445                         self.sound = new Music.priv_init(null, self, self.error)
 446
 447                 else
 448                         self.sound = new Music.priv_init(null, self, null)
 449                 end
 450                 return self.sound.as(not null)
 451         end
 452         # Sets the data source (NativeFileDescriptor) to use
 453         fun data_source_fd(fd: NativeAssetFileDescriptor): Music do
 454                 if not fd.is_java_null then
 455                         if nmedia_player.data_source_fd(fd.file_descriptor, fd.start_offset, fd.length) == 0 then
 456                                 self.error = new Error("could not load the sound")
 457                                 self.sound = new Music.priv_init(null, self, self.error)
 458                         else
 459                                 self.sound = new Music.priv_init(null, self, null)
 460                         end
 461                         return self.sound.as(not null)
 462                 else
 463                         var error = new Error("could not load the sound")
 464                         return new Music.priv_init(null, self, error)
 465                 end
 466         end
 467
 468         # Checks whether the MediaPlayer is looping or non-looping
 469         fun looping: Bool do return nmedia_player.looping
 470
 471         # Sets the player to be looping or non-looping
 472         fun looping=(b: Bool) do nmedia_player.looping = b
 473
 474         # Sets the volume on this player
 475         fun volume=(volume: Float) do nmedia_player.volume = volume
 476
 477         # Sets the left volume and the right volume of this player
 478         fun both_volume(left_volume, right_volume: Float) do nmedia_player.both_volume(left_volume, right_volume)
 479
 480         # Sets the audio stream type for this media player
 481         fun stream_type=(stream_type: Int) do nmedia_player.stream_type = stream_type
 482 end
 483
 484 redef class PlayableAudio
 485         redef init do add_to_sounds(self)
 486 end
 487
 488 redef class Sound
 489
 490         # Resource ID of this sound
 491         var id: nullable Int is noinit
 492
 493         # The SoundPool who loaded this sound
 494         var soundpool: SoundPool is noinit
 495
 496         # The SoundID of this sound in his SoundPool
 497         var soundpool_id: Int is noinit
 498
 499         private init priv_init(id: nullable Int, soundpool_id: Int, soundpool: SoundPool, error: nullable Error) is nosuper do
 500                 self.id = id
 501                 self.soundpool_id = soundpool_id
 502                 self.soundpool = soundpool
 503                 if error != null then
 504                         self.error = error
 505                 else
 506                         self.is_loaded = true
 507                 end
 508         end
 509
 510         redef fun load do
 511                 if is_loaded then return
 512                 var retval_resources = app.default_soundpool.load_name_rid(app.resource_manager, app.native_activity, self.name.strip_extension)
 513                 if retval_resources == -1 then
 514                         self.error = new Error("failed to load" + self.name)
 515                         var nam = app.asset_manager.open_fd(self.name)
 516                         if nam.is_java_null then
 517                                 self.error = new Error("Failed to get file descriptor for " + self.name)
 518                         else
 519                                 var retval_assets = app.default_soundpool.load_asset_fd_rid(nam)
 520                                 if retval_assets == -1 then
 521                                         self.error = new Error("Failed to load" + self.name)
 522                                 else
 523                                         self.soundpool_id = retval_assets
 524                                         self.soundpool = app.default_soundpool
 525                                         self.error = null
 526                                         self.soundpool.error = null
 527                                 end
 528                         end
 529                 else
 530                         self.soundpool_id = retval_resources
 531                         self.soundpool = app.default_soundpool
 532                         self.error = null
 533                         self.soundpool.error = null
 534                 end
 535                 is_loaded = true
 536         end
 537
 538         redef fun play do
 539                 if not is_loaded then load
 540                 if self.error != null then return
 541                 soundpool.play(soundpool_id)
 542         end
 543
 544         redef fun pause do
 545                 if self.error != null or not self.is_loaded then return
 546                 soundpool.pause_stream(soundpool_id)
 547         end
 548
 549         redef fun resume do
 550                 if self.error != null or not self.is_loaded then return
 551                 soundpool.resume(soundpool_id)
 552         end
 553
 554 end
 555
 556 redef class Music
 557
 558         # Resource ID of this sound
 559         var id: nullable Int is noinit
 560
 561         # The MediaPlayer who loaded this sound
 562         var media_player: MediaPlayer is noinit
 563
 564         private init priv_init(id: nullable Int, media_player: MediaPlayer, error: nullable Error) is nosuper do
 565                 self.id = id
 566                 self.media_player = media_player
 567                 if error != null then
 568                         self.error = error
 569                 else
 570                         self.is_loaded = true
 571                 end
 572         end
 573
 574         redef fun load do
 575                 if is_loaded then return
 576                 var mp_sound_resources = app.default_mediaplayer.load_sound(app.resource_manager.raw_id(self.name.strip_extension), app.native_activity)
 577                 if mp_sound_resources.error != null then
 578                         self.error = mp_sound_resources.error
 579                         var nam = app.asset_manager.open_fd(self.name)
 580                         if nam.is_java_null then
 581                                 self.error = new Error("Failed to get file descriptor for " + self.name)
 582                         else
 583                                 var mp_sound_assets = app.default_mediaplayer.data_source_fd(nam)
 584                                 if mp_sound_assets.error != null then
 585                                         self.error = mp_sound_assets.error
 586                                 else
 587                                         self.media_player = app.default_mediaplayer
 588                                         self.error = null
 589                                         self.media_player.error = null
 590                                 end
 591                         end
 592                 else
 593                         self.media_player = app.default_mediaplayer
 594                         self.error = null
 595                         self.media_player.error = null
 596                 end
 597                 is_loaded = true
 598         end
 599
 600         redef fun play do
 601                 if not is_loaded then load
 602                 if self.error != null then return
 603                 media_player.start
 604         end
 605
 606         redef fun pause do
 607                 if self.error != null or not self.is_loaded then return
 608                 media_player.pause
 609         end
 610
 611         redef fun resume do
 612                 if self.error != null or not self.is_loaded then return
 613                 play
 614         end
 615 end
 616
 617 redef class App
 618
 619
 620         # Returns the default MediaPlayer of the application.
 621         # When you load a music, it goes in this MediaPlayer.
 622         # Use it for advanced sound management
 623         var default_mediaplayer: MediaPlayer is lazy do return new MediaPlayer
 624
 625         # Returns the default MediaPlayer of the application.
 626         # When you load a short sound (not a music), it's added to this soundpool.
 627         # Use it for advanced sound management.
 628         var default_soundpool: SoundPool is lazy do return new SoundPool
 629
 630         # Get the native audio manager
 631         fun audio_manager: NativeAudioManager import native_activity in "Java" `{
 632                 return (AudioManager)App_native_activity(self).getSystemService(Context.AUDIO_SERVICE);
 633         `}
 634
 635         # Sets the stream of the app to STREAM_MUSIC.
 636         # STREAM_MUSIC is the default stream used by android apps.
 637         private fun manage_audio_stream import native_activity in "Java" `{
 638                 App_native_activity(self).setVolumeControlStream(AudioManager.STREAM_MUSIC);
 639         `}
 640
 641         # Retrieves a sound with a soundpool in the `assets` folder using its name.
 642         # Used to play short songs, can play multiple sounds simultaneously
 643         redef fun load_sound(path) do
 644                 var fd = asset_manager.open_fd(path)
 645                 if not fd.is_java_null then
 646                         return add_to_sounds(default_soundpool.load_asset_fd(fd)).as(Sound)
 647                 else
 648                         var error = new Error("Failed to load Sound {path}")
 649                         return new Sound.priv_init(null, -1, default_soundpool, error)
 650                 end
 651         end
 652
 653         # Retrieves a music with a media player in the `assets` folder using its name.
 654         # Used to play long sounds or musics, can't play multiple sounds simultaneously
 655         redef fun load_music(path) do
 656                 var fd = asset_manager.open_fd(path)
 657                 if not fd.is_java_null then
 658                         return add_to_sounds(default_mediaplayer.data_source_fd(fd)).as(Music)
 659                 else
 660                         var error = new Error("Failed to load music {path}")
 661                         return new Music.priv_init(null, default_mediaplayer, error)
 662                 end
 663         end
 664
 665         # Same as `load_sound` but load the sound from the `res/raw` folder
 666         fun load_sound_from_res(sound_name: String): Sound do
 667                 return add_to_sounds(default_soundpool.load_name(resource_manager,self.native_activity, sound_name)).as(Sound)
 668         end
 669
 670         # Same as `load_music` but load the sound from the `res/raw` folder
 671         fun load_music_from_res(music: String): Music do
 672                 return add_to_sounds(default_mediaplayer.load_sound(resource_manager.raw_id(music), self.native_activity)).as(Music)
 673         end
 674
 675         redef fun on_pause do
 676                 super
 677                 for s in sounds do s.pause
 678                 audio_manager.abandon_audio_focus
 679         end
 680
 681         redef fun on_create do
 682                 super
 683                 audio_manager.request_audio_focus
 684                 manage_audio_stream
 685         end
 686
 687         redef fun on_resume do
 688                 super
 689                 audio_manager.request_audio_focus
 690                 for s in sounds do s.resume
 691         end
 692 end
 693
 694 redef class Sys
 695
 696         # Sounds handled by the application, when you load a sound, it's added to this list.
 697         # This array is used in `pause` and `resume`
 698         private var sounds = new Array[PlayableAudio]
 699
 700         # Factorizes `sounds.add` to use it in `load_music`, `load_sound`, `load_music_from_res` and `load_sound_from_res`
 701         private fun add_to_sounds(sound: PlayableAudio): PlayableAudio do
 702                 sounds.add(sound)
 703                 return sound
 704         end
 705 end