src/nit.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # A naive Nit interpreter
  18 module nit
  19
  20 import interpreter
  21 import frontend::code_gen
  22 import parser_util
  23 import vm
  24
  25 # Create a tool context to handle options and paths
  26 var toolcontext = new ToolContext
  27 toolcontext.option_context.options_before_rest = true
  28 toolcontext.tooldescription = "Usage: nit [OPTION]... <file.nit>...\nInterprets and debugs Nit programs."
  29 # Add an option "-o" to enable compatibility with the tests.sh script
  30 var opt = new OptionString("Does nothing. Used for compatibility.", "-o")
  31 opt.hidden = true
  32 toolcontext.option_context.add_option(opt)
  33 var opt_eval = new OptionBool("Specifies the program from command-line", "-e")
  34 var opt_loop = new OptionBool("Repeatedly run the program for each line in file-name arguments", "-n")
  35 var opt_vm = new OptionBool("Run the virtual machine instead of the naive interpreter (experimental)", "--vm")
  36 toolcontext.option_context.add_option(opt_eval, opt_loop, opt_vm)
  37 # We do not add other options, so process them now!
  38 toolcontext.process_options(args)
  39
  40 # We need a model to collect stufs
  41 var model = new Model
  42 # An a model builder to parse files
  43 var modelbuilder = new ModelBuilder(model, toolcontext)
  44
  45 var arguments = toolcontext.option_context.rest
  46 var progname = arguments.first
  47
  48 # Here we load an process all modules passed on the command line
  49 var mmodules: Array[MModule]
  50
  51 if opt_eval.value then
  52         var amodule = toolcontext.parse_module(progname)
  53         toolcontext.check_errors
  54
  55         var parent = null
  56         if opt_loop.value then
  57                 parent = modelbuilder.get_mmodule_by_name(null, null, "niti_runtime")
  58                 if parent == null then
  59                         toolcontext.check_errors
  60                         abort
  61                 end
  62         end
  63
  64         modelbuilder.load_rt_module(parent, amodule, "-")
  65
  66         mmodules = [amodule.mmodule.as(not null)]
  67 else if progname == "-" then
  68         var content = stdin.read_all
  69         var amodule = toolcontext.parse_module(content)
  70         toolcontext.check_errors
  71         modelbuilder.load_rt_module(null, amodule, "-")
  72         mmodules = [amodule.mmodule.as(not null)]
  73 else
  74         mmodules = modelbuilder.parse([progname])
  75 end
  76
  77 modelbuilder.run_phases
  78
  79 if toolcontext.opt_only_metamodel.value then toolcontext.quit
  80
  81 var mainmodule = toolcontext.make_main_module(mmodules)
  82
  83 var self_mm = mainmodule
  84 var self_args = arguments
  85
  86 if opt_vm.value then
  87         modelbuilder.run_virtual_machine(self_mm, self_args)
  88 else
  89         modelbuilder.run_naive_interpreter(self_mm, self_args)
  90 end
  91