contrib/benitlux/src/benitlux_daily.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Daily program to fetch and parse the Web site, update the database and email subscribers
  18 module benitlux_daily
  19
  20 import curl
  21 import sendmail
  22 import opts
  23
  24 import benitlux_model
  25 import benitlux_db
  26
  27 redef class Text
  28         # Return a `String` without any HTML tags (such as `<br />`) from `recv`
  29         fun strip_tags: String
  30         do
  31                 var str = to_s
  32                 var new_str = ""
  33
  34                 var from = 0
  35                 loop
  36                         var at = str.index_of_from('<', from)
  37                         if at == -1 then break
  38
  39                         new_str += str.substring(from, at-from)
  40
  41                         at = str.index_of_from('>', at)
  42                         assert at != -1
  43
  44                         from = at+1
  45                 end
  46
  47                 return new_str
  48         end
  49
  50         # Return an `Array` of the non-empty lines in `self`
  51         #
  52         #     assert ["a", "asdf", "", "  ", "&nbsp;", "b"].join("\n").to_clean_lines == ["a", "asdf", "b"]
  53         fun to_clean_lines: Array[String]
  54         do
  55                 var orig_lines = split_with("\n")
  56                 var new_lines = new Array[String]
  57
  58                 for line in orig_lines do
  59                         line = line.trim
  60
  61                         # remove empty lines
  62                         if line == "&nbsp;" then continue
  63                         if line.is_empty then continue
  64
  65                         new_lines.add line.to_s
  66                 end
  67
  68                 return new_lines
  69         end
  70 end
  71
  72 # Main logic of the program to be executed daily
  73 class Benitlux
  74         # The street on which is the Benelux
  75         var street: String
  76
  77         # The url of this precise Benelux
  78         var url = "www.brasseriebenelux.com/{street}" is lazy
  79
  80         # Path to the database
  81         var db_path = "benitlux_{street}.db" is lazy
  82
  83         # Where to save the sample email
  84         var sample_email_path = "benitlux_{street}.email" is lazy
  85
  86         # Execute the main program logic
  87         fun run(send_emails: Bool)
  88         do
  89                 # Get the web page
  90                 var body = download_html_page
  91
  92                 # Parse the Web page and get the available beers
  93                 var beers = parse_beers_from_html(body)
  94
  95                 var db = new DB.open(db_path)
  96
  97                 # Update the database with the beers of the day
  98                 db.insert_beers_of_the_day beers
  99
 100                 # Query the beer-related events of today
 101                 var beer_events = db.beer_events_today
 102
 103                 # Generate the email title and content, store them in attributes
 104                 generate_email(beer_events)
 105
 106                 # Save as sample email to file
 107                 var f = new FileWriter.open(sample_email_path)
 108                 f.write email_title + "\n"
 109                 for line in email_content do f.write line + "\n"
 110                 f.close
 111
 112                 # Set the email if desired
 113                 if send_emails then
 114                         var subs = db.subscribers
 115                         send_emails_to subs
 116                 end
 117
 118                 db.close
 119         end
 120
 121         # Fetch the Web page at `url`
 122         fun download_html_page: String
 123         do
 124                 var request = new CurlHTTPRequest(url)
 125                 var response = request.execute
 126
 127                 if response isa CurlResponseSuccess then
 128                         var body = response.body_str
 129                         return body
 130                 else if response isa CurlResponseFailed then
 131                         print "Failed downloading URL '{url}' with: {response.error_msg} ({response.error_code})"
 132                         exit 1
 133                 end
 134                 abort
 135         end
 136
 137         # Extract the beers of the day information from the HTML if `body`
 138         fun parse_beers_from_html(body: String): HashSet[Beer]
 139         do
 140                 # Parts of the HTML page expected to encapsulate the interesting section
 141                 var header = "<h1>Bières<br /></h1>"
 142                 var ender = "</div></div></div>"
 143
 144                 var match = body.search(header)
 145                 assert match != null else print body
 146                 var start = match.after
 147
 148                 match = body.search_from(ender, start)
 149                 assert match != null
 150                 var finish = match.from
 151
 152                 var of_interest = body.substring(start, finish-start)
 153                 var lines = of_interest.strip_tags.to_clean_lines
 154
 155                 var beers = new HashSet[Beer]
 156                 for line in lines do
 157                         var parts = line.split(" - ")
 158                         if parts.length >= 2 then
 159                                 beers.add new Beer(parts[0].trim, parts[1].trim)
 160                         end
 161                 end
 162                 return beers
 163         end
 164
 165         # Content lines of the email
 166         var email_content: Array[String] is noautoinit
 167
 168         # Title of the email
 169         var email_title: String is noautoinit
 170
 171         # Generate email and fill the attributes `email_content` and `email_title`
 172         fun generate_email(beer_events: BeerEvents)
 173         do
 174                 email_title = beer_events.to_email_title
 175                 email_content = beer_events.to_email_content
 176         end
 177
 178         # Send the email to all the addresses in `subs`
 179         fun send_emails_to(subs: Array[String])
 180         do
 181                 for email in subs do
 182                         var unsub_link = "http://benitlux.xymus.net/?unsub=&email={email}"
 183                         var content = """
 184 {{{email_content.join("<br />\n")}}}
 185 <br /><br />
 186 To unsubscribe, go to <a href="{{{unsub_link}}}">{{{unsub_link}}}</a>
 187 """
 188
 189                         var mail = new Mail("Benitlux <benitlux@xymus.net>", email_title, content)
 190                         mail.to.add email
 191                         mail.header["Content-Type"] = "text/html; charset=\"UTF-8\""
 192                         mail.header["List-Unsubscribe"] = unsub_link
 193                         mail.header["Precedence"] = "bulk"
 194                         mail.encrypt_with_base64
 195
 196                         mail.send
 197                 end
 198         end
 199 end
 200
 201 redef class OptionContext
 202         # Shall we mail the mailing list?
 203         var send_emails = new OptionBool("Send emails to subscribers", "-e", "--email")
 204
 205         # Print the usage message
 206         var help = new OptionBool("Print this help message", "-h", "--help")
 207
 208         redef init do add_option(send_emails, help)
 209 end
 210
 211 # Avoid executing when running tests
 212 if "NIT_TESTING".environ == "true" then exit 0
 213
 214 var opts = new OptionContext
 215 opts.parse args
 216 if not opts.errors.is_empty or opts.help.value == true then
 217         print opts.errors.join("\n")
 218         print "Usage: benitlux_daily [Options]"
 219         opts.usage
 220         exit 1
 221 end
 222
 223 var ben = new Benitlux("sherbrooke")
 224 ben.run(opts.send_emails.value)
 225
 226 # The parsing logic for the wellington location is active (to gather data)
 227 # but the web interface do not allow to subscribe to its mailing list.
 228 #
 229 # TODO revamp mailing list Web interface
 230 ben = new Benitlux("wellington")
 231 ben.run(opts.send_emails.value)