lib/glesv2/glesv2.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # OpenGL graphics rendering library for embedded systems, version 2.0
  18 #
  19 # This is a low-level wrapper, it can be useful for developers already familiar
  20 # with the C API of OpenGL. Most developers will prefer to use higher level
  21 # wrappers such as `mnit` and `gammit`.
  22 #
  23 # Defines the annotations `glsl_vertex_shader` and `glsl_fragment_shader`
  24 # applicable on string literals to check shader code using `glslangValidator`.
  25 # The tool must be in PATH. It can be downloaded from
  26 # https://www.khronos.org/opengles/sdk/tools/Reference-Compiler/
  27 #
  28 # Most services of this module are a direct wrapper of the underlying
  29 # C library. If a method or class is not documented in Nit, refer to
  30 # the official documentation by the Khronos Group at:
  31 # http://www.khronos.org/opengles/sdk/docs/man/
  32 module glesv2 is
  33         pkgconfig
  34         new_annotation glsl_vertex_shader
  35         new_annotation glsl_fragment_shader
  36         ldflags("-lGLESv2")@android
  37 end
  38
  39 import android::aware
  40 intrude import c
  41
  42 in "C Header" `{
  43         #include <GLES2/gl2.h>
  44 `}
  45
  46 # OpenGL ES program to which we attach shaders
  47 extern class GLProgram `{GLuint`}
  48         # Create a new program
  49         #
  50         # The newly created instance should be checked using `is_ok`.
  51         new `{ return glCreateProgram(); `}
  52
  53         # Is this a valid program?
  54         fun is_ok: Bool `{ return glIsProgram(self); `}
  55
  56         # Attach a `shader` to this program
  57         fun attach_shader(shader: GLShader) `{ glAttachShader(self, shader); `}
  58
  59         # Set the location for the attribute by `name`
  60         fun bind_attrib_location(index: Int, name: String) import String.to_cstring `{
  61                 GLchar *c_name = String_to_cstring(name);
  62                 glBindAttribLocation(self, index, c_name);
  63         `}
  64
  65         # Get the location of the attribute by `name`
  66         #
  67         # Returns `-1` if there is no active attribute named `name`.
  68         fun attrib_location(name: String): Int import String.to_cstring `{
  69                 GLchar *c_name = String_to_cstring(name);
  70                 return glGetAttribLocation(self, c_name);
  71         `}
  72
  73         # Get the location of the uniform by `name`
  74         #
  75         # Returns `-1` if there is no active uniform named `name`.
  76         fun uniform_location(name: String): Int import String.to_cstring `{
  77                 GLchar *c_name = String_to_cstring(name);
  78                 return glGetUniformLocation(self, c_name);
  79         `}
  80
  81         # Query information on this program
  82         fun query(pname: Int): Int `{
  83                 int val;
  84                 glGetProgramiv(self, pname, &val);
  85                 return val;
  86         `}
  87
  88         # Try to link this program
  89         #
  90         # Check result using `in_linked` and `info_log`.
  91         fun link `{ glLinkProgram(self); `}
  92
  93         # Is this program linked?
  94         fun is_linked: Bool do return query(0x8B82) != 0
  95
  96         # Use this program for the following operations
  97         fun use `{ glUseProgram(self); `}
  98
  99         # Delete this program
 100         fun delete `{ glDeleteProgram(self); `}
 101
 102         # Has this program been deleted?
 103         fun is_deleted: Bool do return query(0x8B80) != 0
 104
 105         # Validate whether this program can be executed in the current OpenGL state
 106         #
 107         # Check results using `is_validated` and `info_log`.
 108         fun validate `{ glValidateProgram(self); `}
 109
 110         # Boolean result of `validate`, must be called after `validate`
 111         fun is_validated: Bool do return query(0x8B83) != 0
 112
 113         # Retrieve the information log of this program
 114         #
 115         # Useful with `link` and `validate`
 116         fun info_log: String import NativeString.to_s `{
 117                 int size;
 118                 glGetProgramiv(self, GL_INFO_LOG_LENGTH, &size);
 119                 GLchar *msg = malloc(size);
 120                 glGetProgramInfoLog(self, size, NULL, msg);
 121                 return NativeString_to_s(msg);
 122         `}
 123
 124         # Number of active uniform in this program
 125         #
 126         # This should be the number of uniforms declared in all shader, except
 127         # unused uniforms which may have been optimized out.
 128         fun n_active_uniforms: Int do return query(0x8B86)
 129
 130         # Length of the longest uniform name in this program, including `\n`
 131         fun active_uniform_max_length: Int do return query(0x8B87)
 132
 133         # Number of active attributes in this program
 134         #
 135         # This should be the number of uniforms declared in all shader, except
 136         # unused uniforms which may have been optimized out.
 137         fun n_active_attributes: Int do return query(0x8B89)
 138
 139         # Length of the longest uniform name in this program, including `\n`
 140         fun active_attribute_max_length: Int do return query(0x8B8A)
 141
 142         # Number of shaders attached to this program
 143         fun n_attached_shaders: Int do return query(0x8B85)
 144
 145         # Name of the active attribute at `index`
 146         fun active_attrib_name(index: Int): String
 147         do
 148                 var max_size = active_attribute_max_length
 149                 return active_attrib_name_native(index, max_size).to_s
 150         end
 151         private fun active_attrib_name_native(index, max_size: Int): NativeString `{
 152                 // We get more values than we need, for compatibility. At least the
 153                 // NVidia driver tries to fill them even if NULL.
 154
 155                 char *name = malloc(max_size);
 156                 int size;
 157                 GLenum type;
 158                 glGetActiveAttrib(self, index, max_size, NULL, &size, &type, name);
 159                 return name;
 160         `}
 161
 162         # Size of the active attribute at `index`
 163         fun active_attrib_size(index: Int): Int `{
 164                 int size;
 165                 GLenum type;
 166                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 167                 return size;
 168         `}
 169
 170         # Type of the active attribute at `index`
 171         #
 172         # May only be float related data types (single float, vectors and matrix).
 173         fun active_attrib_type(index: Int): GLFloatDataType `{
 174                 int size;
 175                 GLenum type;
 176                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 177                 return type;
 178         `}
 179
 180         # Name of the active uniform at `index`
 181         fun active_uniform_name(index: Int): String
 182         do
 183                 var max_size = active_attribute_max_length
 184                 return active_uniform_name_native(index, max_size).to_s
 185         end
 186         private fun active_uniform_name_native(index, max_size: Int): NativeString `{
 187                 char *name = malloc(max_size);
 188                 int size;
 189                 GLenum type;
 190                 glGetActiveUniform(self, index, max_size, NULL, &size, &type, name);
 191                 return name;
 192         `}
 193
 194         # Size of the active uniform at `index`
 195         fun active_uniform_size(index: Int): Int `{
 196                 int size;
 197                 GLenum type;
 198                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 199                 return size;
 200         `}
 201
 202         # Type of the active uniform at `index`
 203         #
 204         # May be any data type supported by OpenGL ES 2.0 shaders.
 205         fun active_uniform_type(index: Int): GLDataType `{
 206                 int size;
 207                 GLenum type = 0;
 208                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 209                 return type;
 210         `}
 211 end
 212
 213 # Abstract OpenGL ES shader object, implemented by `GLFragmentShader` and `GLVertexShader`
 214 extern class GLShader `{GLuint`}
 215         # Set the source of the shader
 216         fun source=(code: NativeString) `{
 217                 glShaderSource(self, 1, (GLchar const **)&code, NULL);
 218         `}
 219
 220         # Source of the shader, if available
 221         #
 222         # Returns `null` if the source is not available, usually when the shader
 223         # was created from a binary file.
 224         fun source: nullable String
 225         do
 226                 var size = query(0x8B88)
 227                 if size == 0 then return null
 228                 return source_native(size).to_s
 229         end
 230
 231         private fun source_native(size: Int): NativeString `{
 232                 GLchar *code = malloc(size);
 233                 glGetShaderSource(self, size, NULL, code);
 234                 return code;
 235         `}
 236
 237         # Query information on this shader
 238         protected fun query(pname: Int): Int `{
 239                 int val;
 240                 glGetShaderiv(self, pname, &val);
 241                 return val;
 242         `}
 243
 244         # Try to compile `source` into a binary GPU program
 245         #
 246         # Check the result using `is_compiled` and `info_log`
 247         fun compile `{ glCompileShader(self); `}
 248
 249         # Has this shader been compiled?
 250         fun is_compiled: Bool do return query(0x8B81) != 0
 251
 252         # Delete this shader
 253         fun delete `{ glDeleteShader(self); `}
 254
 255         # Has this shader been deleted?
 256         fun is_deleted: Bool do return query(0x8B80) != 0
 257
 258         # Is this a valid shader?
 259         fun is_ok: Bool `{ return glIsShader(self); `}
 260
 261         # Retrieve the information log of this shader
 262         #
 263         # Useful with `link` and `validate`
 264         fun info_log: String import NativeString.to_s `{
 265                 int size;
 266                 glGetShaderiv(self, GL_INFO_LOG_LENGTH, &size);
 267                 GLchar *msg = malloc(size);
 268                 glGetShaderInfoLog(self, size, NULL, msg);
 269                 return NativeString_to_s(msg);
 270         `}
 271 end
 272
 273 # An OpenGL ES 2.0 fragment shader
 274 extern class GLFragmentShader
 275         super GLShader
 276
 277         # Create a new fragment shader
 278         #
 279         # The newly created instance should be checked using `is_ok`.
 280         new `{ return glCreateShader(GL_FRAGMENT_SHADER); `}
 281 end
 282
 283 # An OpenGL ES 2.0 vertex shader
 284 extern class GLVertexShader
 285         super GLShader
 286
 287         # Create a new fragment shader
 288         #
 289         # The newly created instance should be checked using `is_ok`.
 290         new `{ return glCreateShader(GL_VERTEX_SHADER); `}
 291 end
 292
 293 # An array of `Float` associated to a program variable
 294 class VertexArray
 295         var index: Int
 296
 297         # Number of data per vertex
 298         var count: Int
 299
 300         protected var glfloat_array: NativeGLfloatArray
 301
 302         init(index, count: Int, array: Array[Float])
 303         do
 304                 self.index = index
 305                 self.count = count
 306                 self.glfloat_array = new NativeGLfloatArray(array.length)
 307                 for k in [0..array.length[ do
 308                         glfloat_array[k] = array[k]
 309                 end
 310         end
 311
 312         fun attrib_pointer do attrib_pointer_intern(index, count, glfloat_array)
 313         private fun attrib_pointer_intern(index, count: Int, array: NativeGLfloatArray) `{
 314                 glVertexAttribPointer(index, count, GL_FLOAT, GL_FALSE, 0, array);
 315         `}
 316
 317         # Enable this vertex attribute array
 318         fun enable do glEnableVertexAttribArray(index)
 319
 320         # Disable this vertex attribute array
 321         fun disable do glDisableVertexAttribArray(index)
 322 end
 323
 324 # Enable the generic vertex attribute array at `index`
 325 fun glEnableVertexAttribArray(index: Int) `{ glEnableVertexAttribArray(index); `}
 326
 327 # Disable the generic vertex attribute array at `index`
 328 fun glDisableVertexAttribArray(index: Int) `{ glDisableVertexAttribArray(index); `}
 329
 330 # Render primitives from array data
 331 fun glDrawArrays(mode: GLDrawMode, from, count: Int) `{ glDrawArrays(mode, from, count); `}
 332
 333 # Define an array of generic vertex attribute data
 334 fun glVertexAttribPointer(index, size: Int, typ: GLDataType, normalized: Bool, stride: Int, array: NativeGLfloatArray) `{
 335         glVertexAttribPointer(index, size, typ, normalized, stride, array);
 336 `}
 337
 338 # Specify the value of a generic vertex attribute
 339 fun glVertexAttrib1f(index: Int, x: Float) `{ glVertexAttrib1f(index, x); `}
 340
 341 # Specify the value of a generic vertex attribute
 342 fun glVertexAttrib2f(index: Int, x, y: Float) `{ glVertexAttrib2f(index, x, y); `}
 343
 344 # Specify the value of a generic vertex attribute
 345 fun glVertexAttrib3f(index: Int, x, y, z: Float) `{ glVertexAttrib3f(index, x, y, z); `}
 346
 347 # Specify the value of a generic vertex attribute
 348 fun glVertexAttrib4f(index: Int, x, y, z, w: Float) `{ glVertexAttrib4f(index, x, y, z, w); `}
 349
 350 # Specify the value of a uniform variable for the current program object
 351 fun glUniform1i(index, x: Int) `{ glUniform1i(index, x); `}
 352
 353 # Specify the value of a uniform variable for the current program object
 354 fun glUniform2i(index, x, y: Int) `{ glUniform2i(index, x, y); `}
 355
 356 # Specify the value of a uniform variable for the current program object
 357 fun glUniform3i(index, x, y, z: Int) `{ glUniform3i(index, x, y, z); `}
 358
 359 # Specify the value of a uniform variable for the current program object
 360 fun glUniform4i(index, x, y, z, w: Int) `{ glUniform4i(index, x, y, z, w); `}
 361
 362 # TODO glUniform*f
 363
 364 # Low level array of `Float`
 365 class GLfloatArray
 366         super CArray[Float]
 367         redef type NATIVE: NativeGLfloatArray
 368
 369         init do native_array = new NativeGLfloatArray(length)
 370
 371         # Create with the content of `array`
 372         new from(array: Array[Float])
 373         do
 374                 var arr = new GLfloatArray(array.length)
 375                 arr.fill_from array
 376                 return arr
 377         end
 378
 379         # Fill with the content of `array`
 380         fun fill_from(array: Array[Float])
 381         do
 382                 assert length >= array.length
 383                 for k in [0..array.length[ do
 384                         self[k] = array[k]
 385                 end
 386         end
 387 end
 388
 389 # An array of `GLfloat` in C (`GLfloat*`)
 390 extern class NativeGLfloatArray `{ GLfloat* `}
 391         super NativeCArray
 392         redef type E: Float
 393
 394         new(size: Int) `{ return calloc(size, sizeof(GLfloat)); `}
 395
 396         redef fun [](index) `{ return self[index]; `}
 397         redef fun []=(index, val) `{ self[index] = val; `}
 398
 399         redef fun +(offset) `{ return self + offset; `}
 400 end
 401
 402 # General type for OpenGL enumerations
 403 extern class GLEnum `{ GLenum `}
 404
 405         redef fun hash `{ return self; `}
 406
 407         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 408 end
 409
 410 # An OpenGL ES 2.0 error code
 411 extern class GLError
 412         super GLEnum
 413
 414         # Is there no error?
 415         fun is_ok: Bool do return is_no_error
 416
 417         # Is this not an error?
 418         fun is_no_error: Bool `{ return self == GL_NO_ERROR; `}
 419
 420         fun is_invalid_enum: Bool `{ return self == GL_INVALID_ENUM; `}
 421         fun is_invalid_value: Bool `{ return self == GL_INVALID_VALUE; `}
 422         fun is_invalid_operation: Bool `{ return self == GL_INVALID_OPERATION; `}
 423         fun is_invalid_framebuffer_operation: Bool `{ return self == GL_INVALID_FRAMEBUFFER_OPERATION; `}
 424         fun is_out_of_memory: Bool `{ return self == GL_OUT_OF_MEMORY; `}
 425
 426         redef fun to_s
 427         do
 428                 if is_no_error then return "No error"
 429                 if is_invalid_enum then return "Invalid enum"
 430                 if is_invalid_value then return "Invalid value"
 431                 if is_invalid_operation then return "Invalid operation"
 432                 if is_invalid_framebuffer_operation then return "invalid framebuffer operation"
 433                 if is_out_of_memory then return "Out of memory"
 434                 return "Truely unknown error"
 435         end
 436 end
 437
 438 fun assert_no_gl_error
 439 do
 440         var error = gl.error
 441         if not error.is_ok then
 442                 print "GL error: {error}"
 443                 abort
 444         end
 445 end
 446
 447 # Does `name` corresponds to a texture?
 448 fun glIsTexture(name: Int): Bool `{ return glIsTexture(name); `}
 449
 450 # Bind the named `texture` to a `target`
 451 fun glBindTexture(target: GLTextureTarget, texture: Int) `{ glBindTexture(target, texture); `}
 452
 453 # Set pixel storage modes
 454 fun glPixelStorei(parameter: GLPack, val: Int) `{ glPixelStorei(parameter, val); `}
 455
 456 # Symbolic name of the parameter to be set with `glPixelStorei`
 457 extern class GLPack
 458         super GLEnum
 459 end
 460
 461 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 462 fun gl_PACK_ALIGNEMENT: GLPack `{ return GL_PACK_ALIGNMENT; `}
 463
 464 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 465 fun gl_UNPACK_ALIGNEMENT: GLPack `{ return GL_UNPACK_ALIGNMENT; `}
 466
 467 # TODO GL_PACK_ROW_LENGTH, GL_PACK_IMAGE_HEIGHT, GL_PACK_SKIP_PIXELS, GL_PACK_SKIP_ROWS, GL_PACK_SKIP_IMAGES
 468 # GL_UNPACK_ROW_LENGTH, GL_UNPACK_IMAGE_HEIGHT, GL_UNPACK_SKIP_PIXELS, GL_UNPACK_SKIP_ROWS, GL_UNPACK_SKIP_IMAGES
 469
 470 # Specify a two-dimensional texture image
 471 fun glTexImage2D(target: GLTextureTarget, level, internalformat, width, height, border: Int,
 472                  format: GLPixelFormat, typ: GLPixelType, data: NativeCByteArray) `{
 473         glTexImage2D(target, level, internalformat, width, height, border, format, typ, data);
 474 `}
 475
 476 # Texture minifying and magnifying function
 477 extern class GLTextureFilter
 478         super GLEnum
 479 end
 480
 481 fun gl_NEAREST: GLTextureFilter `{ return GL_NEAREST; `}
 482 fun gl_LINEAR: GLTextureFilter `{ return GL_LINEAR; `}
 483 fun gl_NEAREST_MIPMAP_NEAREST: GLTextureFilter `{ return GL_NEAREST_MIPMAP_NEAREST; `}
 484 fun gl_LINEAR_MIPMAP_NEAREST: GLTextureFilter `{ return GL_LINEAR_MIPMAP_NEAREST; `}
 485 fun gl_NEAREST_MIPMAP_NINEAR: GLTextureFilter `{ return GL_NEAREST_MIPMAP_LINEAR; `}
 486 fun gl_LINEAR_MIPMAP_LINEAR: GLTextureFilter `{ return GL_LINEAR_MIPMAP_LINEAR; `}
 487
 488 # Wrap parameter of a texture
 489 #
 490 # Used by: `tex_parameter_wrap_*`
 491 extern class GLTextureWrap
 492         super GLEnum
 493
 494         new clamp_to_edge `{ return GL_CLAMP_TO_EDGE; `}
 495         new mirrored_repeat `{ return GL_MIRRORED_REPEAT; `}
 496         new repeat `{ return GL_REPEAT; `}
 497 end
 498
 499 # Target texture
 500 extern class GLTextureTarget
 501         super GLEnum
 502 end
 503
 504 # Two-dimensional texture
 505 fun gl_TEXTURE_2D: GLTextureTarget `{ return GL_TEXTURE_2D; `}
 506
 507 # Cube map texture
 508 fun gl_TEXTURE_CUBE_MAP: GLTextureTarget `{ return GL_TEXTURE_CUBE_MAP; `}
 509
 510 # TODO GL_TEXTURE_CUBE_MAP_POSITIVE_X, GL_TEXTURE_CUBE_MAP_NEGATIVE_X, GL_TEXTURE_CUBE_MAP_POSITIVE_Y,
 511 # GL_TEXTURE_CUBE_MAP_NEGATIVE_Y, GL_TEXTURE_CUBE_MAP_POSITIVE_Z, GL_TEXTURE_CUBE_MAP_NEGATIVE_Z
 512
 513 # A server-side capability
 514 class GLCap
 515
 516         # TODO private init
 517
 518         # Internal OpenGL integer for this capability
 519         private var val: Int
 520
 521         # Enable this server-side capability
 522         fun enable do enable_native(val)
 523         private fun enable_native(cap: Int) `{ glEnable(cap); `}
 524
 525         # Disable this server-side capability
 526         fun disable do disable_native(val)
 527         private fun disable_native(cap: Int) `{ glDisable(cap); `}
 528
 529         redef fun hash do return val
 530         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 531 end
 532
 533 # Attach a renderbuffer object to a framebuffer object
 534 fun glFramebufferRenderbuffer(target: GLFramebufferTarget, attachment: GLAttachment,
 535                               renderbuffertarget: GLRenderbufferTarget, renderbuffer: Int) `{
 536         glFramebufferRenderbuffer(target, attachment, renderbuffertarget, renderbuffer);
 537 `}
 538
 539 # Establish data storage, `format` and dimensions of the `target` renderbuffer object's image
 540 fun glRenderbufferStorage(target: GLRenderbufferTarget, format: GLRenderbufferFormat, width, height: Int) `{
 541         glRenderbufferStorage(GL_RENDERBUFFER, format, width, height);
 542 `}
 543
 544 # Format for a renderbuffer
 545 extern class GLRenderbufferFormat
 546         super GLEnum
 547 end
 548
 549 # 4 red, 4 green, 4 blue, 4 alpha bits format
 550 fun gl_RGBA4: GLRenderbufferFormat `{ return GL_RGBA4; `}
 551
 552 # 5 red, 6 green, 5 blue bits format
 553 fun gl_RGB565: GLRenderbufferFormat `{ return GL_RGB565; `}
 554
 555 # 5 red, 5 green, 5 blue, 1 alpha bits format
 556 fun gl_RGB_A1: GLRenderbufferFormat `{ return GL_RGB5_A1; `}
 557
 558 # 16 depth bits format
 559 fun gl_DEPTH_COMPNENT16: GLRenderbufferFormat `{ return GL_DEPTH_COMPONENT16; `}
 560
 561 # 8 stencil bits format
 562 fun gl_STENCIL_INDEX8: GLRenderbufferFormat `{ return GL_STENCIL_INDEX8; `}
 563
 564 # Renderbuffer attachment point to a framebuffer
 565 extern class GLAttachment
 566         super GLEnum
 567 end
 568
 569 # First color attachment point
 570 fun gl_COLOR_ATTACHMENT0: GLAttachment `{ return GL_COLOR_ATTACHMENT0; `}
 571
 572 # Depth attachment point
 573 fun gl_DEPTH_ATTACHMENT: GLAttachment `{ return GL_DEPTH_ATTACHMENT; `}
 574
 575 # Stencil attachment
 576 fun gl_STENCIL_ATTACHMENT: GLAttachment `{ return GL_STENCIL_ATTACHMENT; `}
 577
 578 redef class Sys
 579         private var gles = new GLES is lazy
 580 end
 581
 582 # Entry points to OpenGL ES 2.0 services
 583 fun gl: GLES do return sys.gles
 584
 585 # OpenGL ES 2.0 services
 586 class GLES
 587
 588         # Clear the color buffer to `red`, `green`, `blue` and `alpha`
 589         fun clear_color(red, green, blue, alpha: Float) `{
 590                 glClearColor(red, green, blue, alpha);
 591         `}
 592
 593         # Set the viewport
 594         fun viewport(x, y, width, height: Int) `{ glViewport(x, y, width, height); `}
 595
 596         # Specify mapping of depth values from normalized device coordinates to window coordinates
 597         #
 598         # Default at `gl_depth_range(0.0, 1.0)`
 599         fun depth_range(near, far: Float) `{ glDepthRangef(near, far); `}
 600
 601         # Define front- and back-facing polygons
 602         #
 603         # Front-facing polygons are clockwise if `value`, counter-clockwise otherwise.
 604         fun front_face=(value: Bool) `{ glFrontFace(value? GL_CW: GL_CCW); `}
 605
 606         # Specify whether front- or back-facing polygons can be culled, default is `back` only
 607         #
 608         # One or both of `front` or `back` must be `true`. If you want to deactivate culling
 609         # use `(new GLCap.cull_face).disable`.
 610         #
 611         # Require: `front or back`
 612         fun cull_face(front, back: Bool)
 613         do
 614                 assert not (front or back)
 615                 cull_face_native(front, back)
 616         end
 617
 618         private fun cull_face_native(front, back: Bool) `{
 619                 glCullFace(front? back? GL_FRONT_AND_BACK: GL_BACK: GL_FRONT);
 620         `}
 621
 622         # Clear the `buffer`
 623         fun clear(buffer: GLBuffer) `{ glClear(buffer); `}
 624
 625         # Last error from OpenGL ES 2.0
 626         fun error: GLError `{ return glGetError(); `}
 627
 628         # Query the boolean value at `key`
 629         private fun get_bool(key: Int): Bool `{
 630                 GLboolean val;
 631                 glGetBooleanv(key, &val);
 632                 return val == GL_TRUE;
 633         `}
 634
 635         # Query the floating point value at `key`
 636         private fun get_float(key: Int): Float `{
 637                 GLfloat val;
 638                 glGetFloatv(key, &val);
 639                 return val;
 640         `}
 641
 642         # Query the integer value at `key`
 643         private fun get_int(key: Int): Int `{
 644                 GLint val;
 645                 glGetIntegerv(key, &val);
 646                 return val;
 647         `}
 648
 649         # Does this driver support shader compilation?
 650         #
 651         # Should always return `true` in OpenGL ES 2.0 and 3.0.
 652         fun shader_compiler: Bool do return get_bool(0x8DFA)
 653
 654         # Enable or disable writing into the depth buffer
 655         fun depth_mask(value: Bool) `{ glDepthMask(value); `}
 656
 657         # Set the scale and units used to calculate depth values
 658         fun polygon_offset(factor, units: Float) `{ glPolygonOffset(factor, units); `}
 659
 660         # Specify the width of rasterized lines
 661         fun line_width(width: Float) `{ glLineWidth(width); `}
 662
 663         # Set the pixel arithmetic for the blending operations
 664         #
 665         # Defaultvalues before assignation:
 666         # * `src_factor`: `GLBlendFactor::one`
 667         # * `dst_factor`: `GLBlendFactor::zero`
 668         fun blend_func(src_factor, dst_factor: GLBlendFactor) `{
 669                 glBlendFunc(src_factor, dst_factor);
 670         `}
 671
 672         # Specify the value used for depth buffer comparisons
 673         #
 674         # Default value is `GLDepthFunc::less`
 675         #
 676         # Foreign: glDepthFunc
 677         fun depth_func(func: GLDepthFunc) `{ glDepthFunc(func); `}
 678
 679         # Copy a block of pixels from the framebuffer of `fomat` and `typ` at `data`
 680         #
 681         # Foreign: glReadPixel
 682         fun read_pixels(x, y, width, height: Int, format: GLPixelFormat, typ: GLPixelType, data: Pointer) `{
 683                 glReadPixels(x, y, width, height, format, typ, data);
 684         `}
 685
 686         # Set the texture minifying function
 687         #
 688         # Foreign: glTexParameter with GL_TEXTURE_MIN_FILTER
 689         fun tex_parameter_min_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 690                 glTexParameteri(target, GL_TEXTURE_MIN_FILTER, value);
 691         `}
 692
 693         # Set the texture magnification function
 694         #
 695         # Foreign: glTexParameter with GL_TEXTURE_MAG_FILTER
 696         fun tex_parameter_mag_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 697                 glTexParameteri(target, GL_TEXTURE_MAG_FILTER, value);
 698         `}
 699
 700         # Set the texture wrap parameter for coordinates _s_
 701         #
 702         # Foreign: glTexParameter with GL_TEXTURE_WRAP_S
 703         fun tex_parameter_wrap_s(target: GLTextureTarget, value: GLTextureWrap) `{
 704                 glTexParameteri(target, GL_TEXTURE_WRAP_S, value);
 705         `}
 706
 707         # Set the texture wrap parameter for coordinates _t_
 708         #
 709         # Foreign: glTexParameter with GL_TEXTURE_WRAP_T
 710         fun tex_parameter_wrap_t(target: GLTextureTarget, value: GLTextureWrap) `{
 711                 glTexParameteri(target, GL_TEXTURE_WRAP_T, value);
 712         `}
 713
 714         # Render primitives from array data
 715         #
 716         # Foreign: glDrawArrays
 717         fun draw_arrays(mode: GLDrawMode, from, count: Int) `{ glDrawArrays(mode, from, count); `}
 718
 719         # OpenGL server-side capabilities
 720         var capabilities = new GLCapabilities is lazy
 721 end
 722
 723 # Bind `framebuffer` to a framebuffer target
 724 #
 725 # In OpenGL ES 2.0, `target` must be `gl_FRAMEBUFFER`.
 726 fun glBindFramebuffer(target: GLFramebufferTarget, framebuffer: Int) `{
 727         glBindFramebuffer(target, framebuffer);
 728 `}
 729
 730 # Target of `glBindFramebuffer`
 731 extern class GLFramebufferTarget
 732         super GLEnum
 733 end
 734
 735 # Target both reading and writing on the framebuffer with `glBindFramebuffer`
 736 fun gl_FRAMEBUFFER: GLFramebufferTarget `{ return GL_FRAMEBUFFER; `}
 737
 738 # Bind `renderbuffer` to a renderbuffer target
 739 #
 740 # In OpenGL ES 2.0, `target` must be `gl_RENDERBUFFER`.
 741 fun glBindRenderbuffer(target: GLRenderbufferTarget, renderbuffer: Int) `{
 742         glBindRenderbuffer(target, renderbuffer);
 743 `}
 744
 745 # Target of `glBindRenderbuffer`
 746 extern class GLRenderbufferTarget
 747         super GLEnum
 748 end
 749
 750 # Target a renderbuffer with `glBindRenderbuffer`
 751 fun gl_RENDERBUFFER: GLRenderbufferTarget `{ return GL_RENDERBUFFER; `}
 752
 753 # Specify implementation specific hints
 754 fun glHint(target: GLHintTarget, mode: GLHintMode) `{
 755         glHint(target, mode);
 756 `}
 757
 758 # Generate and fill set of mipmaps for the texture object `target`
 759 fun glGenerateMipmap(target: GLTextureTarget) `{ glGenerateMipmap(target); `}
 760
 761 # Bind the named `buffer` object
 762 fun glBindBuffer(target: GLArrayBuffer, buffer: Int) `{ glBindBuffer(target, buffer); `}
 763
 764 # Target to which bind the buffer with `glBindBuffer`
 765 extern class GLArrayBuffer
 766         super GLEnum
 767 end
 768
 769 # Array buffer target
 770 fun gl_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ARRAY_BUFFER; `}
 771
 772 # Element array buffer
 773 fun gl_ELEMENT_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ELEMENT_ARRAY_BUFFER; `}
 774
 775 # Completeness status of a framebuffer object
 776 fun glCheckFramebufferStatus(target: GLFramebufferTarget): GLFramebufferStatus `{
 777         return glCheckFramebufferStatus(target);
 778 `}
 779
 780 # Return value of `glCheckFramebufferStatus`
 781 extern class GLFramebufferStatus
 782         super GLEnum
 783
 784         redef fun to_s
 785         do
 786                 if self == gl_FRAMEBUFFER_COMPLETE then return "complete"
 787                 if self == gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT then return "incomplete attachment"
 788                 if self == gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS then return "incomplete dimension"
 789                 if self == gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT then return "incomplete missing attachment"
 790                 if self == gl_FRAMEBUFFER_UNSUPPORTED then return "unsupported"
 791                 return "unknown"
 792         end
 793 end
 794
 795 # The framebuffer is complete
 796 fun gl_FRAMEBUFFER_COMPLETE: GLFramebufferStatus `{
 797         return GL_FRAMEBUFFER_COMPLETE;
 798 `}
 799
 800 # Not all framebuffer attachment points are framebuffer attachment complete
 801 fun gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT: GLFramebufferStatus `{
 802         return GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT;
 803 `}
 804
 805 # Not all attached images have the same width and height
 806 fun gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS: GLFramebufferStatus `{
 807         return GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS;
 808 `}
 809
 810 # No images are attached to the framebuffer
 811 fun gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT: GLFramebufferStatus `{
 812         return GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT;
 813 `}
 814
 815 # The combination of internal formats of the attached images violates an implementation-dependent set of restrictions
 816 fun gl_FRAMEBUFFER_UNSUPPORTED: GLFramebufferStatus `{
 817         return GL_FRAMEBUFFER_UNSUPPORTED;
 818 `}
 819
 820 # Hint target for `glHint`
 821 extern class GLHintTarget
 822         super GLEnum
 823 end
 824
 825 # Indicates the quality of filtering when generating mipmap images
 826 fun gl_GENERATE_MIPMAP_HINT: GLHintTarget `{ return GL_GENERATE_MIPMAP_HINT; `}
 827
 828 # Hint mode for `glHint`
 829 extern class GLHintMode
 830         super GLEnum
 831 end
 832
 833 # The most efficient option should be chosen
 834 fun gl_FASTEST: GLHintMode `{ return GL_FASTEST; `}
 835
 836 # The most correct, or highest quality, option should be chosen
 837 fun gl_NICEST: GLHintMode `{ return GL_NICEST; `}
 838
 839 # No preference
 840 fun gl_DONT_CARE: GLHintMode `{ return GL_DONT_CARE; `}
 841
 842 # Attach a level of a texture object as a logical buffer to the currently bound framebuffer object
 843 fun glFramebufferTexture2D(target: GLFramebufferTarget, attachment: GLAttachment,
 844                            texture_target: GLTextureTarget,  texture, level: Int) `{
 845         glFramebufferTexture2D(target, attachment, texture_target, texture, level);
 846 `}
 847
 848 # Entry point to OpenGL server-side capabilities
 849 class GLCapabilities
 850
 851         # GL capability: blend the computed fragment color values
 852         #
 853         # Foreign: GL_BLEND
 854         var blend: GLCap is lazy do return new GLCap(0x0BE2)
 855
 856         # GL capability: cull polygons based of their winding in window coordinates
 857         #
 858         # Foreign: GL_CULL_FACE
 859         var cull_face: GLCap is lazy do return new GLCap(0x0B44)
 860
 861         # GL capability: do depth comparisons and update the depth buffer
 862         #
 863         # Foreign: GL_DEPTH_TEST
 864         var depth_test: GLCap is lazy do return new GLCap(0x0B71)
 865
 866         # GL capability: dither color components or indices before they are written to the color buffer
 867         #
 868         # Foreign: GL_DITHER
 869         var dither: GLCap is lazy do return new GLCap(0x0BE2)
 870
 871         # GL capability: add an offset to depth values of a polygon fragment before depth test
 872         #
 873         # Foreign: GL_POLYGON_OFFSET_FILL
 874         var polygon_offset_fill: GLCap is lazy do return new GLCap(0x8037)
 875
 876         # GL capability: compute a temporary coverage value where each bit is determined by the alpha value at the corresponding location
 877         #
 878         # Foreign: GL_SAMPLE_ALPHA_TO_COVERAGE
 879         var sample_alpha_to_coverage: GLCap is lazy do return new GLCap(0x809E)
 880
 881         # GL capability: AND the fragment coverage with the temporary coverage value
 882         #
 883         # Foreign: GL_SAMPLE_COVERAGE
 884         var sample_coverage: GLCap is lazy do return new GLCap(0x80A0)
 885
 886         # GL capability: discard fragments that are outside the scissor rectangle
 887         #
 888         # Foreign: GL_SCISSOR_TEST
 889         var scissor_test: GLCap is lazy do return new GLCap(0x0C11)
 890
 891         # GL capability: do stencil testing and update the stencil buffer
 892         #
 893         # Foreign: GL_STENCIL_TEST
 894         var stencil_test: GLCap is lazy do return new GLCap(0x0B90)
 895 end
 896
 897 # Float related data types of OpenGL ES 2.0 shaders
 898 #
 899 # Only data types supported by shader attributes, as seen with
 900 # `GLProgram::active_attrib_type`.
 901 extern class GLFloatDataType
 902         super GLEnum
 903
 904         fun is_float: Bool `{ return self == GL_FLOAT; `}
 905         fun is_float_vec2: Bool `{ return self == GL_FLOAT_VEC2; `}
 906         fun is_float_vec3: Bool `{ return self == GL_FLOAT_VEC3; `}
 907         fun is_float_vec4: Bool `{ return self == GL_FLOAT_VEC4; `}
 908         fun is_float_mat2: Bool `{ return self == GL_FLOAT_MAT2; `}
 909         fun is_float_mat3: Bool `{ return self == GL_FLOAT_MAT3; `}
 910         fun is_float_mat4: Bool `{ return self == GL_FLOAT_MAT4; `}
 911
 912         # Instances of `GLFloatDataType` can be equal to instances of `GLDataType`
 913         redef fun ==(o)
 914         do
 915                 return o != null and o isa GLFloatDataType and o.hash == self.hash
 916         end
 917 end
 918
 919 # All data types of OpenGL ES 2.0 shaders
 920 #
 921 # These types can be used by shader uniforms, as seen with
 922 # `GLProgram::active_uniform_type`.
 923 extern class GLDataType
 924         super GLFloatDataType
 925
 926         fun is_int: Bool `{ return self == GL_INT; `}
 927         fun is_int_vec2: Bool `{ return self == GL_INT_VEC2; `}
 928         fun is_int_vec3: Bool `{ return self == GL_INT_VEC3; `}
 929         fun is_int_vec4: Bool `{ return self == GL_INT_VEC4; `}
 930         fun is_bool: Bool `{ return self == GL_BOOL; `}
 931         fun is_bool_vec2: Bool `{ return self == GL_BOOL_VEC2; `}
 932         fun is_bool_vec3: Bool `{ return self == GL_BOOL_VEC3; `}
 933         fun is_bool_vec4: Bool `{ return self == GL_BOOL_VEC4; `}
 934         fun is_sampler_2d: Bool `{ return self == GL_SAMPLER_2D; `}
 935         fun is_sampler_cube: Bool `{ return self == GL_SAMPLER_CUBE; `}
 936 end
 937
 938 # Kind of primitives to render with `GLES::draw_arrays`
 939 extern class GLDrawMode
 940         super GLEnum
 941
 942         new points `{ return GL_POINTS; `}
 943         new line_strip `{ return GL_LINE_STRIP; `}
 944         new line_loop `{ return GL_LINE_LOOP; `}
 945         new lines `{ return GL_LINES; `}
 946         new triangle_strip `{ return GL_TRIANGLE_STRIP; `}
 947         new triangle_fan `{ return GL_TRIANGLE_FAN; `}
 948         new triangles `{ return GL_TRIANGLES; `}
 949 end
 950
 951 # Pixel arithmetic for blending operations
 952 #
 953 # Used by `GLES::blend_func`
 954 extern class GLBlendFactor
 955         super GLEnum
 956
 957         new zero `{ return GL_ZERO; `}
 958         new one `{ return GL_ONE; `}
 959         new src_color `{ return GL_SRC_COLOR; `}
 960         new one_minus_src_color `{ return GL_ONE_MINUS_SRC_COLOR; `}
 961         new dst_color `{ return GL_DST_COLOR; `}
 962         new one_minus_dst_color `{ return GL_ONE_MINUS_DST_COLOR; `}
 963         new src_alpha `{ return GL_SRC_ALPHA; `}
 964         new one_minus_src_alpha `{ return GL_ONE_MINUS_SRC_ALPHA; `}
 965         new dst_alpha `{ return GL_DST_ALPHA; `}
 966         new one_minus_dst_alpha `{ return GL_ONE_MINUS_DST_ALPHA; `}
 967         new constant_color `{ return GL_CONSTANT_COLOR; `}
 968         new one_minus_constant_color `{ return GL_ONE_MINUS_CONSTANT_COLOR; `}
 969         new constant_alpha `{ return GL_CONSTANT_ALPHA; `}
 970         new one_minus_constant_alpha `{ return GL_ONE_MINUS_CONSTANT_ALPHA; `}
 971
 972         # Used for destination only
 973         new src_alpha_saturate `{ return GL_SRC_ALPHA_SATURATE; `}
 974 end
 975
 976 # Condition under which a pixel will be drawn
 977 #
 978 # Used by `GLES::depth_func`
 979 extern class GLDepthFunc
 980         super GLEnum
 981
 982          new never `{ return GL_NEVER; `}
 983          new less `{ return GL_LESS; `}
 984          new equal `{ return GL_EQUAL; `}
 985          new lequal `{ return GL_LEQUAL; `}
 986          new greater `{ return GL_GREATER; `}
 987          new not_equal `{ return GL_NOTEQUAL; `}
 988          new gequal `{ return GL_GEQUAL; `}
 989          new always `{ return GL_ALWAYS; `}
 990 end
 991
 992 # Format of pixel data
 993 #
 994 # Used by `GLES::read_pixels`
 995 extern class GLPixelFormat
 996         super GLEnum
 997
 998         new alpha `{ return GL_ALPHA; `}
 999         new rgb `{ return GL_RGB; `}
1000         new rgba `{ return GL_RGBA; `}
1001 end
1002
1003 # Data type of pixel data
1004 #
1005 # Used by `GLES::read_pixels`
1006 extern class GLPixelType
1007         super GLEnum
1008
1009         new unsigned_byte `{ return GL_UNSIGNED_BYTE; `}
1010         new unsigned_short_5_6_5 `{ return GL_UNSIGNED_SHORT_5_6_5; `}
1011         new unsigned_short_4_4_4_4 `{ return GL_UNSIGNED_SHORT_4_4_4_4; `}
1012         new unsigned_short_5_5_5_1 `{ return GL_UNSIGNED_SHORT_5_5_5_1; `}
1013 end
1014
1015 # Set of buffers as a bitwise OR mask, used by `GLES::clear`
1016 #
1017 # ~~~
1018 # var buffers = (new GLBuffer).color.depth
1019 # gl.clear buffers
1020 # ~~~
1021 extern class GLBuffer `{ GLbitfield `}
1022         # Get an empty set of buffers
1023         new `{ return 0; `}
1024
1025         # Add the color buffer to the returned buffer set
1026         fun color: GLBuffer `{ return self | GL_COLOR_BUFFER_BIT; `}
1027
1028         # Add the depth buffer to the returned buffer set
1029         fun depth: GLBuffer `{ return self | GL_DEPTH_BUFFER_BIT; `}
1030
1031         # Add the stencil buffer to the returned buffer set
1032         fun stencil: GLBuffer `{ return self | GL_STENCIL_BUFFER_BIT; `}
1033 end