contrib/nitiwiki/src/wiki_html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML wiki rendering
  16 module wiki_html
  17
  18 import wiki_links
  19 import markdown::decorators
  20
  21 redef class Nitiwiki
  22
  23         # Render HTML output looking for changes in the markdown sources.
  24         redef fun render do
  25                 super
  26                 if not root_section.is_dirty and not force_render then return
  27                 var out_dir = expand_path(config.root_dir, config.out_dir)
  28                 out_dir.mkdir
  29                 copy_assets
  30                 root_section.add_child make_sitemap
  31                 root_section.render
  32         end
  33
  34         # Copy the asset directory to the (public) output directory.
  35         private fun copy_assets do
  36                 var src = expand_path(config.root_dir, config.assets_dir)
  37                 var out = expand_path(config.root_dir, config.out_dir)
  38                 if need_render(src, expand_path(out, config.assets_dir)) then
  39                         if src.file_exists then sys.system "cp -R {src} {out}"
  40                 end
  41         end
  42
  43         # Build the wiki sitemap page.
  44         private fun make_sitemap: WikiSitemap do
  45                 var sitemap = new WikiSitemap(self, "sitemap")
  46                 sitemap.is_dirty = true
  47                 return sitemap
  48         end
  49
  50         # Markdown processor used for inline element such as titles in TOC.
  51         private var inline_processor: MarkdownProcessor is lazy do
  52                 var proc = new MarkdownProcessor
  53                 proc.emitter.decorator = new InlineDecorator
  54                 return proc
  55         end
  56
  57         # Inline markdown (remove h1, p, ... elements).
  58         private fun inline_md(md: Writable): Writable do
  59                 return inline_processor.process(md.write_to_string)
  60         end
  61 end
  62
  63 redef class WikiEntry
  64         # Get a `<a>` template link to `self`
  65         fun tpl_link: Writable do
  66                 return "<a href=\"{url}\">{title}</a>"
  67         end
  68 end
  69
  70 redef class WikiSection
  71
  72         # Output directory (where to ouput the HTML pages for this section).
  73         redef fun out_path: String do
  74                 if parent == null then
  75                         return wiki.config.out_dir
  76                 else
  77                         return wiki.expand_path(parent.out_path, name)
  78                 end
  79         end
  80
  81         redef fun render do
  82                 if not is_dirty and not wiki.force_render then return
  83                 if is_new then
  84                         out_full_path.mkdir
  85                 else
  86                         sys.system "touch {out_full_path}"
  87                 end
  88                 if has_source then
  89                         wiki.message("Render section {out_path}", 1)
  90                         copy_files
  91                 end
  92                 var index = self.index
  93                 if index isa WikiSectionIndex then
  94                         wiki.message("Render auto-index for section {out_path}", 1)
  95                         index.is_dirty = true
  96                         add_child index
  97                 end
  98                 super
  99         end
 100
 101         # Copy attached files from `src_path` to `out_path`.
 102         private fun copy_files do
 103                 assert has_source
 104                 var dir = src_full_path.to_s
 105                 for name in dir.files do
 106                         if name == wiki.config_filename then continue
 107                         if name.has_suffix(".md") then continue
 108                         if has_child(name) then continue
 109                         var src = wiki.expand_path(dir, name)
 110                         var out = wiki.expand_path(out_full_path, name)
 111                         if not wiki.need_render(src, out) then continue
 112                         sys.system "cp -R {src} {out_full_path}"
 113                 end
 114         end
 115
 116         redef fun tpl_link do return index.tpl_link
 117
 118         # Render the section hierarchy as a html tree.
 119         #
 120         # `limit` is used to specify the max-depth of the tree.
 121         #
 122         # The generated tree will be something like this:
 123         #
 124         # ~~~html
 125         # <ul>
 126         #  <li>section 1</li>
 127         #  <li>section 2
 128         #   <ul>
 129         #    <li>section 2.1</li>
 130         #    <li>section 2.2</li>
 131         #   </ul>
 132         #  </li>
 133         # </ul>
 134         # ~~~
 135         fun tpl_tree(limit: Int): Template do
 136                 return tpl_tree_intern(limit, 1)
 137         end
 138
 139         # Build the template tree for this section recursively.
 140         protected fun tpl_tree_intern(limit, count: Int): Template do
 141                 var out = new Template
 142                 var index = index
 143                 out.add "<li>"
 144                 out.add tpl_link
 145                 if (limit < 0 or count < limit) and
 146                    (children.length > 1 or (children.length == 1)) then
 147                         out.add " <ul>"
 148                         for child in children.values do
 149                                 if child == index then continue
 150                                 if child isa WikiArticle then
 151                                         out.add "<li>"
 152                                         out.add child.tpl_link
 153                                         out.add "</li>"
 154                                 else if child isa WikiSection and not child.is_hidden then
 155                                         out.add child.tpl_tree_intern(limit, count + 1)
 156                                 end
 157                         end
 158                         out.add " </ul>"
 159                 end
 160                 out.add "</li>"
 161                 return out
 162         end
 163 end
 164
 165 redef class WikiArticle
 166
 167         redef fun out_path: String do
 168                 if parent == null then
 169                         return wiki.expand_path(wiki.config.out_dir, "{name}.html")
 170                 else
 171                         return wiki.expand_path(parent.out_path, "{name}.html")
 172                 end
 173         end
 174
 175         redef fun render do
 176                 super
 177                 if not is_dirty and not wiki.force_render then return
 178                 wiki.message("Render article {name}", 2)
 179                 var file = out_full_path
 180                 file.dirname.mkdir
 181                 tpl_page.write_to_file file
 182         end
 183
 184
 185         # Replace macros in the template by wiki data.
 186         private fun tpl_page: TemplateString do
 187                 var tpl = wiki.load_template(template_file)
 188                 if tpl.has_macro("TOP_MENU") then
 189                         tpl.replace("TOP_MENU", tpl_menu)
 190                 end
 191                 if tpl.has_macro("HEADER") then
 192                         tpl.replace("HEADER", tpl_header)
 193                 end
 194                 if tpl.has_macro("BODY") then
 195                         tpl.replace("BODY", tpl_article)
 196                 end
 197                 if tpl.has_macro("FOOTER") then
 198                         tpl.replace("FOOTER", tpl_footer)
 199                 end
 200                 return tpl
 201         end
 202
 203         # Generate the HTML header for this article.
 204         fun tpl_header: Writable do
 205                 var file = header_file
 206                 if not wiki.has_template(file) then return ""
 207                 return wiki.load_template(file)
 208         end
 209
 210         # Generate the HTML page for this article.
 211         fun tpl_article: TplArticle do
 212                 var article = new TplArticle
 213                 article.body = content
 214                 article.breadcrumbs = new TplBreadcrumbs(self)
 215                 tpl_sidebar.blocks.add tpl_summary
 216                 article.sidebar = tpl_sidebar
 217                 return article
 218         end
 219
 220         # Sidebar for this page.
 221         var tpl_sidebar = new TplSidebar
 222
 223         # Generate the HTML summary for this article.
 224         #
 225         # Based on `headlines`
 226         fun tpl_summary: Writable do
 227                 var headlines = self.headlines
 228                 var tpl = new Template
 229                 tpl.add "<ul class=\"summary list-unstyled\">"
 230                 var iter = headlines.iterator
 231                 while iter.is_ok do
 232                         var hl = iter.item
 233                         # parse title as markdown
 234                         var title = wiki.inline_md(hl.title)
 235                         tpl.add "<li><a href=\"#{hl.id}\">{title}</a>"
 236                         iter.next
 237                         if iter.is_ok then
 238                                 if iter.item.level > hl.level then
 239                                         tpl.add "<ul class=\"list-unstyled\">"
 240                                 else if iter.item.level < hl.level then
 241                                         tpl.add "</li>"
 242                                         tpl.add "</ul>"
 243                                 end
 244                         else
 245                                 tpl.add "</li>"
 246                         end
 247                 end
 248                 tpl.add "</ul>"
 249                 return tpl
 250         end
 251
 252         # Generate the HTML menu for this article.
 253         fun tpl_menu: Writable do
 254                 var file = menu_file
 255                 if not wiki.has_template(file) then return ""
 256                 var tpl = wiki.load_template(file)
 257                 if tpl.has_macro("MENUS") then
 258                         var items = new Template
 259                         for child in wiki.root_section.children.values do
 260                                 if child isa WikiArticle and child.is_index then continue
 261                                 if child isa WikiSection and child.is_hidden then continue
 262                                 items.add "<li"
 263                                 if self == child or self.breadcrumbs.has(child) then
 264                                         items.add " class=\"active\""
 265                                 end
 266                                 items.add ">"
 267                                 items.add child.tpl_link
 268                                 items.add "</li>"
 269                         end
 270                         tpl.replace("MENUS", items)
 271                 end
 272                 return tpl
 273         end
 274
 275         # Generate the HTML footer for this article.
 276         fun tpl_footer: Writable do
 277                 var file = footer_file
 278                 if not wiki.has_template(file) then return ""
 279                 var tpl = wiki.load_template(file)
 280                 var time = new Tm.gmtime
 281                 if tpl.has_macro("YEAR") then
 282                         tpl.replace("YEAR", (time.year + 1900).to_s)
 283                 end
 284                 if tpl.has_macro("GEN_TIME") then
 285                         tpl.replace("GEN_TIME", time.to_s)
 286                 end
 287                 return tpl
 288         end
 289 end
 290
 291 # A `WikiArticle` that contains the sitemap tree.
 292 class WikiSitemap
 293         super WikiArticle
 294
 295         redef fun tpl_article do
 296                 var article = new TplArticle.with_title("Sitemap")
 297                 article.body = new TplPageTree(wiki.root_section, -1)
 298                 return article
 299         end
 300
 301         redef var is_dirty = false
 302 end
 303
 304 # A `WikiArticle` that contains the section index tree.
 305 redef class WikiSectionIndex
 306
 307         redef var is_dirty = false
 308
 309         redef fun tpl_article do
 310                 var article = new TplArticle.with_title(section.title)
 311                 article.body = new TplPageTree(section, -1)
 312                 article.breadcrumbs = new TplBreadcrumbs(self)
 313                 return article
 314         end
 315 end
 316
 317 # Article HTML output.
 318 class TplArticle
 319         super Template
 320
 321         # Article title.
 322         var title: nullable Writable = null
 323
 324         # Article HTML body.
 325         var body: nullable Writable = null
 326
 327         # Sidebar of this article (if any).
 328         var sidebar: nullable TplSidebar = null
 329
 330         # Breadcrumbs from wiki root to this article.
 331         var breadcrumbs: nullable TplBreadcrumbs = null
 332
 333         # Init `self` with a `title`.
 334         init with_title(title: Writable) do
 335                 self.title = title
 336         end
 337
 338         redef fun rendering do
 339                 if sidebar != null then
 340                         add "<div class=\"col-sm-3 sidebar\">"
 341                         add sidebar.as(not null)
 342                         add "</div>"
 343                         add "<div class=\"col-sm-9 content\">"
 344                 else
 345                         add "<div class=\"col-sm-12 content\">"
 346                 end
 347                 if body != null then
 348                         add "<article>"
 349                         if breadcrumbs != null then
 350                                 add breadcrumbs.as(not null)
 351                         end
 352                         if title != null then
 353                                 add "<h1>"
 354                                 add title.as(not null)
 355                                 add "</h1>"
 356                         end
 357                         add     body.as(not null)
 358                         add " </article>"
 359                 end
 360                 add "</div>"
 361         end
 362 end
 363
 364 # A collection of HTML blocks displayed on the side of a page.
 365 class TplSidebar
 366         super Template
 367
 368         # Blocks are `Stremable` pieces that will be rendered in the sidebar.
 369         var blocks = new Array[Writable]
 370
 371         redef fun rendering do
 372                 for block in blocks do
 373                         add "<div class=\"sideblock\">"
 374                         add block
 375                         add "</div>"
 376                 end
 377         end
 378 end
 379
 380 # An HTML breadcrumbs that show the path from a `WikiArticle` to the `Nitiwiki` root.
 381 class TplBreadcrumbs
 382         super Template
 383
 384         # Bread crumb article.
 385         var article: WikiArticle
 386
 387         redef fun rendering do
 388                 var path = article.breadcrumbs
 389                 if path.is_empty or path.length <= 2 and article.is_index then return
 390                 add "<ol class=\"breadcrumb\">"
 391                 for entry in path do
 392                         if entry == path.last then
 393                                 add "<li class=\"active\">"
 394                                 add entry.title
 395                                 add "</li>"
 396                         else
 397                                 if article.parent == entry and article.is_index then continue
 398                                 add "<li>"
 399                                 add entry.tpl_link
 400                                 add "</li>"
 401                         end
 402                 end
 403                 add "</ol>"
 404         end
 405 end
 406
 407 # An HTML tree that show the section pages structure.
 408 class TplPageTree
 409         super Template
 410
 411         # Builds the page tree from `root`.
 412         var root: WikiSection
 413
 414         # Limits the tree depth to `max_depth` levels.
 415         var max_depth: Int
 416
 417         redef fun rendering do
 418                 add "<ul>"
 419                 add root.tpl_tree(-1)
 420                 add "</ul>"
 421         end
 422 end