src/metrics/generate_hierarchies.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Create dot files for various hierarchies of a model.
  18 # See graphviz http://www.graphviz.org/
  19 module generate_hierarchies
  20
  21 import model
  22 private import metrics_base
  23 import frontend
  24 import model_viz
  25
  26 redef class ToolContext
  27         var generate_hierarchies_phase: Phase = new GenerateHierarchyPhase(self, null)
  28 end
  29
  30 private class GenerateHierarchyPhase
  31         super Phase
  32
  33         redef fun process_mainmodule(mainmodule, given_mmodules)
  34         do
  35                 if not toolcontext.opt_generate_hyperdoc.value and not toolcontext.opt_all.value then return
  36                 var model = toolcontext.modelbuilder.model
  37                 generate_module_hierarchy(toolcontext, given_mmodules)
  38                 generate_classdef_hierarchy(toolcontext, model)
  39                 generate_class_hierarchy(toolcontext, mainmodule)
  40         end
  41 end
  42
  43 # Create a dot file representing the module hierarchy of a model.
  44 # Importation relation is represented with arrow
  45 # Nesting relation is represented with nested boxes
  46 fun generate_module_hierarchy(toolcontext: ToolContext, given_mmodules: Collection[MModule])
  47 do
  48         var model = given_mmodules.first.model
  49         var dot = new MProjectDot(model)
  50
  51         # Collect requested projects
  52         for m in given_mmodules do
  53                 var g = m.mgroup
  54                 if g == null then continue
  55                 dot.mprojects.add(g.mproject)
  56         end
  57         var projectpath = toolcontext.output_dir.join_path("project_hierarchy.dot")
  58         print "generating {projectpath}"
  59         dot.write_to_file(projectpath)
  60
  61         var modulepath = toolcontext.output_dir.join_path("module_hierarchy.dot")
  62         dot.mprojects.add_all(model.mprojects)
  63         print "generating {modulepath}"
  64         dot.write_to_file(modulepath)
  65 end
  66
  67 # Create a dot file representing the class hierarchy of a model.
  68 fun generate_class_hierarchy(toolcontext: ToolContext, mmodule: MModule)
  69 do
  70         var buf = new FlatBuffer
  71         buf.append("digraph \{\n")
  72         buf.append("node [shape=box];\n")
  73         buf.append("rankdir=BT;\n")
  74         var hierarchy = mmodule.flatten_mclass_hierarchy
  75         for mclass in hierarchy do
  76                 buf.append("\"{mclass}\" [label=\"{mclass}\"];\n")
  77                 for s in hierarchy[mclass].direct_greaters do
  78                         buf.append("\"{mclass}\" -> \"{s}\";\n")
  79                 end
  80         end
  81         buf.append("\}\n")
  82         var f = new OFStream.open(toolcontext.output_dir.join_path("class_hierarchy.dot"))
  83         f.write(buf.to_s)
  84         f.close
  85 end
  86
  87 # Create a dot file representing the classdef hierarchy of a model.
  88 # For a simple user of the model, the classdef hierarchy is not really usefull, it is more an internal thing.
  89 fun generate_classdef_hierarchy(toolcontext: ToolContext, model: Model)
  90 do
  91         var buf = new FlatBuffer
  92         buf.append("digraph \{\n")
  93         buf.append("node [shape=box];\n")
  94         buf.append("rankdir=BT;\n")
  95         for mmodule in model.mmodules do
  96                 for mclassdef in mmodule.mclassdefs do
  97                         buf.append("\"{mclassdef} {mclassdef.bound_mtype}\" [label=\"{mclassdef.mmodule}\\n{mclassdef.bound_mtype}\"];\n")
  98                         for s in mclassdef.in_hierarchy.direct_greaters do
  99                                 buf.append("\"{mclassdef} {mclassdef.bound_mtype}\" -> \"{s} {s.bound_mtype}\";\n")
 100                         end
 101                 end
 102         end
 103         buf.append("\}\n")
 104         var f = new OFStream.open(toolcontext.output_dir.join_path("classdef_hierarchy.dot"))
 105         f.write(buf.to_s)
 106         f.close
 107 end