src/loader.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Loading of Nit source files
  18 module loader
  19
  20 import modelbuilder_base
  21
  22 redef class ToolContext
  23         # Option --path
  24         var opt_path = new OptionArray("Set include path for loaders (may be used more than once)", "-I", "--path")
  25
  26         # Option --only-metamodel
  27         var opt_only_metamodel = new OptionBool("Stop after meta-model processing", "--only-metamodel")
  28
  29         # Option --only-parse
  30         var opt_only_parse = new OptionBool("Only proceed to parse step of loaders", "--only-parse")
  31
  32         redef init
  33         do
  34                 super
  35                 option_context.add_option(opt_path, opt_only_parse, opt_only_metamodel)
  36         end
  37 end
  38
  39 redef class ModelBuilder
  40         redef init
  41         do
  42                 super
  43
  44                 # Setup the paths value
  45                 paths.append(toolcontext.opt_path.value)
  46
  47                 var path_env = "NIT_PATH".environ
  48                 if not path_env.is_empty then
  49                         paths.append(path_env.split_with(':'))
  50                 end
  51
  52                 var nit_dir = toolcontext.nit_dir
  53                 var libname = "{nit_dir}/lib"
  54                 if libname.file_exists then paths.add(libname)
  55         end
  56
  57         # Load a bunch of modules.
  58         # `modules` can contains filenames or module names.
  59         # Imported modules are automatically loaded and modelized.
  60         # The result is the corresponding model elements.
  61         # Errors and warnings are printed with the toolcontext.
  62         #
  63         # Note: class and property model elements are not analysed.
  64         fun parse(modules: Sequence[String]): Array[MModule]
  65         do
  66                 var time0 = get_time
  67                 # Parse and recursively load
  68                 self.toolcontext.info("*** PARSE ***", 1)
  69                 var mmodules = new ArraySet[MModule]
  70                 for a in modules do
  71                         var nmodule = self.load_module(a)
  72                         if nmodule == null then continue # Skip error
  73                         # Load imported module
  74                         build_module_importation(nmodule)
  75
  76                         mmodules.add(nmodule.mmodule.as(not null))
  77                 end
  78                 var time1 = get_time
  79                 self.toolcontext.info("*** END PARSE: {time1-time0} ***", 2)
  80
  81                 self.toolcontext.check_errors
  82
  83                 if toolcontext.opt_only_parse.value then
  84                         self.toolcontext.info("*** ONLY PARSE...", 1)
  85                         exit(0)
  86                 end
  87
  88                 return mmodules.to_a
  89         end
  90
  91         # Load recursively all modules of the group `mgroup`.
  92         # See `parse` for details.
  93         fun parse_group(mgroup: MGroup): Array[MModule]
  94         do
  95                 var res = new Array[MModule]
  96                 visit_group(mgroup)
  97                 for mg in mgroup.in_nesting.smallers do
  98                         for mp in mg.module_paths do
  99                                 var nmodule = self.load_module(mp.filepath)
 100                                 if nmodule == null then continue # Skip error
 101                                 # Load imported module
 102                                 build_module_importation(nmodule)
 103
 104                                 res.add(nmodule.mmodule.as(not null))
 105                         end
 106                 end
 107                 return res
 108         end
 109
 110         # Load a bunch of modules and groups.
 111         # Each name can be a module or a group.
 112         # If it is a group then recursively all its modules are parsed.
 113         # See `parse` for details.
 114         fun parse_full(names: Sequence[String]): Array[MModule]
 115         do
 116                 var time0 = get_time
 117                 # Parse and recursively load
 118                 self.toolcontext.info("*** PARSE ***", 1)
 119                 var mmodules = new ArraySet[MModule]
 120                 for a in names do
 121                         var mgroup = self.get_mgroup(a)
 122                         if mgroup != null then
 123                                 mmodules.add_all parse_group(mgroup)
 124                                 continue
 125                         end
 126                         var nmodule = self.load_module(a)
 127                         if nmodule == null then continue # Skip error
 128                         # Load imported module
 129                         build_module_importation(nmodule)
 130
 131                         mmodules.add(nmodule.mmodule.as(not null))
 132                 end
 133                 var time1 = get_time
 134                 self.toolcontext.info("*** END PARSE: {time1-time0} ***", 2)
 135
 136                 self.toolcontext.check_errors
 137
 138                 if toolcontext.opt_only_parse.value then
 139                         self.toolcontext.info("*** ONLY PARSE...", 1)
 140                         exit(0)
 141                 end
 142
 143                 return mmodules.to_a
 144         end
 145
 146         # The list of directories to search for top level modules
 147         # The list is initially set with:
 148         #
 149         #   * the toolcontext --path option
 150         #   * the NIT_PATH environment variable
 151         #   * `toolcontext.nit_dir`
 152         # Path can be added (or removed) by the client
 153         var paths = new Array[String]
 154
 155         # Like (and used by) `get_mmodule_by_name` but just return the ModulePath
 156         fun search_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable ModulePath
 157         do
 158                 # First, look in groups
 159                 var c = mgroup
 160                 while c != null do
 161                         var dirname = c.filepath
 162                         if dirname == null then break # virtual group
 163                         if dirname.has_suffix(".nit") then break # singleton project
 164
 165                         # Second, try the directory to find a file
 166                         var try_file = dirname + "/" + name + ".nit"
 167                         if try_file.file_exists then
 168                                 var res = self.identify_file(try_file.simplify_path)
 169                                 assert res != null
 170                                 return res
 171                         end
 172
 173                         # Third, try if the requested module is itself a group
 174                         try_file = dirname + "/" + name + "/" + name + ".nit"
 175                         if try_file.file_exists then
 176                                 var res = self.identify_file(try_file.simplify_path)
 177                                 assert res != null
 178                                 return res
 179                         end
 180
 181                         c = c.parent
 182                 end
 183
 184                 # Look at some known directories
 185                 var lookpaths = self.paths
 186
 187                 # Look in the directory of the group project also (even if not explicitly in the path)
 188                 if mgroup != null then
 189                         # path of the root group
 190                         var dirname = mgroup.mproject.root.filepath
 191                         if dirname != null then
 192                                 dirname = dirname.join_path("..").simplify_path
 193                                 if not lookpaths.has(dirname) and dirname.file_exists then
 194                                         lookpaths = lookpaths.to_a
 195                                         lookpaths.add(dirname)
 196                                 end
 197                         end
 198                 end
 199
 200                 var candidate = search_module_in_paths(anode.hot_location, name, lookpaths)
 201
 202                 if candidate == null then
 203                         if mgroup != null then
 204                                 error(anode, "Error: cannot find module {name} from {mgroup.name}. tried {lookpaths.join(", ")}")
 205                         else
 206                                 error(anode, "Error: cannot find module {name}. tried {lookpaths.join(", ")}")
 207                         end
 208                         return null
 209                 end
 210                 return candidate
 211         end
 212
 213         # Get a module by its short name; if required, the module is loaded, parsed and its hierarchies computed.
 214         # If `mgroup` is set, then the module search starts from it up to the top level (see `paths`);
 215         # if `mgroup` is null then the module is searched in the top level only.
 216         # If no module exists or there is a name conflict, then an error on `anode` is displayed and null is returned.
 217         fun get_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable MModule
 218         do
 219                 var path = search_mmodule_by_name(anode, mgroup, name)
 220                 if path == null then return null # Forward error
 221                 var res = self.load_module(path.filepath)
 222                 if res == null then return null # Forward error
 223                 # Load imported module
 224                 build_module_importation(res)
 225                 return res.mmodule.as(not null)
 226         end
 227
 228         # Search a module `name` from path `lookpaths`.
 229         # If found, the path of the file is returned
 230         private fun search_module_in_paths(location: nullable Location, name: String, lookpaths: Collection[String]): nullable ModulePath
 231         do
 232                 var candidate: nullable String = null
 233                 for dirname in lookpaths do
 234                         var try_file = (dirname + "/" + name + ".nit").simplify_path
 235                         if try_file.file_exists then
 236                                 if candidate == null then
 237                                         candidate = try_file
 238                                 else if candidate != try_file then
 239                                         # try to disambiguate conflicting modules
 240                                         var abs_candidate = module_absolute_path(candidate)
 241                                         var abs_try_file = module_absolute_path(try_file)
 242                                         if abs_candidate != abs_try_file then
 243                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 244                                         end
 245                                 end
 246                         end
 247                         try_file = (dirname + "/" + name + "/" + name + ".nit").simplify_path
 248                         if try_file.file_exists then
 249                                 if candidate == null then
 250                                         candidate = try_file
 251                                 else if candidate != try_file then
 252                                         # try to disambiguate conflicting modules
 253                                         var abs_candidate = module_absolute_path(candidate)
 254                                         var abs_try_file = module_absolute_path(try_file)
 255                                         if abs_candidate != abs_try_file then
 256                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 257                                         end
 258                                 end
 259                         end
 260                 end
 261                 if candidate == null then return null
 262                 return identify_file(candidate)
 263         end
 264
 265         # Cache for `identify_file` by realpath
 266         private var identified_files_by_path = new HashMap[String, nullable ModulePath]
 267
 268         # All the currently identified modules.
 269         # See `identify_file`.
 270         var identified_files = new Array[ModulePath]
 271
 272         # Identify a source file
 273         # Load the associated project and groups if required
 274         #
 275         # Silently return `null` if `path` is not a valid module path.
 276         fun identify_file(path: String): nullable ModulePath
 277         do
 278                 # special case for not a nit file
 279                 if path.file_extension != "nit" then
 280                         # search dirless files in known -I paths
 281                         if path.dirname == "" then
 282                                 var res = search_module_in_paths(null, path, self.paths)
 283                                 if res != null then return res
 284                         end
 285
 286                         # Found nothing? maybe it is a group...
 287                         var candidate = null
 288                         if path.file_exists then
 289                                 var mgroup = get_mgroup(path)
 290                                 if mgroup != null then
 291                                         var owner_path = mgroup.filepath.join_path(mgroup.name + ".nit")
 292                                         if owner_path.file_exists then candidate = owner_path
 293                                 end
 294                         end
 295
 296                         if candidate == null then
 297                                 return null
 298                         end
 299                         path = candidate
 300                 end
 301
 302                 # Fast track, the path is already known
 303                 var pn = path.basename(".nit")
 304                 var rp = module_absolute_path(path)
 305                 if identified_files_by_path.has_key(rp) then return identified_files_by_path[rp]
 306
 307                 # Search for a group
 308                 var mgrouppath = path.join_path("..").simplify_path
 309                 var mgroup = get_mgroup(mgrouppath)
 310
 311                 if mgroup == null then
 312                         # singleton project
 313                         var mproject = new MProject(pn, model)
 314                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 315                         mgroup.filepath = path
 316                         mproject.root = mgroup
 317                         toolcontext.info("found project `{pn}` at {path}", 2)
 318                 end
 319
 320                 var res = new ModulePath(pn, path, mgroup)
 321                 mgroup.module_paths.add(res)
 322
 323                 identified_files_by_path[rp] = res
 324                 identified_files.add(res)
 325                 return res
 326         end
 327
 328         # Groups by path
 329         private var mgroups = new HashMap[String, nullable MGroup]
 330
 331         # Return the mgroup associated to a directory path.
 332         # If the directory is not a group null is returned.
 333         #
 334         # Note: `paths` is also used to look for mgroups
 335         fun get_mgroup(dirpath: String): nullable MGroup
 336         do
 337                 if not dirpath.file_exists then do
 338                         for p in paths do
 339                                 var try = p / dirpath
 340                                 if try.file_exists then
 341                                         dirpath = try
 342                                         break label
 343                                 end
 344                         end
 345                         return null
 346                 end label
 347
 348                 var rdp = module_absolute_path(dirpath)
 349                 if mgroups.has_key(rdp) then
 350                         return mgroups[rdp]
 351                 end
 352
 353                 # Hack, a group is determined by:
 354                 # * the presence of a honomymous nit file
 355                 # * the fact that the directory is named `src`
 356                 var pn = rdp.basename(".nit")
 357                 var mp = dirpath.join_path(pn + ".nit").simplify_path
 358
 359                 var dirpath2 = dirpath
 360                 if not mp.file_exists then
 361                         if pn == "src" then
 362                                 # With a src directory, the group name is the name of the parent directory
 363                                 dirpath2 = rdp.dirname
 364                                 pn = dirpath2.basename("")
 365                         else
 366                                 return null
 367                         end
 368                 end
 369
 370                 # check parent directory
 371                 var parentpath = dirpath.join_path("..").simplify_path
 372                 var parent = get_mgroup(parentpath)
 373
 374                 var mgroup
 375                 if parent == null then
 376                         # no parent, thus new project
 377                         var mproject = new MProject(pn, model)
 378                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 379                         mproject.root = mgroup
 380                         toolcontext.info("found project `{mproject}` at {dirpath}", 2)
 381                 else
 382                         mgroup = new MGroup(pn, parent.mproject, parent)
 383                         toolcontext.info("found sub group `{mgroup.full_name}` at {dirpath}", 2)
 384                 end
 385                 var readme = dirpath2.join_path("README.md")
 386                 if not readme.file_exists then readme = dirpath2.join_path("README")
 387                 if readme.file_exists then
 388                         var mdoc = new MDoc(new Location(new SourceFile.from_string(readme, ""),0,0,0,0))
 389                         var s = new FileReader.open(readme)
 390                         while not s.eof do
 391                                 mdoc.content.add(s.read_line)
 392                         end
 393                         mgroup.mdoc = mdoc
 394                         mdoc.original_mentity = mgroup
 395                 end
 396                 mgroup.filepath = dirpath
 397                 mgroups[rdp] = mgroup
 398                 return mgroup
 399         end
 400
 401         # Force the identification of all ModulePath of the group and sub-groups.
 402         fun visit_group(mgroup: MGroup) do
 403                 var p = mgroup.filepath
 404                 for f in p.files do
 405                         var fp = p/f
 406                         var g = get_mgroup(fp)
 407                         if g != null then visit_group(g)
 408                         identify_file(fp)
 409                 end
 410         end
 411
 412         # Transform relative paths (starting with '../') into absolute paths
 413         private fun module_absolute_path(path: String): String do
 414                 return getcwd.join_path(path).simplify_path
 415         end
 416
 417         # Try to load a module AST using a path.
 418         # Display an error if there is a problem (IO / lexer / parser) and return null
 419         fun load_module_ast(filename: String): nullable AModule
 420         do
 421                 if filename.file_extension != "nit" then
 422                         self.toolcontext.error(null, "Error: file {filename} is not a valid nit module.")
 423                         return null
 424                 end
 425                 if not filename.file_exists then
 426                         self.toolcontext.error(null, "Error: file {filename} not found.")
 427                         return null
 428                 end
 429
 430                 self.toolcontext.info("load module {filename}", 2)
 431
 432                 # Load the file
 433                 var file = new FileReader.open(filename)
 434                 var lexer = new Lexer(new SourceFile(filename, file))
 435                 var parser = new Parser(lexer)
 436                 var tree = parser.parse
 437                 file.close
 438
 439                 # Handle lexer and parser error
 440                 var nmodule = tree.n_base
 441                 if nmodule == null then
 442                         var neof = tree.n_eof
 443                         assert neof isa AError
 444                         error(neof, neof.message)
 445                         return null
 446                 end
 447
 448                 return nmodule
 449         end
 450
 451         # Try to load a module using a path.
 452         # Display an error if there is a problem (IO / lexer / parser) and return null.
 453         # Note: usually, you do not need this method, use `get_mmodule_by_name` instead.
 454         #
 455         # The MModule is created however, the importation is not performed,
 456         # therefore you should call `build_module_importation`.
 457         fun load_module(filename: String): nullable AModule
 458         do
 459                 # Look for the module
 460                 var file = identify_file(filename)
 461                 if file == null then
 462                         toolcontext.error(null, "Error: cannot find module `{filename}`.")
 463                         return null
 464                 end
 465
 466                 # Already known and loaded? then return it
 467                 var mmodule = file.mmodule
 468                 if mmodule != null then
 469                         return mmodule2nmodule[mmodule]
 470                 end
 471
 472                 # Load it manually
 473                 var nmodule = load_module_ast(file.filepath)
 474                 if nmodule == null then return null # forward error
 475
 476                 # build the mmodule and load imported modules
 477                 mmodule = build_a_mmodule(file.mgroup, file.name, nmodule)
 478
 479                 if mmodule == null then return null # forward error
 480
 481                 # Update the file information
 482                 file.mmodule = mmodule
 483
 484                 return nmodule
 485         end
 486
 487         # Injection of a new module without source.
 488         # Used by the interpreter.
 489         fun load_rt_module(parent: nullable MModule, nmodule: AModule, mod_name: String): nullable AModule
 490         do
 491                 # Create the module
 492
 493                 var mgroup = null
 494                 if parent != null then mgroup = parent.mgroup
 495                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 496                 nmodule.mmodule = mmodule
 497                 nmodules.add(nmodule)
 498                 self.mmodule2nmodule[mmodule] = nmodule
 499
 500                 if parent!= null then
 501                         var imported_modules = new Array[MModule]
 502                         imported_modules.add(parent)
 503                         mmodule.set_visibility_for(parent, intrude_visibility)
 504                         mmodule.set_imported_mmodules(imported_modules)
 505                 else
 506                         build_module_importation(nmodule)
 507                 end
 508
 509                 return nmodule
 510         end
 511
 512         # Visit the AST and create the `MModule` object
 513         private fun build_a_mmodule(mgroup: nullable MGroup, mod_name: String, nmodule: AModule): nullable MModule
 514         do
 515                 # Check the module name
 516                 var decl = nmodule.n_moduledecl
 517                 if decl != null then
 518                         var decl_name = decl.n_name.n_id.text
 519                         if decl_name != mod_name then
 520                                 error(decl.n_name, "Error: module name missmatch; declared {decl_name} file named {mod_name}")
 521                         end
 522                 end
 523
 524                 # Check for conflicting module names in the project
 525                 if mgroup != null then
 526                         var others = model.get_mmodules_by_name(mod_name)
 527                         if others != null then for other in others do
 528                                 if other.mgroup!= null and other.mgroup.mproject == mgroup.mproject then
 529                                         var node: ANode
 530                                         if decl == null then node = nmodule else node = decl.n_name
 531                                         error(node, "Error: A module named `{other.full_name}` already exists at {other.location}")
 532                                         break
 533                                 end
 534                         end
 535                 end
 536
 537                 # Create the module
 538                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 539                 nmodule.mmodule = mmodule
 540                 nmodules.add(nmodule)
 541                 self.mmodule2nmodule[mmodule] = nmodule
 542
 543                 var source = nmodule.location.file
 544                 if source != null then
 545                         assert source.mmodule == null
 546                         source.mmodule = mmodule
 547                 end
 548
 549                 if decl != null then
 550                         # Extract documentation
 551                         var ndoc = decl.n_doc
 552                         if ndoc != null then
 553                                 var mdoc = ndoc.to_mdoc
 554                                 mmodule.mdoc = mdoc
 555                                 mdoc.original_mentity = mmodule
 556                         else
 557                                 advice(decl, "missing-doc", "Documentation warning: Undocumented module `{mmodule}`")
 558                         end
 559                         # Is the module a test suite?
 560                         mmodule.is_test_suite = not decl.get_annotations("test_suite").is_empty
 561                 end
 562
 563                 return mmodule
 564         end
 565
 566         # Analyze the module importation and fill the module_importation_hierarchy
 567         #
 568         # Unless you used `load_module`, the importation is already done and this method does a no-op.
 569         fun build_module_importation(nmodule: AModule)
 570         do
 571                 if nmodule.is_importation_done then return
 572                 nmodule.is_importation_done = true
 573                 var mmodule = nmodule.mmodule.as(not null)
 574                 var stdimport = true
 575                 var imported_modules = new Array[MModule]
 576                 for aimport in nmodule.n_imports do
 577                         stdimport = false
 578                         if not aimport isa AStdImport then
 579                                 continue
 580                         end
 581                         var mgroup = mmodule.mgroup
 582                         if aimport.n_name.n_quad != null then mgroup = null # Start from top level
 583                         for grp in aimport.n_name.n_path do
 584                                 var path = search_mmodule_by_name(grp, mgroup, grp.text)
 585                                 if path == null then return # Skip error
 586                                 mgroup = path.mgroup
 587                         end
 588                         var mod_name = aimport.n_name.n_id.text
 589                         var sup = self.get_mmodule_by_name(aimport.n_name, mgroup, mod_name)
 590                         if sup == null then continue # Skip error
 591                         aimport.mmodule = sup
 592                         imported_modules.add(sup)
 593                         var mvisibility = aimport.n_visibility.mvisibility
 594                         if mvisibility == protected_visibility then
 595                                 error(aimport.n_visibility, "Error: only properties can be protected.")
 596                                 return
 597                         end
 598                         if sup == mmodule then
 599                                 error(aimport.n_name, "Error: Dependency loop in module {mmodule}.")
 600                         end
 601                         if sup.in_importation < mmodule then
 602                                 error(aimport.n_name, "Error: Dependency loop between modules {mmodule} and {sup}.")
 603                                 return
 604                         end
 605                         mmodule.set_visibility_for(sup, mvisibility)
 606                 end
 607                 if stdimport then
 608                         var mod_name = "standard"
 609                         var sup = self.get_mmodule_by_name(nmodule, null, mod_name)
 610                         if sup != null then # Skip error
 611                                 imported_modules.add(sup)
 612                                 mmodule.set_visibility_for(sup, public_visibility)
 613                         end
 614                 end
 615                 self.toolcontext.info("{mmodule} imports {imported_modules.join(", ")}", 3)
 616                 mmodule.set_imported_mmodules(imported_modules)
 617
 618                 # Force standard to be public if imported
 619                 for sup in mmodule.in_importation.greaters do
 620                         if sup.name == "standard" then
 621                                 mmodule.set_visibility_for(sup, public_visibility)
 622                         end
 623                 end
 624
 625                 # TODO: Correctly check for useless importation
 626                 # It is even doable?
 627                 var directs = mmodule.in_importation.direct_greaters
 628                 for nim in nmodule.n_imports do
 629                         if not nim isa AStdImport then continue
 630                         var im = nim.mmodule
 631                         if im == null then continue
 632                         if directs.has(im) then continue
 633                         # This generates so much noise that it is simpler to just comment it
 634                         #warning(nim, "Warning: possible useless importation of {im}")
 635                 end
 636         end
 637
 638         # All the loaded modules
 639         var nmodules = new Array[AModule]
 640
 641         # Register the nmodule associated to each mmodule
 642         #
 643         # Public clients need to use `mmodule2node` to access stuff.
 644         private var mmodule2nmodule = new HashMap[MModule, AModule]
 645
 646         # Retrieve the associated AST node of a mmodule.
 647         # This method is used to associate model entity with syntactic entities.
 648         #
 649         # If the module is not associated with a node, returns null.
 650         fun mmodule2node(mmodule: MModule): nullable AModule
 651         do
 652                 return mmodule2nmodule.get_or_null(mmodule)
 653         end
 654 end
 655
 656 # File-system location of a module (file) that is identified but not always loaded.
 657 class ModulePath
 658         # The name of the module
 659         # (it's the basename of the filepath)
 660         var name: String
 661
 662         # The human path of the module
 663         var filepath: String
 664
 665         # The group (and the project) of the possible module
 666         var mgroup: MGroup
 667
 668         # The loaded module (if any)
 669         var mmodule: nullable MModule = null
 670
 671         redef fun to_s do return filepath
 672 end
 673
 674 redef class MGroup
 675         # Modules paths associated with the group
 676         var module_paths = new Array[ModulePath]
 677
 678         # Is the group interesting for a final user?
 679         #
 680         # Groups are mandatory in the model but for simple projects they are not
 681         # always interesting.
 682         #
 683         # A interesting group has, at least, one of the following true:
 684         #
 685         # * it has 2 modules or more
 686         # * it has a subgroup
 687         # * it has a documentation
 688         fun is_interesting: Bool
 689         do
 690                 return module_paths.length > 1 or mmodules.length > 1 or not in_nesting.direct_smallers.is_empty or mdoc != null
 691         end
 692
 693 end
 694
 695 redef class SourceFile
 696         # Associated mmodule, once created
 697         var mmodule: nullable MModule = null
 698 end
 699
 700 redef class AStdImport
 701         # The imported module once determined
 702         var mmodule: nullable MModule = null
 703 end
 704
 705 redef class AModule
 706         # The associated MModule once build by a `ModelBuilder`
 707         var mmodule: nullable MModule
 708         # Flag that indicate if the importation is already completed
 709         var is_importation_done: Bool = false
 710 end