+ fun owner: User do return new User.from_json(api, json["owner"].as(JsonObject))
+
+ # Set repo owner
+ fun owner=(owner: User) do json["owner"] = owner.json
+
+ # List of branches associated with their names.
+ fun branches: Map[String, Branch] do
+ api.message(1, "Get branches for {full_name}")
+ var array = api.get("repos/{full_name}/branches")
+ var res = new HashMap[String, Branch]
+ if not array isa JsonArray then return res
+ for obj in array do
+ if not obj isa JsonObject then continue
+ var name = obj["name"].as(String)
+ res[name] = new Branch.from_json(api, self, obj)
+ end
+ return res
+ end
+
+ # List of issues associated with their ids.
+ fun issues: Map[Int, Issue] do
+ api.message(1, "Get issues for {full_name}")
+ var res = new HashMap[Int, Issue]
+ var issue = last_issue
+ if issue == null then return res
+ res[issue.number] = issue
+ while issue.number > 1 do
+ issue = api.load_issue(self, issue.number - 1)
+ assert issue isa Issue
+ res[issue.number] = issue
+ end
+ return res
+ end
+
+ # Search issues in this repo form an advanced query.
+ #
+ # Example:
+ #
+ # ~~~nitish
+ # var issues = repo.search_issues("is:open label:need_review")
+ # ~~~
+ #
+ # See <https://developer.github.com/v3/search/#search-issues>.
+ fun search_issues(query: String): nullable Array[Issue] do
+ query = "search/issues?q={query} repo:{full_name}"
+ var response = api.get(query)
+ if api.was_error then return null
+ var arr = response.as(JsonObject)["items"].as(JsonArray)
+ var res = new Array[Issue]
+ for obj in arr do
+ res.add new Issue.from_json(api, self, obj.as(JsonObject))
+ end
+ return res
+ end
+
+ # Get the last published issue.
+ fun last_issue: nullable Issue do
+ var array = api.get("repos/{full_name}/issues")
+ if not array isa JsonArray then return null
+ if array.is_empty then return null
+ var obj = array.first
+ if not obj isa JsonObject then return null
+ return new Issue.from_json(api, self, obj)
+ end
+
+ # List of labels associated with their names.
+ fun labels: Map[String, Label] do
+ api.message(1, "Get labels for {full_name}")
+ var array = api.get("repos/{full_name}/labels")
+ var res = new HashMap[String, Label]
+ if not array isa JsonArray then return res
+ for obj in array do
+ if not obj isa JsonObject then continue
+ var name = obj["name"].as(String)
+ res[name] = new Label.from_json(api, self, obj)
+ end
+ return res
+ end
+
+ # List of milestones associated with their ids.
+ fun milestones: Map[Int, Milestone] do
+ api.message(1, "Get milestones for {full_name}")
+ var array = api.get("repos/{full_name}/milestones")
+ var res = new HashMap[Int, Milestone]
+ if array isa JsonArray then
+ for obj in array do
+ if not obj isa JsonObject then continue
+ var number = obj["number"].as(Int)
+ res[number] = new Milestone.from_json(api, self, obj)
+ end
+ end
+ return res
+ end
+
+ # List of pull-requests associated with their ids.
+ #
+ # Implementation notes: because PR numbers are not consecutive,
+ # PR are loaded from pages.
+ # See: https://developer.github.com/v3/pulls/#list-pull-requests
+ fun pulls: Map[Int, PullRequest] do
+ api.message(1, "Get pulls for {full_name}")
+ var res = new HashMap[Int, PullRequest]
+ var page = 1
+ var array = api.get("{key}/pulls?page={page}").as(JsonArray)
+ while not array.is_empty do
+ for obj in array do
+ if not obj isa JsonObject then continue
+ var number = obj["number"].as(Int)
+ res[number] = new PullRequest.from_json(api, self, obj)
+ end
+ page += 1
+ array = api.get("{key}/pulls?page={page}").as(JsonArray)
+ end
+ return res
+ end
+
+ # List of contributor related statistics.
+ fun contrib_stats: Array[ContributorStats] do
+ api.message(1, "Get contributor stats for {full_name}")
+ var res = new Array[ContributorStats]
+ var array = api.get("{key}/stats/contributors")
+ if array isa JsonArray then
+ for obj in array do
+ res.add new ContributorStats.from_json(api, obj.as(JsonObject))
+ end
+ end
+ return res
+ end
+
+ # Repo default branch.
+ fun default_branch: Branch do
+ var name = json["default_branch"].as(String)
+ var branch = api.load_branch(self, name)
+ assert branch isa Branch
+ return branch
+ end
+
+ # Set the default branch
+ fun default_branch=(branch: Branch) do json["default_branch"] = branch.json
+end
+
+# A `RepoEntity` is something contained in a `Repo`.
+abstract class RepoEntity
+ super GithubEntity
+
+ # Repo that contains `self`.
+ var repo: Repo
+
+ # Init `self` from a `json` object.
+ init from_json(api: GithubAPI, repo: Repo, json: JsonObject) do
+ init(api, repo)
+ self.json = json
+ end
+end
+
+# A Github branch.
+#
+# Should be accessed from `GithubAPI::load_branch`.
+#
+# See <https://developer.github.com/v3/repos/#list-branches>.
+class Branch
+ super RepoEntity
+
+ redef var key is lazy do return "{repo.key}/branches/{name}"
+
+ # Branch name.
+ var name: String
+
+ redef init from_json(api, repo, json) do
+ self.name = json["name"].as(String)
+ super
+ end
+
+ # Get the last commit of `self`.
+ fun commit: Commit do return new Commit.from_json(api, repo, json["commit"].as(JsonObject))
+
+ # Set the last commit
+ fun commit=(commit: Commit) do json["commit"] = commit.json
+
+ # List all commits in `self`.
+ #
+ # This can be long depending on the branch size.
+ # Commit are returned in an unspecified order.
+ fun commits: Array[Commit] do
+ var res = new Array[Commit]
+ var done = new HashSet[String]
+ var todos = new Array[Commit]
+ todos.add commit
+ while not todos.is_empty do
+ var commit = todos.pop
+ if done.has(commit.sha) then continue
+ done.add commit.sha
+ res.add commit
+ for parent in commit.parents do
+ todos.add parent
+ end
+ end
+ return res
+ end
+end
+
+# A Github commit.
+#
+# Should be accessed from `GithubAPI::load_commit`.
+#
+# See <https://developer.github.com/v3/repos/commits/>.
+class Commit
+ super RepoEntity
+
+ redef var key is lazy do return "{repo.key}/commits/{sha}"
+
+ # Commit SHA.
+ var sha: String
+
+ redef init from_json(api, repo, json) do
+ self.sha = json["sha"].as(String)
+ super
+ end
+
+ # Parent commits of `self`.
+ fun parents: Array[Commit] do
+ var res = new Array[Commit]
+ var parents = json.get_or_null("parents")
+ if not parents isa JsonArray then return res
+ for obj in parents do
+ if not obj isa JsonObject then continue
+ res.add(api.load_commit(repo, obj["sha"].as(String)).as(not null))
+ end
+ return res
+ end
+
+ # Set parent commits.
+ fun parents=(parents: Array[Commit]) do
+ var res = new JsonArray
+ for parent in parents do res.add parent.json
+ json["parents"] = res
+ end
+
+ # Author of the commit.
+ fun author: nullable User do
+ var user = json.get_or_null("author")
+ if user isa JsonObject then return new User.from_json(api, user)
+ return null
+ end
+
+ # Set commit author.
+ fun author=(user: nullable User) do
+ if user == null then
+ json["author"] = null
+ else
+ json["author"] = user.json
+ end
+ end
+
+ # Committer of the commit.
+ fun committer: nullable User do
+ var user = json.get_or_null("author")
+ if user isa JsonObject then return new User.from_json(api, user)
+ return null
+ end
+
+ # Set commit committer.
+ fun committer=(user: nullable User) do
+ if user == null then
+ json["committer"] = null
+ else
+ json["committer"] = user.json
+ end
+ end
+
+ # Authoring date as ISODate.
+ fun author_date: ISODate do
+ var commit = json["commit"].as(JsonObject)
+ var author = commit["author"].as(JsonObject)
+ return new ISODate.from_string(author["date"].as(String))
+ end
+
+ # Commit date as ISODate.
+ fun commit_date: ISODate do
+ var commit = json["commit"].as(JsonObject)
+ var author = commit["committer"].as(JsonObject)
+ return new ISODate.from_string(author["date"].as(String))
+ end
+
+ # List files staged in this commit.
+ fun files: Array[GithubFile] do
+ var res = new Array[GithubFile]
+ var files = json.get_or_null("files")
+ if not files isa JsonArray then return res
+ for obj in files do
+ res.add(new GithubFile(obj.as(JsonObject)))
+ end
+ return res
+ end
+
+ # Set commit files.
+ fun files=(files: Array[GithubFile]) do
+ var res = new JsonArray
+ for file in files do res.add file.json
+ json["files"] = res
+ end
+
+ # Commit message.
+ fun message: String do return json["commit"].as(JsonObject)["message"].as(String)
+end
+
+# A Github issue.
+#
+# Should be accessed from `GithubAPI::load_issue`.
+#
+# See <https://developer.github.com/v3/issues/>.
+class Issue
+ super RepoEntity
+
+ redef var key is lazy do return "{repo.key}/issues/{number}"
+
+ # Issue Github ID.
+ var number: Int
+
+ redef init from_json(api, repo, json) do
+ self.number = json["number"].as(Int)
+ super
+ end
+
+ # Issue id.
+ fun id: Int do return json["id"].as(Int)
+
+ # Set issue id.
+ fun id=(id: Int) do json["id"] = id
+
+ # Issue title.
+ fun title: String do return json["title"].as(String)
+
+ # Set issue title
+ fun title=(title: String) do json["title"] = title
+
+ # User that created this issue.
+ fun user: User do return new User.from_json(api, json["user"].as(JsonObject))
+
+ # Set issue creator.
+ fun user=(user: User) do json["user"] = user.json
+
+ # List of labels on this issue associated to their names.
+ fun labels: Map[String, Label] do
+ var res = new HashMap[String, Label]
+ var lbls = json.get_or_null("labels")
+ if not lbls isa JsonArray then return res
+ for obj in lbls do
+ if not obj isa JsonObject then continue
+ var name = obj["name"].as(String)
+ res[name] = new Label.from_json(api, repo, obj)
+ end
+ return res
+ end
+
+ # State of the issue on Github.
+ fun state: String do return json["state"].as(String)
+
+ # Set the state of this issue.
+ fun state=(state: String) do json["state"] = state
+
+ # Is the issue locked?
+ fun locked: Bool do return json["locked"].as(Bool)
+
+ # Set issue locked state.
+ fun locked=(locked: Bool) do json["locked"] = locked
+
+ # Assigned `User` (if any).
+ fun assignee: nullable User do
+ var assignee = json.get_or_null("assignee")
+ if assignee isa JsonObject then return new User.from_json(api, assignee)
+ return null
+ end
+
+ # Set issue assignee.
+ fun assignee=(user: nullable User) do
+ if user == null then
+ json["assignee"] = null
+ else
+ json["assignee"] = user.json
+ end
+ end
+
+ # `Milestone` (if any).
+ fun milestone: nullable Milestone do
+ var milestone = json.get_or_null("milestone")
+ if milestone isa JsonObject then return new Milestone.from_json(api, repo, milestone)
+ return null
+ end
+
+ # Set issue milestone.
+ fun milestone=(milestone: nullable Milestone) do
+ if milestone == null then
+ json["milestone"] = null
+ else
+ json["milestone"] = milestone.json
+ end
+ end
+
+ # List of comments made on this issue.
+ fun comments: Array[IssueComment] do
+ var res = new Array[IssueComment]
+ var count = comments_count
+ var page = 1
+ var array = api.get("{key}/comments?page={page}")
+ if not array isa JsonArray then
+ return res
+ end
+ while not array.is_empty and res.length < count do
+ for obj in array do
+ if not obj isa JsonObject then continue
+ var id = obj["id"].as(Int)
+ var comment = api.load_issue_comment(repo, id)
+ if comment == null then continue
+ res.add(comment)
+ end
+ page += 1
+ var json = api.get("{key}/comments?page={page}")
+ if not json isa JsonArray then
+ return res
+ end
+ array = json
+ end
+ return res
+ end
+
+ # Number of comments on this issue.
+ fun comments_count: Int do return json["comments"].as(Int)
+
+ # Creation time in ISODate format.
+ fun created_at: ISODate do return new ISODate.from_string(json["created_at"].as(String))
+
+ # Set issue creation time.
+ fun created_at=(created_at: nullable ISODate) do
+ if created_at == null then
+ json["created_at"] = null
+ else
+ json["created_at"] = created_at.to_s
+ end
+ end
+
+ # Last update time in ISODate format (if any).
+ fun updated_at: nullable ISODate do
+ var res = json.get_or_null("updated_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set issue last update time.
+ fun updated_at=(updated_at: nullable ISODate) do
+ if updated_at == null then
+ json["updated_at"] = null
+ else
+ json["updated_at"] = updated_at.to_s
+ end
+ end
+
+ # Close time in ISODate format (if any).
+ fun closed_at: nullable ISODate do
+ var res = json.get_or_null("closed_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set issue close time.
+ fun closed_at=(closed_at: nullable ISODate) do
+ if closed_at == null then
+ json["closed_at"] = null
+ else
+ json["closed_at"] = closed_at.to_s
+ end
+ end
+
+ # TODO link to pull request
+
+ # Full description of the issue.
+ fun body: String do return json["body"].as(String)
+
+ # Set description body
+ fun body=(body: String) do json["body"] = body
+
+ # List of events on this issue.
+ fun events: Array[IssueEvent] do
+ var res = new Array[IssueEvent]
+ var page = 1
+ var array = api.get("{key}/events?page={page}")
+ if not array isa JsonArray then return res
+ while not array.is_empty do
+ for obj in array do
+ if not obj isa JsonObject then continue
+ res.add new IssueEvent.from_json(api, repo, obj)
+ end
+ page += 1
+ array = api.get("{key}/events?page={page}").as(JsonArray)
+ end
+ return res
+ end
+
+ # User that closed this issue (if any).
+ fun closed_by: nullable User do
+ var closer = json.get_or_null("closed_by")
+ if closer isa JsonObject then return new User.from_json(api, closer)
+ return null
+ end
+
+ # Set user that closed the issue.
+ fun closed_by=(user: nullable User) do
+ if user == null then
+ json["closed_by"] = null
+ else
+ json["closed_by"] = user.json
+ end
+ end
+
+ # Is this issue linked to a pull request?
+ fun is_pull_request: Bool do return json.has_key("pull_request")
+end
+
+# A Github pull request.
+#
+# Should be accessed from `GithubAPI::load_pull`.
+#
+# PullRequest are basically Issues with more data.
+# See <https://developer.github.com/v3/pulls/>.
+class PullRequest
+ super Issue
+
+ redef var key is lazy do return "{repo.key}/pulls/{number}"
+
+ # Merge time in ISODate format (if any).
+ fun merged_at: nullable ISODate do
+ var res = json.get_or_null("merged_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set pull request merge time.
+ fun merged_at=(merged_at: nullable ISODate) do
+ if merged_at == null then
+ json["merged_at"] = null
+ else
+ json["merged_at"] = merged_at.to_s
+ end
+ end
+
+ # Merge commit SHA.
+ fun merge_commit_sha: String do return json["merge_commit_sha"].as(String)
+
+ # Set merge_commit_sha
+ fun merge_commit_sha=(sha: String) do json["merge_commit_sha"] = sha
+
+ # Count of comments made on the pull request diff.
+ fun review_comments: Int do return json["review_comments"].as(Int)
+
+ # Set review_comments
+ fun review_comments=(count: Int) do json["review_comments"] = count
+
+ # Pull request head (can be a commit SHA or a branch name).
+ fun head: PullRef do
+ var json = json["head"].as(JsonObject)
+ return new PullRef(api, json)
+ end
+
+ # Set head
+ fun head=(head: PullRef) do json["head"] = head.json
+
+ # Pull request base (can be a commit SHA or a branch name).
+ fun base: PullRef do
+ var json = json["base"].as(JsonObject)
+ return new PullRef(api, json)
+ end
+
+ # Set base
+ fun base=(base: PullRef) do json["base"] = base.json
+
+ # Is this pull request merged?
+ fun merged: Bool do return json["merged"].as(Bool)
+
+ # Set merged
+ fun merged=(merged: Bool) do json["merged"] = merged
+
+ # Is this pull request mergeable?
+ fun mergeable: Bool do return json["mergeable"].as(Bool)
+
+ # Set mergeable
+ fun mergeable=(mergeable: Bool) do json["mergeable"] = mergeable
+
+ # Mergeable state of this pull request.
+ #
+ # See <https://developer.github.com/v3/pulls/#list-pull-requests>.
+ fun mergeable_state: Int do return json["mergeable_state"].as(Int)
+
+ # Set mergeable_state
+ fun mergeable_state=(mergeable_state: Int) do json["mergeable_state"] = mergeable_state
+
+ # User that merged this pull request (if any).
+ fun merged_by: nullable User do
+ var merger = json.get_or_null("merged_by")
+ if merger isa JsonObject then return new User.from_json(api, merger)
+ return null
+ end
+
+ # Set merged_by.
+ fun merged_by=(merged_by: nullable User) do
+ if merged_by == null then
+ json["merged_by"] = null
+ else
+ json["merged_by"] = merged_by.json
+ end
+ end
+
+ # Count of commits in this pull request.
+ fun commits: Int do return json["commits"].as(Int)
+
+ # Set commits
+ fun commits=(commits: Int) do json["commits"] = commits
+
+ # Added line count.
+ fun additions: Int do return json["additions"].as(Int)
+
+ # Set additions
+ fun additions=(additions: Int) do json["additions"] = additions
+
+ # Deleted line count.
+ fun deletions: Int do return json["deletions"].as(Int)
+
+ # Set deletions
+ fun deletions=(deletions: Int) do json["deletions"] = deletions
+
+ # Changed files count.
+ fun changed_files: Int do return json["changed_files"].as(Int)
+
+ # Set changed_files
+ fun changed_files=(changed_files: Int) do json["changed_files"] = changed_files
+end
+
+# A pull request reference (used for head and base).
+class PullRef
+
+ # Api instance that maintains self.
+ var api: GithubAPI
+
+ # JSON representation.
+ var json: JsonObject
+
+ # Label pointed by `self`.
+ fun labl: String do return json["label"].as(String)
+
+ # Set labl
+ fun labl=(labl: String) do json["label"] = labl
+
+ # Reference pointed by `self`.
+ fun ref: String do return json["ref"].as(String)
+
+ # Set ref
+ fun ref=(ref: String) do json["ref"] = ref
+
+ # Commit SHA pointed by `self`.
+ fun sha: String do return json["sha"].as(String)
+
+ # Set sha
+ fun sha=(sha: String) do json["sha"] = sha
+
+ # User pointed by `self`.
+ fun user: User do
+ return new User.from_json(api, json["user"].as(JsonObject))
+ end
+
+ # Set user
+ fun user=(user: User) do json["user"] = user.json
+
+ # Repo pointed by `self`.
+ fun repo: Repo do
+ return new Repo.from_json(api, json["repo"].as(JsonObject))
+ end
+
+ # Set repo
+ fun repo=(repo: Repo) do json["repo"] = repo.json
+end
+
+# A Github label.
+#
+# Should be accessed from `GithubAPI::load_label`.
+#
+# See <https://developer.github.com/v3/issues/labels/>.
+class Label
+ super RepoEntity
+
+ redef var key is lazy do return "{repo.key}/labels/{name}"
+
+ # Label name.
+ var name: String
+
+ redef init from_json(api, repo, json) do
+ self.name = json["name"].as(String)
+ super
+ end
+
+ # Label color code.
+ fun color: String do return json["color"].as(String)
+
+ # Set color
+ fun color=(color: String) do json["color"] = color
+end
+
+# A Github milestone.
+#
+# Should be accessed from `GithubAPI::load_milestone`.
+#
+# See <https://developer.github.com/v3/issues/milestones/>.
+class Milestone
+ super RepoEntity
+
+ redef var key is lazy do return "{repo.key}/milestones/{number}"
+
+ # The milestone id on Github.
+ var number: Int
+
+ redef init from_json(api, repo, json) do
+ super
+ self.number = json["number"].as(Int)
+ end
+
+ # Milestone title.
+ fun title: String do return json["title"].as(String)
+
+ # Set title
+ fun title=(title: String) do json["title"] = title
+
+ # Milestone long description.
+ fun description: String do return json["description"].as(String)
+
+ # Set description
+ fun description=(description: String) do json["description"] = description
+
+ # Count of opened issues linked to this milestone.
+ fun open_issues: Int do return json["open_issues"].as(Int)
+
+ # Set open_issues
+ fun open_issues=(open_issues: Int) do json["open_issues"] = open_issues
+
+ # Count of closed issues linked to this milestone.
+ fun closed_issues: Int do return json["closed_issues"].as(Int)
+
+ # Set closed_issues
+ fun closed_issues=(closed_issues: Int) do json["closed_issues"] = closed_issues
+
+ # Milestone state.
+ fun state: String do return json["state"].as(String)
+
+ # Set state
+ fun state=(state: String) do json["state"] = state
+
+ # Creation time in ISODate format.
+ fun created_at: ISODate do
+ return new ISODate.from_string(json["created_at"].as(String))
+ end
+
+ # Set created_at
+ fun created_at=(created_at: ISODate) do json["created_at"] = created_at.to_s
+
+ # User that created this milestone.
+ fun creator: User do
+ return new User.from_json(api, json["creator"].as(JsonObject))
+ end
+
+ # Set creator
+ fun creator=(creator: User) do json["creator"] = creator.json
+
+ # Due time in ISODate format (if any).
+ fun due_on: nullable ISODate do
+ var res = json.get_or_null("updated_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set due_on.
+ fun due_on=(due_on: nullable ISODate) do
+ if due_on == null then
+ json["due_on"] = null
+ else
+ json["due_on"] = due_on.to_s
+ end
+ end
+
+ # Update time in ISODate format (if any).
+ fun updated_at: nullable ISODate do
+ var res = json.get_or_null("updated_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set updated_at.
+ fun updated_at=(updated_at: nullable ISODate) do
+ if updated_at == null then
+ json["updated_at"] = null
+ else
+ json["updated_at"] = updated_at.to_s
+ end
+ end
+
+ # Close time in ISODate format (if any).
+ fun closed_at: nullable ISODate do
+ var res = json.get_or_null("closed_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set closed_at.
+ fun closed_at=(closed_at: nullable ISODate) do
+ if closed_at == null then
+ json["closed_at"] = null
+ else
+ json["closed_at"] = closed_at.to_s
+ end
+ end
+end
+
+# A Github comment
+#
+# There is two kinds of comments:
+#
+# * `CommitComment` are made on a commit page.
+# * `IssueComment` are made on an issue or pull request page.
+# * `ReviewComment` are made on the diff associated to a pull request.
+abstract class Comment
+ super RepoEntity
+
+ # Identifier of this comment.
+ var id: Int
+
+ redef init from_json(api, repo, json) do
+ self.id = json["id"].as(Int)
+ super
+ end
+
+ # User that made this comment.
+ fun user: User do
+ return new User.from_json(api, json["user"].as(JsonObject))
+ end
+
+ # Set user
+ fun user=(user: User) do json["user"] = user.json
+
+ # Creation time in ISODate format.
+ fun created_at: ISODate do
+ return new ISODate.from_string(json["created_at"].as(String))
+ end
+
+ # Set created_at
+ fun created_at=(created_at: ISODate) do json["created_at"] = created_at.to_s
+
+ # Last update time in ISODate format (if any).
+ fun updated_at: nullable ISODate do
+ var res = json.get_or_null("updated_at")
+ if res isa String then return new ISODate.from_string(res)
+ return null
+ end
+
+ # Set updated_at.
+ fun updated_at=(updated_at: nullable ISODate) do
+ if updated_at == null then
+ json["updated_at"] = null
+ else
+ json["updated_at"] = updated_at.to_s
+ end
+ end
+
+ # Comment body text.
+ fun body: String do return json["body"].as(String)
+
+ # Set body
+ fun body=(body: String) do json["body"] = body
+
+ # Does the comment contain an acknowledgement (+1)
+ fun is_ack: Bool
+ do
+ return body.has("\\+1\\b".to_re) or body.has(":+1:") or body.has(":shipit:")
+ end
+end
+
+# A comment made on a commit.
+class CommitComment
+ super Comment
+
+ redef var key is lazy do return "{repo.key}/comments/{id}"
+
+ # Commented commit.
+ fun commit: Commit do
+ return api.load_commit(repo, json["commit_id"].as(String)).as(not null)
+ end
+
+ # Set commit
+ fun commit=(commit: Commit) do json["commit_id"] = commit.json
+
+ # Position of the comment on the line.
+ fun position: nullable String do
+ var res = json.get_or_null("position")
+ if res isa String then return res
+ return null
+ end
+
+ # Set position.
+ fun position=(position: nullable String) do json["position"] = position
+
+ # Line of the comment.
+ fun line: nullable String do
+ var res = json.get_or_null("line")
+ if res isa String then return res
+ return null
+ end
+
+ # Set line.
+ fun line=(line: nullable String) do json["line"] = line
+
+ # Path of the commented file.
+ fun path: String do return json["path"].as(String)
+
+ # Set path.
+ fun path=(path: String) do json["path"] = path
+end
+
+# Comments made on Github issue and pull request pages.
+#
+# Should be accessed from `GithubAPI::load_issue_comment`.
+#
+# See <https://developer.github.com/v3/issues/comments/>.
+class IssueComment
+ super Comment
+
+ redef var key is lazy do return "{repo.key}/issues/comments/{id}"
+
+ # Issue that contains `self`.
+ fun issue: Issue do
+ var number = issue_url.split("/").last.to_i
+ return api.load_issue(repo, number).as(not null)