lib/gamnit/dynamic_resolution.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Virtual screen with a resolution independent from the real screen
  16 #
  17 # The attribute `dynamic_resolution_ratio` sets the size of the virtual screen
  18 # in relation to the real screen. See its documentation for more information.
  19 #
  20 # Reference implementation:
  21 # https://software.intel.com/en-us/articles/dynamic-resolution-rendering-on-opengl-es-2
  22 module dynamic_resolution
  23
  24 import performance_analysis
  25
  26 import gamnit
  27
  28 redef class App
  29         # Resolution of the dynamic screen as ratio of the real screen resolution.
  30         #
  31         # - At 1.0, the default, the virtual screen is not used and the visuals are
  32         #   drawn directly to the real screen and pixels.
  33         # - When below 1.0, there is less pixels in the dynamic screen than in the
  34         #   real screen. This reduces the strain on the GPU, especially of high
  35         #   resolution displays.
  36         # - Values above 1.0 are not supported at this point, but they would allow
  37         #   super-sampling.
  38         #
  39         # This value must be set either by the user using a video quality slider or
  40         # by an heuristic according to the device capabilities.
  41         # A lower value should use less battery power on mobile devices.
  42         #
  43         # This value is applied to both X and Y, so it has an exponential effect on
  44         # the number of pixels.
  45         var dynamic_resolution_ratio = 1.0
  46
  47         # Minimum dynamic screen resolution
  48         var min_dynamic_resolution_ratio = 0.0125 is writable
  49
  50         # Maximum dynamic screen resolution, must be set before first draw
  51         var max_dynamic_resolution_ratio = 1.0 is writable
  52
  53         private var dynres_program = new DynamicResolutionProgram
  54
  55         private var perf_clock_dynamic_resolution = new Clock is lazy
  56
  57         redef fun on_create
  58         do
  59                 super
  60
  61                 var program = dynres_program
  62                 program.compile_and_link
  63                 var error = program.error
  64                 assert error == null else print_error error
  65         end
  66
  67         # Prepare to draw to the dynamic screen if `dynamic_resolution_ratio != 1.0`
  68         protected fun frame_core_dynamic_resolution_before(display: GamnitDisplay)
  69         do
  70                 # TODO autodetect when to lower/increase resolution
  71
  72                 if dynamic_resolution_ratio == 1.0 then
  73                         # Draw directly to the screen framebuffer
  74                         glBindFramebuffer(gl_FRAMEBUFFER, dynamic_context.screen_framebuffer)
  75                         glViewport(0, 0, display.width, display.height)
  76                         glClear gl_COLOR_BUFFER_BIT | gl_DEPTH_BUFFER_BIT
  77
  78                         var gl_error = glGetError
  79                         assert gl_error == gl_NO_ERROR else print_error gl_error
  80                         return
  81                 end
  82
  83                 # Draw to our dynamic framebuffer
  84                 glBindFramebuffer(gl_FRAMEBUFFER, dynamic_context.dynamic_framebuffer)
  85
  86                 var ratio = dynamic_resolution_ratio
  87                 ratio = ratio.clamp(min_dynamic_resolution_ratio, max_dynamic_resolution_ratio)
  88                 glViewport(0, 0, (display.width.to_f*ratio).to_i,
  89                                                  (display.height.to_f*ratio).to_i)
  90
  91                 glClear gl_COLOR_BUFFER_BIT | gl_DEPTH_BUFFER_BIT
  92
  93                 var gl_error = glGetError
  94                 assert gl_error == gl_NO_ERROR else print_error gl_error
  95         end
  96
  97         # Draw the dynamic screen to the real screen if `dynamic_resolution_ratio != 1.0`
  98         protected fun frame_core_dynamic_resolution_after(display: GamnitDisplay)
  99         do
 100                 if dynamic_resolution_ratio == 1.0 then return
 101                 perf_clock_dynamic_resolution.lapse
 102
 103                 var ratio = dynamic_resolution_ratio
 104                 ratio = ratio.clamp(min_dynamic_resolution_ratio, max_dynamic_resolution_ratio)
 105
 106                 glBindFramebuffer(gl_FRAMEBUFFER, dynamic_context.screen_framebuffer)
 107                 glBindBuffer(gl_ARRAY_BUFFER, dynamic_context.buffer_array)
 108                 glViewport(0, 0, display.width, display.height)
 109                 glClear gl_COLOR_BUFFER_BIT | gl_DEPTH_BUFFER_BIT
 110                 dynres_program.use
 111
 112                 # Uniforms
 113                 glActiveTexture gl_TEXTURE0
 114                 glBindTexture(gl_TEXTURE_2D, dynamic_context.texture)
 115                 dynres_program.texture.uniform 0
 116                 dynres_program.ratio.uniform ratio
 117
 118                 # Attributes
 119                 var sizeof_gl_float = 4
 120                 var n_floats = 3
 121                 glEnableVertexAttribArray dynres_program.coord.location
 122                 glVertexAttribPointeri(dynres_program.coord.location, n_floats, gl_FLOAT, false, 0, 0)
 123                 var offset = 4 * n_floats * sizeof_gl_float
 124
 125                 n_floats = 2
 126                 glEnableVertexAttribArray dynres_program.tex_coord.location
 127                 glVertexAttribPointeri(dynres_program.tex_coord.location, n_floats, gl_FLOAT, false, 0, offset)
 128                 var gl_error = glGetError
 129                 assert gl_error == gl_NO_ERROR else print_error gl_error
 130
 131                 # Draw
 132                 glDrawArrays(gl_TRIANGLE_STRIP, 0, 4)
 133
 134                 gl_error = glGetError
 135                 assert gl_error == gl_NO_ERROR else print_error gl_error
 136
 137                 sys.perfs["gamnit flat dyn res"].add app.perf_clock_dynamic_resolution.lapse
 138         end
 139
 140         # Framebuffer and texture for dynamic resolution intermediate drawing
 141         private var dynamic_context: DynamicContext = create_dynamic_context is lazy
 142
 143         private fun create_dynamic_context: DynamicContext
 144         do
 145                 # TODO option or flag to regen on real resolution change.
 146
 147                 var display = display
 148                 assert display != null
 149
 150                 var context = new DynamicContext
 151                 context.prepare_once(display, max_dynamic_resolution_ratio)
 152                 return context
 153         end
 154 end
 155
 156 # Program drawing the dynamic screen to the real screen
 157 private class DynamicContext
 158
 159         # Real screen framebuffer
 160         var screen_framebuffer: Int = -1
 161
 162         # Dynamic screen framebuffer
 163         var dynamic_framebuffer: Int = -1
 164
 165         # Depth renderbuffer attached to `dynamic_framebuffer`
 166         var depth_renderbuffer: Int = -1
 167
 168         # Texture attached to `dynamic_framebuffer` as color attachment
 169         var texture: Int = -1
 170
 171         # Buffer name for vertex data
 172         var buffer_array: Int = -1
 173
 174         var float_per_vertex: Int is lazy do return 4 + 4 + 3
 175
 176         # Prepare all attributes once per resolution change
 177         fun prepare_once(display: GamnitDisplay, max_dynamic_resolution_ratio: Float)
 178         do
 179                 # TODO enable antialiasing.
 180
 181                 var width = (display.width.to_f * max_dynamic_resolution_ratio).to_i
 182                 var height = (display.height.to_f * max_dynamic_resolution_ratio).to_i
 183
 184                 # Set aside the real screen framebuffer name
 185                 var screen_framebuffer = glGetIntegerv(gl_FRAMEBUFFER_BINDING, 0)
 186                 self.screen_framebuffer = screen_framebuffer
 187
 188                 # Framebuffer
 189                 var framebuffer = glGenFramebuffers(1).first
 190                 glBindFramebuffer(gl_FRAMEBUFFER, framebuffer)
 191                 assert glIsFramebuffer(framebuffer)
 192                 self.dynamic_framebuffer = framebuffer
 193
 194                 # Depth
 195                 var depthbuffer = glGenRenderbuffers(1).first
 196                 glBindRenderbuffer(gl_RENDERBUFFER, depthbuffer)
 197                 assert glIsRenderbuffer(depthbuffer)
 198                 glRenderbufferStorage(gl_RENDERBUFFER, gl_DEPTH_COMPNENT16, width, height)
 199                 glFramebufferRenderbuffer(gl_FRAMEBUFFER, gl_DEPTH_ATTACHMENT, gl_RENDERBUFFER, depthbuffer)
 200                 self.depth_renderbuffer = depthbuffer
 201
 202                 # Texture
 203                 var texture = glGenTextures(1).first
 204                 glBindTexture(gl_TEXTURE_2D, texture)
 205                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MIN_FILTER, gl_LINEAR)
 206                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, gl_LINEAR)
 207                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_WRAP_S, gl_CLAMP_TO_EDGE)
 208                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_WRAP_T, gl_CLAMP_TO_EDGE)
 209                 glTexImage2D(gl_TEXTURE_2D, 0, gl_RGB, width, height,
 210                              0, gl_RGB, gl_UNSIGNED_BYTE, new Pointer.nul)
 211                 glFramebufferTexture2D(gl_FRAMEBUFFER, gl_COLOR_ATTACHMENT0, gl_TEXTURE_2D, texture, 0)
 212                 self.texture = texture
 213
 214                 var gl_error = glGetError
 215                 assert gl_error == gl_NO_ERROR else print_error gl_error
 216                 assert glCheckFramebufferStatus(gl_FRAMEBUFFER) == gl_FRAMEBUFFER_COMPLETE
 217
 218                 # Take down
 219                 glBindRenderbuffer(gl_RENDERBUFFER, 0)
 220                 glBindFramebuffer(gl_FRAMEBUFFER, 0)
 221
 222                 # Array buffer
 223                 buffer_array = glGenBuffers(1).first
 224                 glBindBuffer(gl_ARRAY_BUFFER, buffer_array)
 225                 assert glIsBuffer(buffer_array)
 226                 gl_error = glGetError
 227                 assert gl_error == gl_NO_ERROR else print_error gl_error
 228
 229                 ## coord
 230                 var data = new Array[Float]
 231                 data.add_all([-1.0, -1.0, 0.0,
 232                            1.0, -1.0, 0.0,
 233                           -1.0,  1.0, 0.0,
 234                            1.0,  1.0, 0.0])
 235                 ## tex_coord
 236                 data.add_all([0.0, 0.0,
 237                               1.0, 0.0,
 238                               0.0, 1.0,
 239                               1.0, 1.0])
 240                 var c_data = new GLfloatArray.from(data)
 241                 glBufferData(gl_ARRAY_BUFFER, data.length*4, c_data.native_array, gl_STATIC_DRAW)
 242
 243                 glBindBuffer(gl_ARRAY_BUFFER, 0)
 244
 245                 gl_error = glGetError
 246                 assert gl_error == gl_NO_ERROR else print_error gl_error
 247         end
 248
 249         var destroyed = false
 250         fun destroy
 251         do
 252                 if destroyed then return
 253                 destroyed = true
 254
 255                 # Free the buffer
 256                 glDeleteBuffers([buffer_array])
 257                 var gl_error = glGetError
 258                 assert gl_error == gl_NO_ERROR else print_error gl_error
 259                 buffer_array = -1
 260
 261                 # Free the dynamic framebuffer and its attachments
 262                 glDeleteBuffers([buffer_array])
 263                 glDeleteFramebuffers([dynamic_framebuffer])
 264                 glDeleteRenderbuffers([depth_renderbuffer])
 265                 glDeleteTextures([texture])
 266         end
 267 end
 268
 269 private class DynamicResolutionProgram
 270         super GamnitProgramFromSource
 271
 272         redef var vertex_shader_source = """
 273                 // Vertex coordinates
 274                 attribute vec3 coord;
 275
 276                 // Vertex coordinates on textures
 277                 attribute vec2 tex_coord;
 278
 279                 // Output to the fragment shader
 280                 varying vec2 v_coord;
 281
 282                 void main()
 283                 {
 284                         gl_Position = vec4(coord, 1.0);
 285                         v_coord = tex_coord;
 286                 }
 287                 """ @ glsl_vertex_shader
 288
 289         redef var fragment_shader_source = """
 290                 precision mediump float;
 291
 292                 // Virtual screen texture / color attachment
 293                 uniform sampler2D texture0;
 294
 295                 // Input from the vertex shader
 296                 varying vec2 v_coord;
 297
 298                 // Ratio of the virtual screen to draw
 299                 uniform float ratio;
 300
 301                 void main()
 302                 {
 303                         gl_FragColor = texture2D(texture0, v_coord*ratio);
 304                 }
 305                 """ @ glsl_fragment_shader
 306
 307         # Vertices coordinates
 308         var coord = attributes["coord"].as(AttributeVec3) is lazy
 309
 310         # Coordinates on the textures, per vertex
 311         var tex_coord = attributes["tex_coord"].as(AttributeVec2) is lazy
 312
 313         # Virtual screen texture / color attachment
 314         var texture = uniforms["texture0"].as(UniformSampler2D) is lazy
 315
 316         # Ratio of the virtual screen to draw
 317         var ratio = uniforms["ratio"].as(UniformFloat) is lazy
 318 end