contrib/neo_doxygen/src/model/member.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Members.
  16 module model::member
  17
  18 import graph
  19 import type_entity
  20
  21 # A member.
  22 abstract class Member
  23         super CodeBlock
  24
  25         # The node used to represent the `MProperty` node.
  26         #
  27         # Only defined if `self` is at the root of a reimplementation graph, and
  28         # only once `put_in_graph` is called.
  29         var introducer: nullable MemberIntroducer = null
  30
  31         # Members that this member redefines/reimplements.
  32         var reimplemented: SimpleCollection[String] = new Array[String]
  33
  34         init do
  35                 super
  36                 self.labels.add("MPropDef")
  37         end
  38
  39         # Set the static type.
  40         fun static_type=(static_type: nullable TypeEntity) is abstract
  41
  42         # Get the static type.
  43         fun static_type: nullable TypeEntity is abstract
  44
  45         # Append the specified parameter to the signature.
  46         fun add_parameter(parameter: MemberParameter) do end
  47
  48         # Append a member that is reimplemeneted by `self`.
  49         fun reimplement(parent: String) do
  50                 reimplemented.add(parent)
  51         end
  52
  53         # Does this member introduce the property?
  54         fun is_intro: Bool do
  55                 return reimplemented.length <= 0
  56         end
  57
  58         redef fun put_in_graph do
  59                 super
  60                 self["is_intro"] = is_intro
  61                 if is_intro then
  62                         var visibility = self["visibility"]
  63                         var full_name = self["full_name"]
  64                         var name = self["name"]
  65
  66                         introducer = create_introducer
  67                         if full_name isa String then
  68                                 introducer.full_name = full_name
  69                         else if name isa String then
  70                                 introducer.name = name
  71                         end
  72                         if visibility isa String then
  73                                 introducer.visibility = visibility
  74                         end
  75                         introducer.put_in_graph
  76                 end
  77         end
  78
  79         redef fun put_edges do
  80                 super
  81                 var intro = resolve_introducer
  82
  83                 assert intro != null
  84                 graph.add_edge(self, "DEFINES", intro)
  85         end
  86
  87         # Set the visibility.
  88         fun visibility=(visibility: String) do
  89                 self["visibility"] = visibility
  90                 if introducer != null then
  91                         introducer.as(not null).visibility = visibility
  92                 end
  93         end
  94
  95         redef fun name=(name: String) do
  96                 super
  97                 if introducer != null then
  98                         introducer.as(not null).name = name
  99                 end
 100         end
 101
 102         redef fun full_name=(full_name: String) do
 103                 super
 104                 if introducer != null then
 105                         introducer.as(not null).full_name = full_name
 106                 end
 107         end
 108
 109         redef fun parent_name=(parent_name: String) do
 110                 super
 111                 if introducer != null then
 112                         introducer.as(not null).parent_name = parent_name
 113                 end
 114         end
 115
 116         # Is the member abstract?
 117         fun is_abstract=(is_abstract: Bool) do
 118                 self["is_abstract"] = is_abstract
 119         end
 120
 121         # Create an instance of `MemberIntroducer` that will be linked to `self`.
 122         protected fun create_introducer: MemberIntroducer is abstract
 123
 124         # Find the nearest reimplementation root.
 125         #
 126         #     var g = new ProjectGraph("foo")
 127         #     var m1 = new Attribute(g)
 128         #     var m2 = new Attribute(g)
 129         #     var m3 = new Attribute(g)
 130         #     #
 131         #     m1.model_id = "1"
 132         #     m1.put_in_graph
 133         #     m2.reimplement("1")
 134         #     m2.put_in_graph
 135         #     assert m1.resolve_introducer == m1.introducer
 136         #     assert m2.resolve_introducer == m1.introducer
 137         #     #
 138         #     m3.model_id = "3"
 139         #     m3.reimplement("3")
 140         #     m3.put_in_graph
 141         #     assert m3.resolve_introducer == null
 142         fun resolve_introducer: nullable MemberIntroducer do
 143                 if introducer == null then
 144                         var member_queue = new List[String]
 145                         var visited = new HashSet[Member]
 146                         var member: Member
 147
 148                         member_queue.add_all(reimplemented)
 149                         while not member_queue.is_empty do
 150                                 member = graph.by_id[member_queue.shift].as(Member)
 151                                 if visited.has(member) then
 152                                         return null
 153                                 else if member.is_intro then
 154                                         return member.introducer
 155                                 else
 156                                         visited.add(member)
 157                                         member_queue.add_all(member.reimplemented)
 158                                 end
 159                         end
 160                         return null
 161                 else
 162                         return introducer
 163                 end
 164         end
 165 end
 166
 167 # An unrecognized member.
 168 #
 169 # Used to simplify the handling of ignored entities.
 170 class UnknownMember
 171         super Member
 172
 173         redef fun put_in_graph do end
 174         redef fun put_edges do end
 175 end
 176
 177 class Method
 178         super Member
 179
 180         # The method’s signature.
 181         var signature: Signature is noinit, writable
 182
 183         init do
 184                 super
 185                 self.labels.add("MMethodDef")
 186                 self["is_intern"] = false # TODO
 187                 self["is_extern"] = false # TODO
 188                 signature = new Signature(graph)
 189                 is_abstract = false
 190         end
 191
 192         # Set the return type.
 193         redef fun static_type=(static_type: nullable TypeEntity) do
 194                 signature.return_type = static_type
 195         end
 196
 197         # Get the return type.
 198         redef fun static_type: nullable TypeEntity do return signature.return_type
 199
 200         redef fun add_parameter(parameter: MemberParameter) do
 201                 signature.parameters.add(parameter)
 202         end
 203
 204         redef fun create_introducer: MemberIntroducer do
 205                 return new MethodIntroducer(graph)
 206         end
 207
 208         redef fun put_in_graph do
 209                 super
 210                 signature.put_in_graph
 211         end
 212
 213         redef fun put_edges do
 214                 super
 215                 graph.add_edge(self, "SIGNATURE", signature)
 216         end
 217 end
 218
 219 class Attribute
 220         super Member
 221
 222         # The declared type.
 223         redef var static_type: nullable TypeEntity = null is writable
 224
 225         init do
 226                 super
 227                 self.labels.add("MAttributeDef")
 228         end
 229
 230         redef fun create_introducer: MemberIntroducer do
 231                 return new AttributeIntroducer(graph)
 232         end
 233
 234         redef fun put_in_graph do
 235                 super
 236                 if static_type != null then
 237                         static_type.as(not null).put_in_graph
 238                 end
 239         end
 240
 241         redef fun put_edges do
 242                 super
 243                 if static_type != null then
 244                         graph.add_edge(self, "TYPE", static_type.as(not null))
 245                 end
 246         end
 247 end
 248
 249 # The `MProperty` node of a root of a reimplementation graph.
 250 abstract class MemberIntroducer
 251         super Entity
 252
 253         init do
 254                 super
 255                 self.labels.add("MProperty")
 256                 self["visibility"] = "public"
 257         end
 258
 259         fun visibility=(visibility: String) do
 260                 self["visibility"] = visibility
 261         end
 262 end
 263
 264 # A `MProperty` node for a method.
 265 class MethodIntroducer
 266         super MemberIntroducer
 267
 268         init do
 269                 super
 270                 self.labels.add("MMethod")
 271                 self["is_init"] = false # TODO
 272         end
 273 end
 274
 275 # A `MProperty` node for an attribute.
 276 class AttributeIntroducer
 277         super MemberIntroducer
 278
 279         init do
 280                 super
 281                 self.labels.add("MAttribute")
 282         end
 283 end
 284
 285 redef class Compound
 286         # Append the specified member.
 287         fun declare_member(member: Member) do end
 288 end