src/nitcatalog.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Basic catalog generator for Nit packages
  16 #
  17 # See: <http://nitlanguage.org/catalog/>
  18 #
  19 # The tool scans packages and generates the HTML files of a catalog.
  20 #
  21 # ## Features
  22 #
  23 # * [X] scan packages and their `.ini`
  24 # * [X] generate lists of packages
  25 # * [X] generate a page per package with the readme and most metadata
  26 # * [ ] link/include/be included in the documentation
  27 # * [ ] propose `related packages`
  28 # * [X] show directory content (a la nitls)
  29 # * [X] gather git information from the working directory
  30 # * [ ] gather git information from the repository
  31 # * [ ] gather package information from github
  32 # * [ ] gather people information from github
  33 # * [ ] reify people
  34 # * [ ] separate information gathering from rendering
  35 # * [ ] move up information gathering in (existing or new) service modules
  36 # * [X] add command line options
  37 # * [ ] harden HTML (escaping, path injection, etc)
  38 # * [ ] nitcorn server with RESTful API
  39 #
  40 # ## Issues and limitations
  41 #
  42 # The tool works likee the other tools and expects to find valid Nit source code in the directories
  43 #
  44 # * cruft and temporary files will be collected
  45 # * missing source file (e.g. not yet generated by nitcc) will make information
  46 #   incomplete (e.g. invalid module thus partial dependency and metrics)
  47 #
  48 # How to use the tool as the basis of a Nit code archive on the web usable with a package manager is not clear.
  49 module nitcatalog
  50
  51 import loader # Scan&load packages, groups and modules
  52 import doc::doc_down # Display mdoc
  53 import md5 # To get gravatar images
  54 import counter # For statistics
  55 import modelize # To process and count classes and methods
  56
  57 redef class MPackage
  58         # Return the associated metadata from the `ini`, if any
  59         fun metadata(key: String): nullable String
  60         do
  61                 var ini = self.ini
  62                 if ini == null then return null
  63                 return ini[key]
  64         end
  65
  66         # The list of maintainers
  67         var maintainers = new Array[String]
  68
  69         # The list of contributors
  70         var contributors = new Array[String]
  71
  72         # The date of the most recent commit
  73         var last_date: nullable String = null
  74
  75         # The date of the oldest commit
  76         var first_date: nullable String = null
  77 end
  78
  79 # A HTML page in a catalog
  80 #
  81 # This is just a template with the header pre-filled and the footer injected at rendering.
  82 # Therefore, once instantiated, the content can just be added to it.
  83 class CatalogPage
  84         super Template
  85
  86         # Placeholder to include additional things before the `</head>`.
  87         var more_head = new Template
  88
  89         # Relative path to the root directory (with the index file).
  90         #
  91         # Use "" for pages in the root directory
  92         # Use ".." for pages in a subdirectory
  93         var rootpath: String
  94
  95         redef init
  96         do
  97                 add """
  98 <!DOCTYPE html>
  99 <html>
 100 <head>
 101         <meta charset="utf-8">
 102         <link rel="stylesheet" media="all" href="https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/css/bootstrap.min.css">
 103         <link rel="stylesheet" media="all" href="{{{rootpath / "style.css"}}}">
 104 """
 105                 add more_head
 106
 107                 add """
 108 </head>
 109 <body>
 110 <div class='container-fluid'>
 111  <div class='row'>
 112   <nav id='topmenu' class='navbar navbar-default navbar-fixed-top' role='navigation'>
 113    <div class='container-fluid'>
 114     <div class='navbar-header'>
 115      <button type='button' class='navbar-toggle' data-toggle='collapse' data-target='#topmenu-collapse'>
 116       <span class='sr-only'>Toggle menu</span>
 117       <span class='icon-bar'></span>
 118       <span class='icon-bar'></span>
 119       <span class='icon-bar'></span>
 120      </button>
 121      <span class='navbar-brand'><a href="http://nitlanguage.org/">Nitlanguage.org</a></span>
 122     </div>
 123     <div class='collapse navbar-collapse' id='topmenu-collapse'>
 124      <ul class='nav navbar-nav'>
 125       <li><a href="{{{rootpath / "index.html"}}}">Catalog</a></li>
 126      </ul>
 127     </div>
 128    </div>
 129   </nav>
 130  </div>
 131 """
 132         end
 133
 134         redef fun rendering
 135         do
 136                 add """
 137 </div> <!-- container-fluid -->
 138 <script src='https://code.jquery.com/jquery-latest.min.js'></script>
 139 <script src='https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/js/bootstrap.min.js'></script>
 140 <script src='https://cdnjs.cloudflare.com/ajax/libs/bootstrap-table/1.8.1/bootstrap-table-all.min.js'></script>
 141 </body>
 142 </html>
 143 """
 144         end
 145 end
 146
 147 redef class Int
 148         # Returns `log(self+1)`. Used to compute score of packages
 149         fun score: Float do return (self+1).to_f.log
 150 end
 151
 152 # The main class of the calatog generator that has the knowledge
 153 class Catalog
 154
 155         # The modelbuilder
 156         # used to access the files and count source lines of code
 157         var modelbuilder: ModelBuilder
 158
 159         # Packages by tag
 160         var tag2proj = new MultiHashMap[String, MPackage]
 161
 162         # Packages by category
 163         var cat2proj = new MultiHashMap[String, MPackage]
 164
 165         # Packages by maintainer
 166         var maint2proj = new MultiHashMap[String, MPackage]
 167
 168         # Packages by contributors
 169         var contrib2proj = new MultiHashMap[String, MPackage]
 170
 171         # Dependency between packages
 172         var deps = new POSet[MPackage]
 173
 174         # Number of modules by package
 175         var mmodules = new Counter[MPackage]
 176
 177         # Number of classes by package
 178         var mclasses = new Counter[MPackage]
 179
 180         # Number of methods by package
 181         var mmethods = new Counter[MPackage]
 182
 183         # Number of line of code by package
 184         var loc = new Counter[MPackage]
 185
 186         # Number of commits by package
 187         var commits = new Counter[MPackage]
 188
 189         # Score by package
 190         #
 191         # The score is loosely computed using other metrics
 192         var score = new Counter[MPackage]
 193
 194         # Scan, register and add a contributor to a package
 195         fun add_contrib(person: String, mpackage: MPackage, res: Template)
 196         do
 197                 var projs = contrib2proj[person]
 198                 if not projs.has(mpackage) then projs.add mpackage
 199                 var name = person
 200                 var email = null
 201                 var page = null
 202
 203                 # Regular expressions are broken, need to investigate.
 204                 # So split manually.
 205                 #
 206                 #var re = "([^<(]*?)(<([^>]*?)>)?(\\((.*)\\))?".to_re
 207                 #var m = (person+" ").search(re)
 208                 #print "{person}: `{m or else "?"}` `{m[1] or else "?"}` `{m[3] or else "?"}` `{m[5] or else "?"}`"
 209                 do
 210                         var sp1 = person.split_once_on("<")
 211                         if sp1.length < 2 then
 212                                 break
 213                         end
 214                         var sp2 = sp1.last.split_once_on(">")
 215                         if sp2.length < 2 then
 216                                 break
 217                         end
 218                         name = sp1.first.trim
 219                         email = sp2.first.trim
 220                         var sp3 = sp2.last.split_once_on("(")
 221                         if sp3.length < 2 then
 222                                 break
 223                         end
 224                         var sp4 = sp3.last.split_once_on(")")
 225                         if sp4.length < 2 then
 226                                 break
 227                         end
 228                         page = sp4.first.trim
 229                 end
 230
 231                 var e = name.html_escape
 232                 res.add "<li>"
 233                 if page != null then
 234                         res.add "<a href=\"{page.html_escape}\">"
 235                 end
 236                 if email != null then
 237                         # TODO get more things from github by using the email as a key
 238                         # "https://api.github.com/search/users?q={email}+in:email"
 239                         var md5 = email.md5.to_lower
 240                         res.add "<img src=\"https://secure.gravatar.com/avatar/{md5}?size=20&amp;default=retro\">&nbsp;"
 241                 end
 242                 res.add "{e}"
 243                 if page != null then res.add "</a>"
 244                 res.add "</li>"
 245         end
 246
 247         # Recursively generate a level in the file tree of the *content* section
 248         private fun gen_content_level(ot: OrderedTree[Object], os: Array[Object], res: Template)
 249         do
 250                 res.add "<ul>\n"
 251                 for o in os do
 252                         res.add "<li>"
 253                         if o isa MGroup then
 254                                 var d = ""
 255                                 var mdoc = o.mdoc
 256                                 if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 257                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 258                         else if o isa ModulePath then
 259                                 var d = ""
 260                                 var m = o.mmodule
 261                                 if m != null then
 262                                         var mdoc = m.mdoc
 263                                         if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 264                                 end
 265                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 266                         else
 267                                 abort
 268                         end
 269                         var subs = ot.sub.get_or_null(o)
 270                         if subs != null then gen_content_level(ot, subs, res)
 271                         res.add "</li>\n"
 272                 end
 273                 res.add "</ul>\n"
 274         end
 275
 276         # Compute information and generate a full HTML page for a package
 277         fun package_page(mpackage: MPackage): Writable
 278         do
 279                 var res = new CatalogPage("..")
 280                 var score = score[mpackage].to_f
 281                 var name = mpackage.name.html_escape
 282                 res.more_head.add """<title>{{{name}}}</title>"""
 283
 284                 res.add """
 285 <div class="content">
 286 <h1 class="package-name">{{{name}}}</h1>
 287 """
 288                 var mdoc = mpackage.mdoc_or_fallback
 289                 if mdoc != null then
 290                         score += 100.0
 291                         res.add mdoc.html_documentation
 292                         score += mdoc.content.length.score
 293                 end
 294
 295                 res.add "<h2>Content</h2>"
 296                 var ot = new OrderedTree[Object]
 297                 for g in mpackage.mgroups do
 298                         var pa = g.parent
 299                         if g.is_interesting then
 300                                 ot.add(pa, g)
 301                                 pa = g
 302                         end
 303                         for mp in g.module_paths do
 304                                 ot.add(pa, mp)
 305                         end
 306                 end
 307                 ot.sort_with(alpha_comparator)
 308                 gen_content_level(ot, ot.roots, res)
 309
 310
 311                 res.add """
 312 </div>
 313 <div class="sidebar">
 314 <ul class="box">
 315 """
 316                 var homepage = mpackage.metadata("upstream.homepage")
 317                 if homepage != null then
 318                         score += 5.0
 319                         var e = homepage.html_escape
 320                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 321                 end
 322                 var maintainer = mpackage.metadata("package.maintainer")
 323                 if maintainer != null then
 324                         score += 5.0
 325                         add_contrib(maintainer, mpackage, res)
 326                         mpackage.maintainers.add maintainer
 327                         var projs = maint2proj[maintainer]
 328                         if not projs.has(mpackage) then projs.add mpackage
 329                 end
 330                 var license = mpackage.metadata("package.license")
 331                 if license != null then
 332                         score += 5.0
 333                         var e = license.html_escape
 334                         res.add "<li><a href=\"http://opensource.org/licenses/{e}\">{e}</a> license</li>\n"
 335                 end
 336                 res.add "</ul>\n"
 337
 338                 res.add "<h3>Source Code</h3>\n<ul class=\"box\">\n"
 339                 var browse = mpackage.metadata("upstream.browse")
 340                 if browse != null then
 341                         score += 5.0
 342                         var e = browse.html_escape
 343                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 344                 end
 345                 var git = mpackage.metadata("upstream.git")
 346                 if git != null then
 347                         var e = git.html_escape
 348                         res.add "<li><tt>{e}</tt></li>\n"
 349                 end
 350                 var last_date = mpackage.last_date
 351                 if last_date != null then
 352                         var e = last_date.html_escape
 353                         res.add "<li>most recent commit: {e}</li>\n"
 354                 end
 355                 var first_date = mpackage.first_date
 356                 if first_date != null then
 357                         var e = first_date.html_escape
 358                         res.add "<li>oldest commit: {e}</li>\n"
 359                 end
 360                 var commits = commits[mpackage]
 361                 if commits != 0 then
 362                         res.add "<li>{commits} commits</li>\n"
 363                 end
 364                 res.add "</ul>\n"
 365
 366                 res.add "<h3>Tags</h3>\n"
 367                 var tags = mpackage.metadata("package.tags")
 368                 var ts = new Array[String]
 369                 if tags != null then
 370                         for t in tags.split(",") do
 371                                 t = t.trim
 372                                 if t == "" then continue
 373                                 ts.add t
 374                         end
 375                 end
 376                 if ts.is_empty then ts.add "none"
 377                 var ts2 = new Array[String]
 378                 for t in ts do
 379                         tag2proj[t].add mpackage
 380                         t = t.html_escape
 381                         ts2.add "<a href=\"../index.html#tag_{t}\">{t}</a>"
 382                 end
 383                 res.add_list(ts2, ", ", ", ")
 384                 var cat = ts.first
 385                 cat2proj[cat].add mpackage
 386                 score += ts.length.score
 387
 388                 if deps.has(mpackage) then
 389                         var reqs = deps[mpackage].greaters.to_a
 390                         reqs.remove(mpackage)
 391                         alpha_comparator.sort(reqs)
 392                         res.add "<h3>Requirements</h3>\n"
 393                         if reqs.is_empty then
 394                                 res.add "none"
 395                         else
 396                                 var list = new Array[String]
 397                                 for r in reqs do
 398                                         var direct = deps.has_direct_edge(mpackage, r)
 399                                         var s = "<a href=\"{r}.html\">"
 400                                         if direct then s += "<strong>"
 401                                         s += r.to_s
 402                                         if direct then s += "</strong>"
 403                                         s += "</a>"
 404                                         list.add s
 405                                 end
 406                                 res.add_list(list, ", ", " and ")
 407                         end
 408
 409                         reqs = deps[mpackage].smallers.to_a
 410                         reqs.remove(mpackage)
 411                         alpha_comparator.sort(reqs)
 412                         res.add "<h3>Clients</h3>\n"
 413                         if reqs.is_empty then
 414                                 res.add "none"
 415                         else
 416                                 var list = new Array[String]
 417                                 for r in reqs do
 418                                         var direct = deps.has_direct_edge(r, mpackage)
 419                                         var s = "<a href=\"{r}.html\">"
 420                                         if direct then s += "<strong>"
 421                                         s += r.to_s
 422                                         if direct then s += "</strong>"
 423                                         s += "</a>"
 424                                         list.add s
 425                                 end
 426                                 res.add_list(list, ", ", " and ")
 427                         end
 428
 429                         score += deps[mpackage].greaters.length.score
 430                         score += deps[mpackage].direct_greaters.length.score
 431                         score += deps[mpackage].smallers.length.score
 432                         score += deps[mpackage].direct_smallers.length.score
 433                 end
 434
 435                 var contributors = mpackage.contributors
 436                 if not contributors.is_empty then
 437                         res.add "<h3>Contributors</h3>\n<ul class=\"box\">"
 438                         for c in contributors do
 439                                 add_contrib(c, mpackage, res)
 440                         end
 441                         res.add "</ul>"
 442                 end
 443                 score += contributors.length.to_f
 444
 445                 var mmodules = 0
 446                 var mclasses = 0
 447                 var mmethods = 0
 448                 var loc = 0
 449                 for g in mpackage.mgroups do
 450                         mmodules += g.module_paths.length
 451                         for m in g.mmodules do
 452                                 var am = modelbuilder.mmodule2node(m)
 453                                 if am != null then
 454                                         var file = am.location.file
 455                                         if file != null then
 456                                                 loc += file.line_starts.length - 1
 457                                         end
 458                                 end
 459                                 for cd in m.mclassdefs do
 460                                         mclasses += 1
 461                                         for pd in cd.mpropdefs do
 462                                                 if not pd isa MMethodDef then continue
 463                                                 mmethods += 1
 464                                         end
 465                                 end
 466                         end
 467                 end
 468                 self.mmodules[mpackage] = mmodules
 469                 self.mclasses[mpackage] = mclasses
 470                 self.mmethods[mpackage] = mmethods
 471                 self.loc[mpackage] = loc
 472
 473                 #score += mmodules.score
 474                 score += mclasses.score
 475                 score += mmethods.score
 476                 score += loc.score
 477
 478                 res.add """
 479 <h3>Stats</h3>
 480 <ul class="box">
 481 <li>{{{mmodules}}} modules</li>
 482 <li>{{{mclasses}}} classes</li>
 483 <li>{{{mmethods}}} methods</li>
 484 <li>{{{loc}}} lines of code</li>
 485 </ul>
 486 """
 487
 488                 res.add """
 489 </div>
 490 """
 491                 self.score[mpackage] = score.to_i
 492
 493                 return res
 494         end
 495
 496         # Return a short HTML sequence for a package
 497         #
 498         # Intended to use in lists.
 499         fun li_package(p: MPackage): String
 500         do
 501                 var res = ""
 502                 var f = "p/{p.name}.html"
 503                 res += "<a href=\"{f}\">{p}</a>"
 504                 var d = p.mdoc_or_fallback
 505                 if d != null then res += " - {d.html_synopsis.write_to_string}"
 506                 return res
 507         end
 508
 509         # List packages by group.
 510         #
 511         # For each key of the `map` a `<h3>` is generated.
 512         # Each package is then listed.
 513         #
 514         # The list of keys is generated first to allow fast access to the correct `<h3>`.
 515         # `id_prefix` is used to give an id to the `<h3>` element.
 516         fun list_by(map: MultiHashMap[String, MPackage], id_prefix: String): Template
 517         do
 518                 var res = new Template
 519                 var keys = map.keys.to_a
 520                 alpha_comparator.sort(keys)
 521                 var list = [for x in keys do "<a href=\"#{id_prefix}{x.html_escape}\">{x.html_escape}</a>"]
 522                 res.add_list(list, ", ", " and ")
 523
 524                 for k in keys do
 525                         var projs = map[k].to_a
 526                         alpha_comparator.sort(projs)
 527                         var e = k.html_escape
 528                         res.add "<h3 id=\"{id_prefix}{e}\">{e} ({projs.length})</h3>\n<ul>\n"
 529                         for p in projs do
 530                                 res.add "<li>"
 531                                 res.add li_package(p)
 532                                 res.add "</li>"
 533                         end
 534                         res.add "</ul>"
 535                 end
 536                 return res
 537         end
 538
 539         # List the 10 best packages from `cpt`
 540         fun list_best(cpt: Counter[MPackage]): Template
 541         do
 542                 var res = new Template
 543                 res.add "<ul>"
 544                 var best = cpt.sort
 545                 for i in [1..10] do
 546                         if i > best.length then break
 547                         var p = best[best.length-i]
 548                         res.add "<li>"
 549                         res.add li_package(p)
 550                         # res.add " ({cpt[p]})"
 551                         res.add "</li>"
 552                 end
 553                 res.add "</ul>"
 554                 return res
 555         end
 556
 557         # Collect more information on a package using the `git` tool.
 558         fun git_info(mpackage: MPackage)
 559         do
 560                 var ini = mpackage.ini
 561                 if ini == null then return
 562
 563                 # TODO use real git info
 564                 #var repo = ini.get_or_null("upstream.git")
 565                 #var branch = ini.get_or_null("upstream.git.branch")
 566                 #var directory = ini.get_or_null("upstream.git.directory")
 567
 568                 var dirpath = mpackage.root.filepath
 569                 if dirpath == null then return
 570
 571                 # Collect commits info
 572                 var res = git_run("log", "--no-merges", "--follow", "--pretty=tformat:%ad;%aN <%aE>", "--", dirpath)
 573                 var contributors = new Counter[String]
 574                 var commits = res.split("\n")
 575                 if commits.not_empty and commits.last == "" then commits.pop
 576                 self.commits[mpackage] = commits.length
 577                 for l in commits do
 578                         var s = l.split_once_on(';')
 579                         if s.length != 2 or s.last == "" then continue
 580
 581                         # Collect date of last and first commit
 582                         if mpackage.last_date == null then mpackage.last_date = s.first
 583                         mpackage.first_date = s.first
 584
 585                         # Count contributors
 586                         contributors.inc(s.last)
 587                 end
 588                 for c in contributors.sort.reverse_iterator do
 589                         mpackage.contributors.add c
 590                 end
 591
 592         end
 593
 594         # Produce a HTML table containig information on the packages
 595         #
 596         # `package_page` must have been called before so that information is computed.
 597         fun table_packages(mpackages: Array[MPackage]): Template
 598         do
 599                 alpha_comparator.sort(mpackages)
 600                 var res = new Template
 601                 res.add "<table data-toggle=\"table\" data-sort-name=\"name\" data-sort-order=\"desc\" width=\"100%\">\n"
 602                 res.add "<thead><tr>\n"
 603                 res.add "<th data-field=\"name\" data-sortable=\"true\">name</th>\n"
 604                 res.add "<th data-field=\"maint\" data-sortable=\"true\">maint</th>\n"
 605                 res.add "<th data-field=\"contrib\" data-sortable=\"true\">contrib</th>\n"
 606                 if deps.not_empty then
 607                         res.add "<th data-field=\"reqs\" data-sortable=\"true\">reqs</th>\n"
 608                         res.add "<th data-field=\"dreqs\" data-sortable=\"true\">direct<br>reqs</th>\n"
 609                         res.add "<th data-field=\"cli\" data-sortable=\"true\">clients</th>\n"
 610                         res.add "<th data-field=\"dcli\" data-sortable=\"true\">direct<br>clients</th>\n"
 611                 end
 612                 res.add "<th data-field=\"mod\" data-sortable=\"true\">modules</th>\n"
 613                 res.add "<th data-field=\"cla\" data-sortable=\"true\">classes</th>\n"
 614                 res.add "<th data-field=\"met\" data-sortable=\"true\">methods</th>\n"
 615                 res.add "<th data-field=\"loc\" data-sortable=\"true\">lines</th>\n"
 616                 res.add "<th data-field=\"score\" data-sortable=\"true\">score</th>\n"
 617                 res.add "</tr></thead>"
 618                 for p in mpackages do
 619                         res.add "<tr>"
 620                         res.add "<td><a href=\"p/{p.name}.html\">{p.name}</a></td>"
 621                         var maint = "?"
 622                         if p.maintainers.not_empty then maint = p.maintainers.first
 623                         res.add "<td>{maint}</td>"
 624                         res.add "<td>{p.contributors.length}</td>"
 625                         if deps.not_empty then
 626                                 res.add "<td>{deps[p].greaters.length-1}</td>"
 627                                 res.add "<td>{deps[p].direct_greaters.length}</td>"
 628                                 res.add "<td>{deps[p].smallers.length-1}</td>"
 629                                 res.add "<td>{deps[p].direct_smallers.length}</td>"
 630                         end
 631                         res.add "<td>{mmodules[p]}</td>"
 632                         res.add "<td>{mclasses[p]}</td>"
 633                         res.add "<td>{mmethods[p]}</td>"
 634                         res.add "<td>{loc[p]}</td>"
 635                         res.add "<td>{score[p]}</td>"
 636                         res.add "</tr>\n"
 637                 end
 638                 res.add "</table>\n"
 639                 return res
 640         end
 641 end
 642
 643 # Execute a git command and return the result
 644 fun git_run(command: String...): String
 645 do
 646         # print "git {command.join(" ")}"
 647         var p = new ProcessReader("git", command...)
 648         var res = p.read_all
 649         p.close
 650         p.wait
 651         return res
 652 end
 653
 654 var model = new Model
 655 var tc = new ToolContext
 656
 657 var opt_dir = new OptionString("Directory where the HTML files are generated", "-d", "--dir")
 658 var opt_no_git = new OptionBool("Do not gather git information from the working directory", "--no-git")
 659 var opt_no_parse = new OptionBool("Do not parse nit files (no importation information)", "--no-parse")
 660 var opt_no_model = new OptionBool("Do not analyse nit files (no class/method information)", "--no-model")
 661
 662 tc.option_context.add_option(opt_dir, opt_no_git, opt_no_parse, opt_no_model)
 663
 664 tc.process_options(sys.args)
 665 tc.keep_going = true
 666
 667 var modelbuilder = new ModelBuilder(model, tc)
 668 var catalog = new Catalog(modelbuilder)
 669
 670 # Get files or groups
 671 for a in tc.option_context.rest do
 672         modelbuilder.get_mgroup(a)
 673         modelbuilder.identify_file(a)
 674 end
 675
 676 # Scan packages and compute information
 677 for p in model.mpackages do
 678         var g = p.root
 679         assert g != null
 680         modelbuilder.scan_group(g)
 681
 682         # Load the module to process importation information
 683         if opt_no_parse.value then continue
 684         modelbuilder.parse_group(g)
 685
 686         catalog.deps.add_node(p)
 687         for gg in p.mgroups do for m in gg.mmodules do
 688                 for im in m.in_importation.direct_greaters do
 689                         var ip = im.mpackage
 690                         if ip == null or ip == p then continue
 691                         catalog.deps.add_edge(p, ip)
 692                 end
 693         end
 694 end
 695
 696 if not opt_no_git.value then for p in model.mpackages do
 697         catalog.git_info(p)
 698 end
 699
 700 # Run phases to modelize classes and properties (so we can count them)
 701 if not opt_no_model.value then
 702         modelbuilder.run_phases
 703 end
 704
 705 var out = opt_dir.value or else "catalog.out"
 706 (out/"p").mkdir
 707
 708 # Generate the css (hard coded)
 709 var css = """
 710 body {
 711 margin-top:                     15px;
 712 background-color:               #f8f8f8;
 713 }
 714
 715 a {
 716 color:                          #0D8921;
 717 text-decoration:                none;
 718 }
 719
 720 a:hover {
 721 color:                          #333;
 722 text-decoration:                none;
 723 }
 724
 725 h1 {
 726 font-weight:                    bold;
 727 color:                          #0D8921;
 728 font-size:                      22px;
 729 }
 730
 731 h2 {
 732 color:                          #6C6C6C;
 733 font-size:                      18px;
 734 border-bottom:                  solid 3px #CCC;
 735 }
 736
 737 h3 {
 738 color:                          #6C6C6C;
 739 font-size:                      15px;
 740 border-bottom:                  solid 1px #CCC;
 741 }
 742
 743 ul {
 744 list-style-type:                square;
 745 }
 746
 747 dd {
 748 color:                          #6C6C6C;
 749 margin-top:                     1em;
 750 margin-bottom:                  1em;
 751 }
 752
 753 pre {
 754 border:                         1px solid #CCC;
 755 font-family:                    Monospace;
 756 color:                          #2d5003;
 757 background-color:               rgb(250, 250, 250);
 758 }
 759
 760 code {
 761 font-family:                    Monospace;
 762 color:                          #2d5003;
 763 }
 764
 765 footer {
 766 margin-top:                     20px;
 767 }
 768
 769 .container {
 770 margin:                         0 auto;
 771 padding:                        0 20px;
 772 }
 773
 774 .content {
 775 float:                          left;
 776 margin-top:                     40px;
 777 width:                          65%;
 778 }
 779
 780 .sidebar {
 781 float:                          right;
 782 margin-top:                     40px;
 783 width:                          30%
 784 }
 785
 786 .sidebar h3 {
 787 color:                          #0D8921;
 788 font-size:                      18px;
 789 border-bottom:                  0px;
 790 }
 791
 792 .box {
 793 margin:                         0;
 794 padding:                        0;
 795 }
 796
 797 .box li {
 798 line-height:                    2.5;
 799 white-space:                    nowrap;
 800 overflow:                       hidden;
 801 text-overflow:                  ellipsis;
 802 padding-right:                  10px;
 803 border-bottom:                  1px solid rgba(0,0,0,0.2);
 804 }
 805 """
 806 css.write_to_file(out/"style.css")
 807
 808 # PAGES
 809
 810 for p in model.mpackages do
 811         # print p
 812         var f = "p/{p.name}.html"
 813         catalog.package_page(p).write_to_file(out/f)
 814 end
 815
 816 # INDEX
 817
 818 var index = new CatalogPage("")
 819 index.more_head.add "<title>Packages in Nit</title>"
 820
 821 index.add """
 822 <div class="content">
 823 <h1>Packages in Nit</h1>
 824 """
 825
 826 index.add "<h2>Highlighted Packages</h2>\n"
 827 index.add catalog.list_best(catalog.score)
 828
 829 if catalog.deps.not_empty then
 830         index.add "<h2>Most Required</h2>\n"
 831         var reqs = new Counter[MPackage]
 832         for p in model.mpackages do
 833                 reqs[p] = catalog.deps[p].smallers.length - 1
 834         end
 835         index.add catalog.list_best(reqs)
 836 end
 837
 838 index.add "<h2>By First Tag</h2>\n"
 839 index.add catalog.list_by(catalog.cat2proj, "cat_")
 840
 841 index.add "<h2>By Any Tag</h2>\n"
 842 index.add catalog.list_by(catalog.tag2proj, "tag_")
 843
 844 index.add """
 845 </div>
 846 <div class="sidebar">
 847 <h3>Stats</h3>
 848 <ul class="box">
 849 <li>{{{model.mpackages.length}}} packages</li>
 850 <li>{{{catalog.maint2proj.length}}} maintainers</li>
 851 <li>{{{catalog.contrib2proj.length}}} contributors</li>
 852 <li>{{{catalog.tag2proj.length}}} tags</li>
 853 <li>{{{catalog.mmodules.sum}}} modules</li>
 854 <li>{{{catalog.mclasses.sum}}} classes</li>
 855 <li>{{{catalog.mmethods.sum}}} methods</li>
 856 <li>{{{catalog.loc.sum}}} lines of code</li>
 857 </ul>
 858 </div>
 859 """
 860
 861 index.write_to_file(out/"index.html")
 862
 863 # PEOPLE
 864
 865 var page = new CatalogPage("")
 866 page.more_head.add "<title>People of Nit</title>"
 867 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 868 page.add "<h2>By Maintainer</h2>\n"
 869 page.add catalog.list_by(catalog.maint2proj, "maint_")
 870 page.add "<h2>By Contributor</h2>\n"
 871 page.add catalog.list_by(catalog.contrib2proj, "contrib_")
 872 page.add "</div>\n"
 873 page.write_to_file(out/"people.html")
 874
 875 # TABLE
 876
 877 page = new CatalogPage("")
 878 page.more_head.add "<title>Projets of Nit</title>"
 879 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 880 page.add "<h2>Table of Projets</h2>\n"
 881 page.add catalog.table_packages(model.mpackages)
 882 page.add "</div>\n"
 883 page.write_to_file(out/"table.html")