lib/realtime.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # This file is free software, which comes along with NIT.  This software is
   6 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   7 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   8 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
   9 # is kept unaltered, and a notification of the changes is added.
  10 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  11 # another product.
  12
  13 # Services to keep time of the wall clock time
  14 module realtime is ldflags "-lrt"
  15
  16 in "C header" `{
  17 #ifdef _POSIX_C_SOURCE
  18         #undef _POSIX_C_SOURCE
  19 #endif
  20 #define _POSIX_C_SOURCE 199309L
  21 #include <time.h>
  22 `}
  23
  24 in "C" `{
  25
  26 #ifdef __MACH__
  27 /* OS X does not have clock_gettime, mascarade it and use clock_get_time
  28  * cf http://stackoverflow.com/questions/11680461/monotonic-clock-on-osx
  29 */
  30 #include <mach/clock.h>
  31 #include <mach/mach.h>
  32 #define CLOCK_REALTIME CALENDAR_CLOCK
  33 #define CLOCK_MONOTONIC SYSTEM_CLOCK
  34 void clock_gettime(clock_t clock_name, struct timespec *ts) {
  35         clock_serv_t cclock;
  36         mach_timespec_t mts;
  37         host_get_clock_service(mach_host_self(), clock_name, &cclock);
  38         clock_get_time(cclock, &mts);
  39         mach_port_deallocate(mach_task_self(), cclock);
  40         ts->tv_sec = mts.tv_sec;
  41         ts->tv_nsec = mts.tv_nsec;
  42 }
  43 #endif
  44 `}
  45
  46 # Elapsed time representation.
  47 extern class Timespec `{struct timespec*`}
  48
  49         # Init a new Timespec from `s` seconds and `ns` nanoseconds.
  50         new ( s, ns : Int ) `{
  51                 struct timespec* tv = malloc( sizeof(struct timespec) );
  52                 tv->tv_sec = s; tv->tv_nsec = ns;
  53                 return tv;
  54         `}
  55
  56         # Init a new Timespec from now.
  57         new monotonic_now `{
  58                 struct timespec* tv = malloc( sizeof(struct timespec) );
  59                 clock_gettime( CLOCK_MONOTONIC, tv );
  60                 return tv;
  61         `}
  62
  63         # Init a new Timespec copied from another.
  64         new copy_of( other : Timespec ) `{
  65                 struct timespec* tv = malloc( sizeof(struct timespec) );
  66                 tv->tv_sec = other->tv_sec;
  67                 tv->tv_nsec = other->tv_nsec;
  68                 return tv;
  69         `}
  70
  71         # Update `self` clock.
  72         fun update `{
  73                 clock_gettime(CLOCK_MONOTONIC, self);
  74         `}
  75
  76         # Substract a Timespec from `self`.
  77         fun - ( o : Timespec ) : Timespec
  78         do
  79                 var s = sec - o.sec
  80                 var ns = nanosec - o.nanosec
  81                 if ns > nanosec then s += 1
  82                 return new Timespec( s, ns )
  83         end
  84
  85         # Number of whole seconds of elapsed time.
  86         fun sec : Int `{
  87                 return self->tv_sec;
  88         `}
  89
  90         # Rest of the elapsed time (a fraction of a second).
  91         #
  92         # Number of nanoseconds.
  93         fun nanosec : Int `{
  94                 return self->tv_nsec;
  95         `}
  96
  97         # Elapsed time in microseconds, with both whole seconds and the rest
  98         #
  99         # May cause an `Int` overflow, use only with a low number of seconds.
 100         fun microsec: Int `{
 101                 return self->tv_sec*1000000 + self->tv_nsec/1000;
 102         `}
 103
 104         # Elapsed time in milliseconds, with both whole seconds and the rest
 105         #
 106         # May cause an `Int` overflow, use only with a low number of seconds.
 107         fun millisec: Int `{
 108                 return self->tv_sec*1000 + self->tv_nsec/1000000;
 109         `}
 110
 111         # Number of seconds as a `Float`
 112         #
 113         # Incurs a loss of precision, but the result is pretty to print.
 114         fun to_f: Float do return sec.to_f + nanosec.to_f / 1000000000.0
 115
 116         redef fun to_s do return "{to_f}s"
 117 end
 118
 119 # Keeps track of real time
 120 class Clock
 121         # Time at instanciation
 122         protected var time_at_beginning = new Timespec.monotonic_now
 123
 124         # Time at last time a lapse method was called
 125         protected var time_at_last_lapse = new Timespec.monotonic_now
 126
 127         # Smallest time frame reported by clock
 128         fun resolution : Timespec `{
 129                 struct timespec* tv = malloc( sizeof(struct timespec) );
 130 #ifdef __MACH__
 131                 clock_serv_t cclock;
 132                 int nsecs;
 133                 mach_msg_type_number_t count;
 134                 host_get_clock_service(mach_host_self(), SYSTEM_CLOCK, &cclock);
 135                 clock_get_attributes(cclock, CLOCK_GET_TIME_RES, (clock_attr_t)&nsecs, &count);
 136                 mach_port_deallocate(mach_task_self(), cclock);
 137                 tv->tv_sec = 0;
 138                 tv->tv_nsec = nsecs;
 139 #else
 140                 clock_getres( CLOCK_MONOTONIC, tv );
 141 #endif
 142                 return tv;
 143         `}
 144
 145         # Return timelapse since instanciation of this instance
 146         fun total : Timespec
 147         do
 148                 return new Timespec.monotonic_now - time_at_beginning
 149         end
 150
 151         # Return timelapse since last call to lapse
 152         fun lapse : Timespec
 153         do
 154                 var nt = new Timespec.monotonic_now
 155                 var dt = nt - time_at_last_lapse
 156                 time_at_last_lapse = nt
 157                 return dt
 158         end
 159 end