lib/a_star.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Copyright 2011-2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Services related to pathfinding of graphs using A*
  18 # A single graph may have different properties according to the `PathContext` used
  19 #
  20 #
  21 # Usage:
  22 #
  23 # ~~~
  24 # # Weighted graph (letters are nodes, digits are weights):
  25 # #
  26 # #     a -2- b
  27 # #    /     /
  28 # #   3     1
  29 # #  /     /
  30 # # c -3- d -8- e
  31 # #
  32 # var graph = new Graph[Node,WeigthedLink[Node]]
  33 #
  34 # var na = new Node(graph)
  35 # var nb = new Node(graph)
  36 # var nc = new Node(graph)
  37 # var nd = new Node(graph)
  38 # var ne = new Node(graph)
  39 #
  40 # var lab = new WeightedLink(graph, na, nb, 2)
  41 # var lac = new WeightedLink(graph, na, nc, 3)
  42 # var lbd = new WeightedLink(graph, nb, nd, 1)
  43 # var lcd = new WeightedLink(graph, nc, nd, 3)
  44 # var lde = new WeightedLink(graph, nd, ne, 8)
  45 #
  46 # var context = new WeightedPathContext(graph)
  47 #
  48 # var path = na.path_to(ne, 100, context)
  49 # assert path != null else print "No possible path"
  50 #
  51 # assert path.step == nb
  52 # assert path.step == nd
  53 # assert path.step == ne
  54 # assert path.at_end_of_path
  55 # ~~~
  56 module a_star
  57
  58 redef class Object
  59         protected fun debug_a_star: Bool do return false
  60         private fun debug(msg: String) do if debug_a_star then
  61                 stderr.write "a_star debug: {msg}\n"
  62         end
  63 end
  64
  65 # General graph node
  66 class Node
  67         type N: Node
  68
  69         # parent graph
  70         var graph: Graph[N, Link]
  71
  72         init(graph: Graph[N, Link])
  73         do
  74                 self.graph = graph
  75                 graph.add_node(self)
  76         end
  77
  78         # adjacent nodes
  79         var links: Set[Link] = new HashSet[Link]
  80
  81         # used to check if node has been searched in one pathfinding
  82         private var last_pathfinding_evocation: Int = 0
  83
  84         # cost up to in current evocation
  85         # lifetime limited to evocation of `path_to`
  86         private var best_cost_up_to: Int = 0
  87
  88         # source node
  89         # lifetime limited to evocation of `path_to`
  90         private var best_source: nullable N = null
  91
  92         # is in frontier or buckets
  93         # lifetime limited to evocation of `path_to`
  94         private var open: Bool = false
  95
  96         # Main functionnality, returns path from `self` to `dest`
  97         fun path_to(dest: N, max_cost: Int, context: PathContext): nullable Path[N]
  98         do
  99                 var cost = 0
 100
 101                 var nbr_buckets = context.worst_cost + context.worst_heuristic_cost + 1
 102                 var buckets = new Array[List[N]].with_capacity(nbr_buckets)
 103
 104                 for i in [0 .. nbr_buckets[ do
 105                         buckets.add(new List[N])
 106                 end
 107
 108                 graph.pathfinding_current_evocation += 1
 109
 110                 # open source node
 111                 buckets[0].add(self)
 112                 open = true
 113                 self.last_pathfinding_evocation = graph.pathfinding_current_evocation
 114                 self.best_cost_up_to = 0
 115
 116                 loop
 117                         var frontier_node: nullable N = null
 118
 119                         var bucket_searched: Int = 0
 120
 121                         # find next valid node in frontier/buckets
 122                         loop
 123                                 var current_bucket = buckets[cost % nbr_buckets]
 124
 125                                 if current_bucket.is_empty then # move to next bucket
 126                                         debug "b {cost} {cost % nbr_buckets} {buckets[cost % nbr_buckets].hash}"
 127                                         cost += 1
 128                                         if cost > max_cost then return null
 129                                         bucket_searched += 1
 130
 131                                         if bucket_searched > nbr_buckets then break
 132                                 else # found a node
 133                                         debug "c {cost}"
 134                                         frontier_node = current_bucket.pop
 135
 136                                         if frontier_node.open then break
 137                                 end
 138                         end
 139
 140                         # no path possible
 141                         if frontier_node == null then
 142                                 return null
 143
 144                         # at destination
 145                         else if frontier_node == dest then
 146                                 debug "picked {frontier_node}, is destination"
 147
 148                                 var path = new Path[N](cost)
 149
 150                                 while frontier_node != self do
 151                                         path.nodes.unshift(frontier_node)
 152                                         frontier_node = frontier_node.best_source.as(not null)
 153                                 end
 154
 155                                 return path
 156
 157                         # adds all next nodes to frontier/buckets
 158                         else
 159                                 frontier_node.open = false
 160
 161                                 debug "w exploring adjacents of {frontier_node}"
 162
 163                                 for link in frontier_node.links do
 164                                         var peek_node = link.to
 165                                         debug "v {context.is_blocked(link)} {peek_node.last_pathfinding_evocation != graph.pathfinding_current_evocation} {peek_node.best_cost_up_to > frontier_node.best_cost_up_to + context.cost(link)}, {peek_node.best_cost_up_to} > {frontier_node.best_cost_up_to} + {context.cost(link)}"
 166                                         if not context.is_blocked(link) and
 167                                          (peek_node.last_pathfinding_evocation != graph.pathfinding_current_evocation or
 168                                            (peek_node.open and
 169                                              peek_node.best_cost_up_to > cost + context.cost(link)))
 170                                         then
 171
 172                                                 peek_node.open = true
 173                                                 peek_node.last_pathfinding_evocation = graph.pathfinding_current_evocation
 174                                                 peek_node.best_cost_up_to = cost + context.cost(link)
 175                                                 peek_node.best_source = frontier_node
 176
 177                                                 var est_cost = peek_node.best_cost_up_to+context.heuristic_cost(link.from, peek_node)
 178                                                 var at_bucket = buckets[est_cost % nbr_buckets]
 179                                                 at_bucket.add(peek_node)
 180
 181                                                 debug "u putting {peek_node} at {est_cost} -> {est_cost % nbr_buckets} {at_bucket.hash}, {cost}+{context.cost(link)}"
 182                                         end
 183                                 end
 184                         end
 185                 end
 186         end
 187 end
 188
 189 # Link between two nodes and associated to a graph
 190 class Link
 191         type N: Node
 192         type L: Link
 193
 194         var graph: Graph[N, L]
 195
 196         var from: N
 197         var to: N
 198
 199         init(graph: Graph[N, L], from, to: N)
 200         do
 201                 self.graph = graph
 202                 self.from = from
 203                 self.to = to
 204
 205                 graph.add_link(self)
 206         end
 207 end
 208
 209 # General graph
 210 class Graph[N: Node, L: Link]
 211         var nodes: Set[N] = new HashSet[N]
 212         var links: Set[L] = new HashSet[L]
 213
 214         fun add_node(node: N): N
 215         do
 216                 nodes.add(node)
 217
 218                 return node
 219         end
 220
 221         fun add_link(link: L): L
 222         do
 223                 links.add(link)
 224
 225                 link.from.links.add(link)
 226
 227                 return link
 228         end
 229
 230         # used to check if nodes have been searched in one pathfinding
 231         var pathfinding_current_evocation: Int = 0
 232 end
 233
 234 # Result from pathfinding, a walkable path
 235 class Path[N]
 236
 237         var total_cost: Int
 238
 239         var nodes = new List[N]
 240
 241         init (cost: Int) do total_cost = cost
 242
 243         var at: Int = 0
 244         fun step: N
 245         do
 246                 assert nodes.length >= at else print "a_star::Path::step failed, is at_end_of_path"
 247
 248                 var s = nodes[at]
 249                 at += 1
 250
 251                 return s
 252         end
 253
 254         fun peek_step: N do return nodes[at]
 255
 256         fun at_end_of_path: Bool do return at >= nodes.length
 257 end
 258
 259 # Context related to an evocation of pathfinding
 260 class PathContext
 261         type N: Node
 262         type L: Link
 263
 264         var graph: Graph[N, L]
 265
 266         # Worst cost of all the link's costs
 267         fun worst_cost: Int is abstract
 268
 269         # Get cost of a link
 270         fun cost(link: L): Int is abstract
 271
 272         # Is that link blocked?
 273         fun is_blocked(link: L): Bool is abstract
 274
 275         # Heuristic
 276         fun heuristic_cost(a, b: N): Int is abstract
 277
 278         fun worst_heuristic_cost: Int is abstract
 279 end
 280
 281 #
 282 ### Additionnal classes, may be useful
 283 #
 284
 285 # Simple context with constant cost on each links
 286 # Warning: A* is not optimize for such a case
 287 class ConstantPathContext
 288         super PathContext
 289
 290         redef fun worst_cost do return 1
 291         redef fun cost(l) do return 1
 292         redef fun is_blocked(l) do return false
 293         redef fun heuristic_cost(a, b) do return 0
 294         redef fun worst_heuristic_cost do return 0
 295 end
 296
 297 class WeightedPathContext
 298         super PathContext
 299
 300         redef type L: WeightedLink
 301
 302         init(graph: Graph[N, L])
 303         do
 304                 super
 305
 306                 var worst_cost = 0
 307                 for l in graph.links do
 308                         var cost = l.weight
 309                         if cost >= worst_cost then worst_cost = cost + 1
 310                 end
 311                 self.worst_cost = worst_cost
 312         end
 313
 314         redef var worst_cost: Int
 315
 316         redef fun cost(l) do
 317                 return l.weight
 318         end
 319         redef fun is_blocked(l) do return false
 320         redef fun heuristic_cost(a, b) do return 0
 321         redef fun worst_heuristic_cost do return 0
 322 end
 323
 324 class WeightedLink
 325         super Link
 326
 327         var weight: Int
 328
 329         init(graph: Graph[N, L], from, to: N, weight: Int)
 330         do
 331                 super
 332
 333                 self.weight = weight
 334         end
 335 end