lib/a_star.nit

   1 # This file is part of NIT (http://www.nitlanguage.org).
   2 #
   3 # Copyright 2011-2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Services related to pathfinding of graphs using A*
  18 # A single graph may have different properties according to the `PathContext` used
  19 #
  20 #
  21 # Usage:
  22 #
  23 # ~~~
  24 # # Weighted graph (letters are nodes, digits are weights):
  25 # #
  26 # #     a -2- b
  27 # #    /     /
  28 # #   3     1
  29 # #  /     /
  30 # # c -3- d -8- e
  31 # #
  32 # var graph = new Graph[Node,WeightedLink]
  33 #
  34 # var na = new Node(graph)
  35 # var nb = new Node(graph)
  36 # var nc = new Node(graph)
  37 # var nd = new Node(graph)
  38 # var ne = new Node(graph)
  39 #
  40 # var lab = new WeightedLink(graph, na, nb, 2)
  41 # var lac = new WeightedLink(graph, na, nc, 3)
  42 # var lbd = new WeightedLink(graph, nb, nd, 1)
  43 # var lcd = new WeightedLink(graph, nc, nd, 3)
  44 # var lde = new WeightedLink(graph, nd, ne, 8)
  45 #
  46 # var context = new WeightedPathContext(graph)
  47 #
  48 # var path = na.path_to(ne, 100, context)
  49 # assert path != null else print "No possible path"
  50 #
  51 # assert path.step == nb
  52 # assert path.step == nd
  53 # assert path.step == ne
  54 # assert path.at_end_of_path
  55 # ~~~
  56 module a_star
  57
  58 # General graph node
  59 class Node
  60         # Type of the others nodes in the `graph`
  61         type N: Node
  62
  63         # parent graph
  64         var graph: Graph[N, Link]
  65
  66         init
  67         do
  68                 graph.add_node(self)
  69         end
  70
  71         # adjacent nodes
  72         var links: Set[Link] = new HashSet[Link]
  73
  74         # used to check if node has been searched in one pathfinding
  75         private var last_pathfinding_evocation: Int = 0
  76
  77         # cost up to in current evocation
  78         # lifetime limited to evocation of `path_to`
  79         private var best_cost_up_to: Int = 0
  80
  81         # source node
  82         # lifetime limited to evocation of `path_to`
  83         private var best_source: nullable N = null
  84
  85         # is in frontier or buckets
  86         # lifetime limited to evocation of `path_to`
  87         private var open: Bool = false
  88
  89         # Main functionnality, returns path from `self` to `dest`
  90         fun path_to(dest: N, max_cost: Int, context: PathContext): nullable AStarPath[N]
  91         do
  92                 return path_to_alts(dest, max_cost, context, null)
  93         end
  94
  95         # Find a path to a possible `destination` or a node accepted by `alt_targets`
  96         fun path_to_alts(destination: nullable N, max_cost: Int, context: PathContext,
  97                 alt_targets: nullable TargetCondition[N]): nullable AStarPath[N]
  98         do
  99                 var cost = 0
 100
 101                 var nbr_buckets = context.worst_cost + context.worst_heuristic_cost + 1
 102                 var buckets = new Array[List[N]].with_capacity(nbr_buckets)
 103
 104                 for i in [0 .. nbr_buckets[ do
 105                         buckets.add(new List[N])
 106                 end
 107
 108                 graph.pathfinding_current_evocation += 1
 109
 110                 # open source node
 111                 buckets[0].add(self)
 112                 open = true
 113                 self.last_pathfinding_evocation = graph.pathfinding_current_evocation
 114                 self.best_cost_up_to = 0
 115
 116                 loop
 117                         var frontier_node: nullable N = null
 118
 119                         var bucket_searched = 0
 120
 121                         # find next valid node in frontier/buckets
 122                         loop
 123                                 var current_bucket = buckets[cost % nbr_buckets]
 124
 125                                 if current_bucket.is_empty then # move to next bucket
 126                                         cost += 1
 127                                         if cost > max_cost then return null
 128                                         bucket_searched += 1
 129
 130                                         if bucket_searched > nbr_buckets then break
 131                                 else # found a node
 132                                         frontier_node = current_bucket.pop
 133
 134                                         if frontier_node.open then break
 135                                 end
 136                         end
 137
 138                         # no path possible
 139                         if frontier_node == null then
 140                                 return null
 141
 142                         # at destination
 143                         else if frontier_node == destination or
 144                              (alt_targets != null and alt_targets.accept(frontier_node)) then
 145
 146                                 var path = new AStarPath[N](cost)
 147
 148                                 while frontier_node != self do
 149                                         path.nodes.unshift(frontier_node)
 150                                         frontier_node = frontier_node.best_source
 151                                         assert frontier_node != null
 152                                 end
 153
 154                                 return path
 155
 156                         # adds all next nodes to frontier/buckets
 157                         else
 158                                 frontier_node.open = false
 159
 160                                 for link in frontier_node.links do
 161                                         var peek_node = link.to
 162                                         if not context.is_blocked(link) and
 163                                          (peek_node.last_pathfinding_evocation != graph.pathfinding_current_evocation or
 164                                            (peek_node.open and
 165                                              peek_node.best_cost_up_to > cost + context.cost(link)))
 166                                         then
 167                                                 peek_node.open = true
 168                                                 peek_node.last_pathfinding_evocation = graph.pathfinding_current_evocation
 169                                                 peek_node.best_cost_up_to = cost + context.cost(link)
 170                                                 peek_node.best_source = frontier_node
 171
 172                                                 var est_cost
 173                                                 if destination != null then
 174                                                         est_cost = peek_node.best_cost_up_to + context.heuristic_cost(peek_node, destination)
 175                                                 else if alt_targets != null then
 176                                                         est_cost = peek_node.best_cost_up_to + alt_targets.heuristic_cost(peek_node, link)
 177                                                 else est_cost = 0
 178
 179                                                 var at_bucket = buckets[est_cost % nbr_buckets]
 180                                                 at_bucket.add(peek_node)
 181                                         end
 182                                 end
 183                         end
 184                 end
 185         end
 186 end
 187
 188 # Link between two nodes and associated to a graph
 189 class Link
 190         # Type of the nodes in `graph`
 191         type N: Node
 192
 193         # Type of the other links in `graph`
 194         type L: Link
 195
 196         # The graph to which belongs `self`
 197         var graph: Graph[N, L]
 198
 199         # Origin of this link
 200         var from: N
 201
 202         # Endpoint of this link
 203         var to: N
 204
 205         init
 206         do
 207                 graph.add_link(self)
 208         end
 209 end
 210
 211 # General graph
 212 class Graph[N: Node, L: Link]
 213         # Nodes in this graph
 214         var nodes: Set[N] = new HashSet[N]
 215
 216         # Links in this graph
 217         var links: Set[L] = new HashSet[L]
 218
 219         # Add a `node` to this graph
 220         fun add_node(node: N): N
 221         do
 222                 nodes.add(node)
 223
 224                 return node
 225         end
 226
 227         # Add a `link` to this graph
 228         fun add_link(link: L): L
 229         do
 230                 links.add(link)
 231
 232                 link.from.links.add(link)
 233
 234                 return link
 235         end
 236
 237         # Used to check if nodes have been searched in one pathfinding
 238         private var pathfinding_current_evocation: Int = 0
 239 end
 240
 241 # Result from path finding and a walkable path
 242 class AStarPath[N]
 243
 244         # The total cost of this path
 245         var total_cost: Int
 246
 247         # The list of nodes composing this path
 248         var nodes = new List[N]
 249
 250         private var at: Int = 0
 251
 252         # Step on the path and get the next node to travel
 253         fun step: N
 254         do
 255                 assert nodes.length >= at else print "a_star::AStarPath::step failed, is at_end_of_path"
 256
 257                 var s = nodes[at]
 258                 at += 1
 259
 260                 return s
 261         end
 262
 263         # Peek at the next step of the path
 264         fun peek_step: N do return nodes[at]
 265
 266         # Are we at the end of this path?
 267         fun at_end_of_path: Bool do return at >= nodes.length
 268 end
 269
 270 # Context related to an evocation of pathfinding
 271 class PathContext
 272         # Type of the nodes in `graph`
 273         type N: Node
 274
 275         # Type of the links in `graph`
 276         type L: Link
 277
 278         # Graph to which is associated `self`
 279         var graph: Graph[N, L]
 280
 281         # Worst cost of all the link's costs
 282         fun worst_cost: Int is abstract
 283
 284         # Get cost of a link
 285         fun cost(link: L): Int is abstract
 286
 287         # Is that link blocked?
 288         fun is_blocked(link: L): Bool is abstract
 289
 290         # Heuristic
 291         fun heuristic_cost(a, b: N): Int is abstract
 292
 293         # The worst cost suggested by the heuristic
 294         fun worst_heuristic_cost: Int is abstract
 295 end
 296
 297 #
 298 ### Additionnal classes, may be useful
 299 #
 300
 301 # Simple context with constant cost on each links
 302 # Warning: A* is not optimize for such a case
 303 class ConstantPathContext
 304         super PathContext
 305
 306         redef fun worst_cost do return 1
 307         redef fun cost(l) do return 1
 308         redef fun is_blocked(l) do return false
 309         redef fun heuristic_cost(a, b) do return 0
 310         redef fun worst_heuristic_cost do return 0
 311 end
 312
 313 # A `PathContext` for graphs with `WeightedLink`
 314 class WeightedPathContext
 315         super PathContext
 316
 317         redef type L: WeightedLink
 318
 319         init
 320         do
 321                 super
 322
 323                 var worst_cost = 0
 324                 for l in graph.links do
 325                         var cost = l.weight
 326                         if cost >= worst_cost then worst_cost = cost + 1
 327                 end
 328                 self.worst_cost = worst_cost
 329         end
 330
 331         redef var worst_cost: Int is noinit
 332
 333         redef fun cost(l) do
 334                 return l.weight
 335         end
 336         redef fun is_blocked(l) do return false
 337         redef fun heuristic_cost(a, b) do return 0
 338         redef fun worst_heuristic_cost do return 0
 339 end
 340
 341 # A `Link` with a `weight`
 342 class WeightedLink
 343         super Link
 344
 345         # The `weight`, or cost, of this link
 346         var weight: Int
 347 end
 348
 349 # Advanced path conditions with customizable accept states
 350 class TargetCondition[N: Node]
 351         # Should the pathfinding accept `node` as a goal?
 352         fun accept(node: N): Bool is abstract
 353
 354         # Approximate cost from `node` to an accept state
 355         fun heuristic_cost(node: N, link: Link): Int is abstract
 356 end