- option_context.add_option(opt_path, opt_only_parse, opt_only_metamodel)
- end
-end
-
-# A model builder knows how to load nit source files and build the associated model
-# The important function is `parse_and_build' that does all the job.
-# The others function can be used for specific tasks
-class ModelBuilder
- # The model where new modules, classes and properties are added
- var model: Model
-
- # The toolcontext used to control the interaction with the user (getting options and displaying messages)
- var toolcontext: ToolContext
-
- # Instantiate a modelbuilder for a model and a toolcontext
- # Important, the options of the toolcontext must be correctly set (parse_option already called)
- init(model: Model, toolcontext: ToolContext)
- do
- self.model = model
- self.toolcontext = toolcontext
-
- # Setup the paths value
- paths.append(toolcontext.opt_path.value)
-
- var path_env = "NIT_PATH".environ
- if not path_env.is_empty then
- paths.append(path_env.split_with(':'))
- end
-
- path_env = "NIT_DIR".environ
- if not path_env.is_empty then
- var libname = "{path_env}/lib"
- if libname.file_exists then paths.add(libname)
- end
-
- var libname = "{sys.program_name.dirname}/../lib"
- if libname.file_exists then paths.add(libname.simplify_path)
- end
-
- # Load and analyze a bunch of modules.
- # `modules' can contains filenames or module names.
- # Imported modules are automatically loaded, builds and analysed.
- # The result is the corresponding built modules.
- # Errors and warnings are printed with the toolcontext.
- #
- # FIXME: Maybe just let the client do the loop (instead of playing with Sequences)
- fun parse_and_build(modules: Sequence[String]): Array[MModule]
- do
- var time0 = get_time
- # Parse and recursively load
- self.toolcontext.info("*** PARSE ***", 1)
- var mmodules = new Array[MModule]
- for a in modules do
- var nmodule = self.load_module(null, a)
- if nmodule == null then continue # Skip error
- mmodules.add(nmodule.mmodule.as(not null))
- end
- var time1 = get_time
- self.toolcontext.info("*** END PARSE: {time1-time0} ***", 2)
-
- self.toolcontext.check_errors
-
- if self.toolcontext.opt_only_parse.value then
- self.toolcontext.info("--only-parse: stop processing", 2)
- return new Array[MModule]
- end
-
- # Build the model
- self.toolcontext.info("*** BUILD MODEL ***", 1)
- self.build_all_classes
- var time2 = get_time
- self.toolcontext.info("*** END BUILD MODEL: {time2-time1} ***", 2)
-
- self.toolcontext.check_errors
-
- return mmodules
- end
-
- # Return a class named `name' visible by the module `mmodule'.
- # Visibility in modules is correctly handled.
- # If no such a class exists, then null is returned.
- # If more than one class exists, then an error on `anode' is displayed and null is returned.
- # FIXME: add a way to handle class name conflict
- fun try_get_mclass_by_name(anode: ANode, mmodule: MModule, name: String): nullable MClass
- do
- var classes = model.get_mclasses_by_name(name)
- if classes == null then
- return null
- end
-
- var res: nullable MClass = null
- for mclass in classes do
- if not mmodule.in_importation <= mclass.intro_mmodule then continue
- if not mmodule.is_visible(mclass.intro_mmodule, mclass.visibility) then continue
- if res == null then
- res = mclass
- else
- error(anode, "Ambigous class name '{name}'; conflict between {mclass.full_name} and {res.full_name}")
- return null
- end
- end
- return res
- end
-
- # Return a property named `name' on the type `mtype' visible in the module `mmodule'.
- # Visibility in modules is correctly handled.
- # Protected properties are returned (it is up to the caller to check and reject protected properties).
- # If no such a property exists, then null is returned.
- # If more than one property exists, then an error on `anode' is displayed and null is returned.
- # FIXME: add a way to handle property name conflict
- fun try_get_mproperty_by_name2(anode: ANode, mmodule: MModule, mtype: MType, name: String): nullable MProperty
- do
- var props = self.model.get_mproperties_by_name(name)
- if props == null then
- return null
- end
-
- var cache = self.try_get_mproperty_by_name2_cache[mmodule, mtype, name]
- if cache != null then return cache
-
- var res: nullable MProperty = null
- var ress: nullable Array[MProperty] = null
- for mprop in props do
- if not mtype.has_mproperty(mmodule, mprop) then continue
- if not mmodule.is_visible(mprop.intro_mclassdef.mmodule, mprop.visibility) then continue
- if res == null then
- res = mprop
- else
- var restype = res.intro_mclassdef.bound_mtype
- var mproptype = mprop.intro_mclassdef.bound_mtype
- if restype.is_subtype(mmodule, null, mproptype) then
- # we keep res
- else if mproptype.is_subtype(mmodule, null, restype) then
- res = mprop
- else
- if ress == null then ress = new Array[MProperty]
- ress.add(mprop)
- end
- end
- end
- if ress != null then
- var restype = res.intro_mclassdef.bound_mtype
- for mprop in ress do
- var mproptype = mprop.intro_mclassdef.bound_mtype
- if not restype.is_subtype(mmodule, null, mproptype) then
- self.error(anode, "Ambigous property name '{name}' for {mtype}; conflict between {mprop.full_name} and {res.full_name}")
- return null
- end
- end
- end
-
- self.try_get_mproperty_by_name2_cache[mmodule, mtype, name] = res
- return res
- end
-
- private var try_get_mproperty_by_name2_cache: HashMap3[MModule, MType, String, nullable MProperty] = new HashMap3[MModule, MType, String, nullable MProperty]
-
-
- # Alias for try_get_mproperty_by_name2(anode, mclassdef.mmodule, mclassdef.mtype, name)
- fun try_get_mproperty_by_name(anode: ANode, mclassdef: MClassDef, name: String): nullable MProperty
- do
- return try_get_mproperty_by_name2(anode, mclassdef.mmodule, mclassdef.bound_mtype, name)
- end
-
- # The list of directories to search for top level modules
- # The list is initially set with :
- # * the toolcontext --path option
- # * the NIT_PATH environment variable
- # * some heuristics including the NIT_DIR environment variable and the progname of the process
- # Path can be added (or removed) by the client
- var paths: Array[String] = new Array[String]
-
- # Get a module by its short name; if required, the module is loaded, parsed and its hierarchies computed.
- # If `mmodule' is set, then the module search starts from it up to the top level (see `paths');
- # if `mmodule' is null then the module is searched in the top level only.
- # If no module exists or there is a name conflict, then an error on `anode' is displayed and null is returned.
- # FIXME: add a way to handle module name conflict
- fun get_mmodule_by_name(anode: ANode, mmodule: nullable MModule, name: String): nullable MModule
- do
- var origmmodule = mmodule
- var modules = model.get_mmodules_by_name(name)
-
- var tries = new Array[String]
-
- var lastmodule = mmodule
- while mmodule != null do
- var dirname = mmodule.location.file.filename.dirname
-
- # Determine the owner
- var owner: nullable MModule
- if dirname.basename("") != mmodule.name then
- owner = mmodule.direct_owner
- else
- owner = mmodule
- end
-
- # First, try the already known nested modules
- if modules != null then
- for candidate in modules do
- if candidate.direct_owner == owner then
- return candidate
- end
- end
- end
-
- # Second, try the directory to find a file
- var try_file = dirname + "/" + name + ".nit"
- tries.add try_file
- if try_file.file_exists then
- var res = self.load_module(owner, try_file.simplify_path)
- if res == null then return null # Forward error
- return res.mmodule.as(not null)
- end
-
- # Third, try if the requested module is itself an owner
- try_file = dirname + "/" + name + "/" + name + ".nit"
- if try_file.file_exists then
- var res = self.load_module(owner, try_file.simplify_path)
- if res == null then return null # Forward error
- return res.mmodule.as(not null)
- end
-
- lastmodule = mmodule
- mmodule = mmodule.direct_owner
- end
-
- if modules != null then
- for candidate in modules do
- if candidate.direct_owner == null then
- return candidate
- end
- end
- end
-
- # Look at some known directories
- var lookpaths = self.paths
-
- # Look in the directory of the last module also (event if not in the path)
- if lastmodule != null then
- var dirname = lastmodule.location.file.filename.dirname
- if dirname.basename("") == lastmodule.name then
- dirname = dirname.dirname
- end
- if not lookpaths.has(dirname) then
- lookpaths = lookpaths.to_a
- lookpaths.add(dirname)
- end
- end
-
- var candidate: nullable String = null
- for dirname in lookpaths do
- var try_file = (dirname + "/" + name + ".nit").simplify_path
- tries.add try_file
- if try_file.file_exists then
- if candidate == null then
- candidate = try_file
- else if candidate != try_file then
- error(anode, "Error: conflicting module file for {name}: {candidate} {try_file}")
- end
- end
- try_file = (dirname + "/" + name + "/" + name + ".nit").simplify_path
- if try_file.file_exists then
- if candidate == null then
- candidate = try_file
- else if candidate != try_file then
- error(anode, "Error: conflicting module file for {name}: {candidate} {try_file}")
- end
- end
- end
- if candidate == null then
- if origmmodule != null then
- error(anode, "Error: cannot find module {name} from {origmmodule}. tried {tries.join(", ")}")
- else
- error(anode, "Error: cannot find module {name}. tried {tries.join(", ")}")
- end
- return null
- end
- var res = self.load_module(mmodule, candidate)
- if res == null then return null # Forward error
- return res.mmodule.as(not null)
- end
-
- # Try to load a module using a path.
- # Display an error if there is a problem (IO / lexer / parser) and return null
- # Note: usually, you do not need this method, use `get_mmodule_by_name` instead.
- fun load_module(owner: nullable MModule, filename: String): nullable AModule
- do
- if not filename.file_exists then
- self.toolcontext.error(null, "Error: file {filename} not found.")
- return null
- end
-
- var x = if owner != null then owner.to_s else "."
- self.toolcontext.info("load module {filename} in {x}", 2)
-
- # Load the file
- var file = new IFStream.open(filename)
- var lexer = new Lexer(new SourceFile(filename, file))
- var parser = new Parser(lexer)
- var tree = parser.parse
- file.close
-
- # Handle lexer and parser error
- var nmodule = tree.n_base
- if nmodule == null then
- var neof = tree.n_eof
- assert neof isa AError
- error(neof, neof.message)
- return null
- end
-
- # Check the module name
- var mod_name = filename.basename(".nit")
- var decl = nmodule.n_moduledecl
- if decl == null then
- #warning(nmodule, "Warning: Missing 'module' keyword") #FIXME: NOT YET FOR COMPATIBILITY
- else
- var decl_name = decl.n_name.n_id.text
- if decl_name != mod_name then
- error(decl.n_name, "Error: module name missmatch; declared {decl_name} file named {mod_name}")
- end
- end
-
- # Create the module
- var mmodule = new MModule(model, owner, mod_name, nmodule.location)
- nmodule.mmodule = mmodule
- nmodules.add(nmodule)
- self.mmodule2nmodule[mmodule] = nmodule
-
- build_module_importation(nmodule)
-
- return nmodule
- end
-
- # Analysis the module importation and fill the module_importation_hierarchy
- private fun build_module_importation(nmodule: AModule)
- do
- if nmodule.is_importation_done then return
- var mmodule = nmodule.mmodule.as(not null)
- var stdimport = true
- var imported_modules = new Array[MModule]
- for aimport in nmodule.n_imports do
- stdimport = false
- if not aimport isa AStdImport then
- continue
- end
- var mod_name = aimport.n_name.n_id.text
- var sup = self.get_mmodule_by_name(aimport.n_name, mmodule, mod_name)
- if sup == null then continue # Skip error
- imported_modules.add(sup)
- var mvisibility = aimport.n_visibility.mvisibility
- mmodule.set_visibility_for(sup, mvisibility)
- end
- if stdimport then
- var mod_name = "standard"
- var sup = self.get_mmodule_by_name(nmodule, null, mod_name)
- if sup != null then # Skip error
- imported_modules.add(sup)
- mmodule.set_visibility_for(sup, public_visibility)
- end
- end
- self.toolcontext.info("{mmodule} imports {imported_modules.join(", ")}", 3)
- mmodule.set_imported_mmodules(imported_modules)
- nmodule.is_importation_done = true
- end
-
- # All the loaded modules
- var nmodules: Array[AModule] = new Array[AModule]
-
- # Build the classes of all modules `nmodules'.
- private fun build_all_classes
- do
- for nmodule in self.nmodules do
- build_classes(nmodule)
- end
- end
-
- # Visit the AST and create the MClass objects
- private fun build_a_mclass(nmodule: AModule, nclassdef: AClassdef)
- do
- var mmodule = nmodule.mmodule.as(not null)
-
- var name: String
- var nkind: nullable AClasskind
- var mkind: MClassKind
- var nvisibility: nullable AVisibility
- var mvisibility: nullable MVisibility
- var arity = 0
- if nclassdef isa AStdClassdef then
- name = nclassdef.n_id.text
- nkind = nclassdef.n_classkind
- mkind = nkind.mkind
- nvisibility = nclassdef.n_visibility
- mvisibility = nvisibility.mvisibility
- arity = nclassdef.n_formaldefs.length
- else if nclassdef isa ATopClassdef then
- name = "Object"
- nkind = null
- mkind = interface_kind
- nvisibility = null
- mvisibility = public_visibility
- else if nclassdef isa AMainClassdef then
- name = "Sys"
- nkind = null
- mkind = concrete_kind
- nvisibility = null
- mvisibility = public_visibility